pgd_snap_temp_profile.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE pgd_snap_temp_profile(HPROGRAM,HFILENAME,PSNAP_COEF, &
                                       ksnap,ktps,hsnap_time_ref      )
!     ##############################################################
!
!!**** *PGD_SNAP_TEMP_PROFILE* reads a temporal emission profile
!!
!!    PURPOSE
!!    -------
!!
!!    AUTHOR
!!    ------
!!
!!    S. QUEGUINER          Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original    09/2011 
!!    A. Alias    07/2013 CONTINUE procedure for compilation on beaufix
!!
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!

USE modi_open_file
USE modi_close_file
USE modi_get_luout
USE modi_test_nam_var_surf
!
!
USE modd_surf_par,       ONLY : xundef
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
 CHARACTER(LEN=6),     INTENT(IN) :: hprogram      ! Type of program
 CHARACTER(LEN=28),    INTENT(IN) :: hfilename     ! Name of the field file.
REAL, DIMENSION(:,:), INTENT(OUT):: psnap_coef    ! Snap coefficient
INTEGER,              INTENT(IN) :: ktps          ! Number of time step
INTEGER,              INTENT(IN) :: ksnap         ! Number of snaps
 CHARACTER(LEN=5), OPTIONAL, INTENT(OUT):: hsnap_time_ref ! Reference time
!                                                        ! 'UTC  ' : UTC   time
!                                                        ! 'SOLAR' : SOLAR time
!                                                        ! 'LEGAL' : LEGAL time
!
!*    0.2    Declaration of local variables
!            ------------------------------
!
INTEGER                           :: iunit      ! logical unit
INTEGER                           :: jsnap      ! loop counter on snaps
 CHARACTER(LEN=200) :: ycomment
REAL,    DIMENSION(KTPS)          :: zsnap_coef ! snap temporal coefficient
INTEGER                           :: isnap      ! snap number
INTEGER                           :: iluout     ! output listing
REAL(KIND=JPRB) :: zhook_handle
!----------------------------------------------------------------------------
!
!*    1.      Open the file
!             -------------
!
IF (lhook) CALL dr_hook('PGD_SNAP_TEMP_PROFILE',0,zhook_handle)
!
 CALL open_file(hprogram,iunit,hfilename,'FORMATTED',haction='READ')
!
 CALL get_luout(hprogram,iluout)
!
!----------------------------------------------------------------------------
READ(iunit,'(A)') ycomment
!----------------------------------------------------------------------------
!
!*    2.     Reading of time reference for hourly profiles
!            ---------------------------------------------
!
IF (present(hsnap_time_ref)) THEN
  READ(iunit,'(A)') hsnap_time_ref
  CALL test_nam_var_surf(iluout,'CSNAP_TIME_REF',hsnap_time_ref,'UTC  ','SOLAR','LEGAL')
END IF
!
!----------------------------------------------------------------------------
READ(iunit,'(A)') ycomment
!----------------------------------------------------------------------------
!
!*    3.     Reading of snaps temporal coefficients
!            --------------------------------------
!
psnap_coef(:,:)=0.
!
DO jsnap=1,ksnap
  READ(iunit,*,end=2000) isnap,zsnap_coef(1:ktps) 
  psnap_coef(:,isnap)=zsnap_coef(:)
ENDDO
!
!----------------------------------------------------------------------------
!
!*    8.    Closing of the data file
!           ------------------------
!
2000 CONTINUE
 CALL close_file(hprogram,iunit)
!
IF (lhook) CALL dr_hook('PGD_SNAP_TEMP_PROFILE',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE pgd_snap_temp_profile