pack_grid_gauss.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!##############################################################
SUBROUTINE pack_grid_gauss(KMASK_SIZE,KMASK,KGRID_PAR1,PGRID_PAR1,KGRID_PAR2,OPACK,PGRID_PAR2)
!##############################################################
!
!!**** *PACK_GRID_GAUSS* packs the grid definition vector
!!
!!    PURPOSE
!!    -------
!!
!!    METHOD
!!    ------
!!   
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    V. Masson         Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original    03/2004
!!    (B. Decharme)  2008 pack mesh area  
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
USE modi_pack_same_rank
USE mode_gridtype_gauss
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
INTEGER,                        INTENT(IN)    :: kmask_size ! size of mask
INTEGER, DIMENSION(KMASK_SIZE), INTENT(IN)    :: kmask      ! mask used
INTEGER,                        INTENT(IN)    :: kgrid_par1 ! size of input grid vector
REAL,    DIMENSION(KGRID_PAR1), INTENT(IN)    :: pgrid_par1 ! parameters of input grid
INTEGER,                        INTENT(INOUT) :: kgrid_par2 ! size of output grid vector
LOGICAL,                        INTENT(IN)    :: opack      ! flag to pack the grid vector
REAL,    DIMENSION(KGRID_PAR2), INTENT(OUT)   :: pgrid_par2 ! parameters of output grid
!
!*    0.2    Declaration of other local variables
!            ------------------------------------
!
INTEGER :: inlati   ! number of pseudo-latitudes
REAL    :: zlapo    ! latitude  of the rotated pole (deg)
REAL    :: zlopo    ! longitude of the rotated pole (deg)
REAL    :: zcodil   ! stretching factor (must be greater than or equal to 1)
INTEGER, DIMENSION(:), ALLOCATABLE :: inlopa ! number of pseudo-longitudes on each
                                             ! pseudo-latitude circle
!
REAL, DIMENSION(:), ALLOCATABLE    :: zlat1     ! latitude of all grid points
REAL, DIMENSION(:), ALLOCATABLE    :: zlon1     ! longitude of all grid points
REAL, DIMENSION(:), ALLOCATABLE    :: zlat2     ! latitude of subset of grid points
REAL, DIMENSION(:), ALLOCATABLE    :: zlon2     ! longitude of subset of grid points
REAL, DIMENSION(:), ALLOCATABLE    :: zlat_xy1  ! pseudo-latitude of all grid points
REAL, DIMENSION(:), ALLOCATABLE    :: zlon_xy1  ! pseudo-longitude of all grid points
REAL, DIMENSION(:), ALLOCATABLE    :: zlat_xy2  ! pseudo-latitude of subset of grid points
REAL, DIMENSION(:), ALLOCATABLE    :: zlon_xy2  ! pseudo-longitude of subset of grid points
REAL, DIMENSION(:), ALLOCATABLE    :: zmesh_size1! 
REAL, DIMENSION(:), ALLOCATABLE    :: zmesh_size2! 
!                                                                            _____ Sup
REAL, DIMENSION(:), ALLOCATABLE    :: zlatsup1    ! Grid corner Latitude    |     |
REAL, DIMENSION(:), ALLOCATABLE    :: zlonsup1    ! Grid corner Longitude   |     |
REAL, DIMENSION(:), ALLOCATABLE    :: zlatinf1    ! Grid corner Latitude    |_____|
REAL, DIMENSION(:), ALLOCATABLE    :: zloninf1    ! Grid corner Longitude  Inf
!                                                                            _____ Sup
REAL, DIMENSION(:), ALLOCATABLE    :: zlatsup2    ! Grid corner Latitude    |     |
REAL, DIMENSION(:), ALLOCATABLE    :: zlonsup2    ! Grid corner Longitude   |     |
REAL, DIMENSION(:), ALLOCATABLE    :: zlatinf2    ! Grid corner Latitude    |_____|
REAL, DIMENSION(:), ALLOCATABLE    :: zloninf2    ! Grid corner Longitude  Inf
!
INTEGER                            :: il        ! total number of points

