pack_grid_cartesian.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     ##############################################################
      SUBROUTINE pack_grid_cartesian(KMASK_SIZE,KMASK,KGRID_PAR1,PGRID_PAR1,KGRID_PAR2,OPACK,PGRID_PAR2)
!     ##############################################################
!
!!**** *PACK_GRID_CARTESIAN* packs the grid definition vector
!!
!!    PURPOSE
!!    -------
!!
!!    METHOD
!!    ------
!!   
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    V. Masson         Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original    03/2004
!!
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
USE modi_pack_same_rank
USE mode_gridtype_cartesian
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
INTEGER,                        INTENT(IN)    :: kmask_size ! size of mask
INTEGER, DIMENSION(KMASK_SIZE), INTENT(IN)    :: kmask      ! mask used
INTEGER,                        INTENT(IN)    :: kgrid_par1 ! size of input grid vector
REAL,    DIMENSION(KGRID_PAR1), INTENT(IN)    :: pgrid_par1 ! parameters of input grid
INTEGER,                        INTENT(INOUT) :: kgrid_par2 ! size of output grid vector
LOGICAL,                        INTENT(IN)    :: opack      ! flag to pack the grid vector
REAL,    DIMENSION(KGRID_PAR2), INTENT(OUT)   :: pgrid_par2 ! parameters of output grid
!
!*    0.2    Declaration of other local variables
!            ------------------------------------
!
REAL                              :: zlat0    ! reference latitude
REAL                              :: zlon0    ! reference longitude
INTEGER                           :: iimax    ! number of points in I direction
INTEGER                           :: ijmax    ! number of points in J direction
REAL, DIMENSION(:), ALLOCATABLE   :: zx1      ! X conformal coordinate of grid mesh
REAL, DIMENSION(:), ALLOCATABLE   :: zy1      ! Y conformal coordinate of grid mesh
REAL, DIMENSION(:), ALLOCATABLE   :: zdx1     ! X grid mesh size
REAL, DIMENSION(:), ALLOCATABLE   :: zdy1     ! Y grid mesh size
REAL, DIMENSION(:), ALLOCATABLE   :: zx2      ! X conformal coordinate of grid mesh
REAL, DIMENSION(:), ALLOCATABLE   :: zy2      ! Y conformal coordinate of grid mesh
REAL, DIMENSION(:), ALLOCATABLE   :: zdx2     ! X grid mesh size
REAL, DIMENSION(:), ALLOCATABLE   :: zdy2     ! Y grid mesh size

INTEGER                           :: il1        ! number of points of input grid
REAL, DIMENSION(:), POINTER       :: zgrid_par2 ! parameters of output grid
REAL(KIND=JPRB) :: zhook_handle
!----------------------------------------------------------------------------
!
!*    2.     Computes grid parameters
!            ------------------------
!
IF (lhook) CALL dr_hook('PACK_GRID_CARTESIAN',0,zhook_handle)
 CALL get_gridtype_cartesian(pgrid_par1,kl=il1)
!
ALLOCATE(zx1(il1))
ALLOCATE(zy1(il1))
ALLOCATE(zdx1(il1))
ALLOCATE(zdy1(il1))
!
 CALL get_gridtype_cartesian(pgrid_par1,zlat0,zlon0,           &
                              iimax,ijmax,                      &
                              zx1,zy1,zdx1,zdy1                 )  
!
ALLOCATE(zx2(kmask_size))
ALLOCATE(zy2(kmask_size))
ALLOCATE(zdx2(kmask_size))
ALLOCATE(zdy2(kmask_size))
!
 CALL pack_same_rank(kmask,zx1 ,zx2 )
 CALL pack_same_rank(kmask,zy1 ,zy2 )
 CALL pack_same_rank(kmask,zdx1,zdx2)
 CALL pack_same_rank(kmask,zdy1,zdy2)
!
DEALLOCATE(zx1 )
DEALLOCATE(zy1 )
DEALLOCATE(zdx1)
DEALLOCATE(zdy1)
!
 CALL put_gridtype_cartesian(zgrid_par2,zlat0,zlon0,           &
                              iimax,ijmax,                      &
                              zx2,zy2,zdx2,zdy2                 )  
!
IF (opack) THEN
  pgrid_par2(:) = zgrid_par2(:)
ELSE
  kgrid_par2    = SIZE(zgrid_par2(:))
END IF
!
DEALLOCATE(zgrid_par2)
DEALLOCATE(zx2 )
DEALLOCATE(zy2 )
DEALLOCATE(zdx2)
DEALLOCATE(zdy2)
IF (lhook) CALL dr_hook('PACK_GRID_CARTESIAN',1,zhook_handle)
!-------------------------------------------------------------------------------
!
END SUBROUTINE pack_grid_cartesian