oi_jacobians.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
SUBROUTINE oi_jacobians (KNBPT,&
!---------------------------------------------------------------------------------
! - INPUT  1D
   pws_o, psab, parg, pd2, pwp, &
! - OUTPUT 1D .
   pdwg_dwg, pdwg_dw2)    
!
!**** * JACOBIANS * - Compute analytical Jacobians for assimilation of WG

!     Purpose.
!     --------

!     - Based on the restore term of the ISBA equation for WG
!       
    
!**   Interface.
!     ----------
!        *CALL* *OI_JACOBIANS*

!----------------------------------------------------------------------------------

!     Externals.
!     ---------

!     Method.  analytical formulation
!     -------

!     Author.
!     -------
!        09-06, J.-F. Mahfouf

!-----------------------------------------------------------------------
!
USE modd_assim,      ONLY : nechgu, xrscal_jac                                                                      
USE modd_csts,       ONLY : xrholw, xday  
!  
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!  
INTEGER, INTENT(IN)    :: knbpt
REAL    ,INTENT(IN)    :: pws_o(knbpt) 
REAL    ,INTENT(IN)    :: psab(knbpt)
REAL    ,INTENT(IN)    :: parg(knbpt)
REAL    ,INTENT(IN)    :: pd2(knbpt)
REAL    ,INTENT(IN)    :: pwp(knbpt)
!
REAL    ,INTENT(OUT)   :: pdwg_dwg(knbpt)
REAL    ,INTENT(OUT)   :: pdwg_dw2(knbpt) 
!
REAL    :: zwsat, zwl, zdt, zw2, zc2, zc2ref, zp, za, zwgeq_dw2
INTEGER    :: jrof
REAL(KIND=JPRB) :: zhook_handle
!
IF (lhook) CALL dr_hook('OI_JACOBIANS',0,zhook_handle)
!
zwl = 1.e-5
zdt = REAL(nechgu)*3600.0*xrscal_jac
!
! Compute analytical Jacobians for the ISBA 2L scheme
!
DO jrof = 1,knbpt

  IF (pws_o(jrof) /= 999.0) THEN

    zp = 0.134     * parg(jrof) + 3.4
    za = 732.42e-3 * parg(jrof)**(-0.539)
    zc2ref = 13.815 * parg(jrof)**(-0.954)
    zwsat = (-1.08*psab(jrof) + 494.305)*0.001
    zw2 = pwp(jrof)/(pd2(jrof)*xrholw)
    zc2 = zc2ref*zw2/(zwsat -zw2 + zwl)
    zwgeq_dw2 = 1.0 - za*zp*(zw2/zwsat)**(zp-1.0) +  &
                  9.0*za*zp*(zw2/zwsat)**(9.0*zp-1.0)   
    pdwg_dwg(jrof) = exp(-zc2/xday*zdt)
    pdwg_dw2(jrof) = zwgeq_dw2 * (1.0 - exp(-zc2/xday*zdt))

  ELSE

    pdwg_dwg(jrof) = 0.0
    pdwg_dw2(jrof) = 0.0

  ENDIF 

ENDDO
IF (lhook) CALL dr_hook('OI_JACOBIANS',1,zhook_handle)
!
END SUBROUTINE oi_jacobians