REAL, DIMENSION(:), POINTER       :: zgrid_par2 ! parameters of output grid
REAL(KIND=JPRB) :: zhook_handle
!----------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('PACK_GRID_GAUSS',0,zhook_handle)
!
!*    1.     Computes grid parameters
!            ------------------------
!
 CALL get_gridtype_gauss(pgrid_par1,inlati,kl=il)
!
ALLOCATE(inlopa(inlati))
ALLOCATE(zlat_xy1(il))
ALLOCATE(zlon_xy1(il))
ALLOCATE(zlat1(il))
ALLOCATE(zlon1(il))
ALLOCATE(zmesh_size1(il))
ALLOCATE(zloninf1(il))
ALLOCATE(zlatinf1(il))
ALLOCATE(zlonsup1(il))
ALLOCATE(zlatsup1(il))
!
 CALL get_gridtype_gauss(pgrid_par1,inlati,zlapo,zlopo,zcodil,inlopa(:), &
                        il,zlat1,zlon1,zlat_xy1,zlon_xy1,zmesh_size1  , &
                        zloninf1,zlatinf1,zlonsup1,zlatsup1             )  
!
!----------------------------------------------------------------------------
!
!*    2.     Packs latitude and longitude arrays
!            -----------------------------------
!
!
ALLOCATE(zlat_xy2(kmask_size))
ALLOCATE(zlon_xy2(kmask_size))
ALLOCATE(zlat2(kmask_size))
ALLOCATE(zlon2(kmask_size))
ALLOCATE(zmesh_size2(kmask_size))
ALLOCATE(zloninf2(kmask_size))
ALLOCATE(zlatinf2(kmask_size))
ALLOCATE(zlonsup2(kmask_size))
ALLOCATE(zlatsup2(kmask_size))
!
 CALL pack_same_rank(kmask,zlat_xy1,zlat_xy2)
 CALL pack_same_rank(kmask,zlon_xy1,zlon_xy2)
 CALL pack_same_rank(kmask,zlat1,zlat2)
 CALL pack_same_rank(kmask,zlon1,zlon2)
 CALL pack_same_rank(kmask,zmesh_size1,zmesh_size2)
 CALL pack_same_rank(kmask,zloninf1,zloninf2)
 CALL pack_same_rank(kmask,zlatinf1,zlatinf2)
 CALL pack_same_rank(kmask,zlonsup1,zlonsup2)
 CALL pack_same_rank(kmask,zlatsup1,zlatsup2)
!
DEALLOCATE(zlat_xy1   )
DEALLOCATE(zlon_xy1   )
DEALLOCATE(zlat1      )
DEALLOCATE(zlon1      )
DEALLOCATE(zmesh_size1)
DEALLOCATE(zloninf1   )
DEALLOCATE(zlatinf1   )
DEALLOCATE(zlonsup1   )
DEALLOCATE(zlatsup1   )
!
!----------------------------------------------------------------------------
!
!*    3.     Stores data in new grid vector
!            ------------------------------
!
 CALL put_gridtype_gauss(zgrid_par2,inlati,zlapo,zlopo,zcodil,inlopa(:), &
                        kmask_size,zlat2,zlon2,zlat_xy2,zlon_xy2,       &
                        zmesh_size2,zloninf2,zlatinf2,zlonsup2,zlatsup2 )  
!
DEALLOCATE(zlat_xy2   )
DEALLOCATE(zlon_xy2   )
DEALLOCATE(zlat2      )
DEALLOCATE(zlon2      )
DEALLOCATE(zmesh_size2)
DEALLOCATE(zloninf2   )
DEALLOCATE(zlatinf2   )
DEALLOCATE(zlonsup2   )
DEALLOCATE(zlatsup2   )

!----------------------------------------------------------------------------
! 
IF (opack) THEN
  pgrid_par2(:) = zgrid_par2(:)
ELSE
  kgrid_par2    = SIZE(zgrid_par2(:))
END IF
!
DEALLOCATE(zgrid_par2)
DEALLOCATE(inlopa)
IF (lhook) CALL dr_hook('PACK_GRID_GAUSS',1,zhook_handle)
!-------------------------------------------------------------------------------
!
END SUBROUTINE pack_grid_gauss