mode_surf_flood_frac.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!##########################
MODULE mode_surf_flood_frac
!##########################
!
!!****  *MODE_SURF_FLOOD_FRAC* -  module for routines to compute flood fraction
!!                               for surface schemes
!!
!!    PURPOSE
!!    -------
!    
!      The purpose of this routine is to store here all routines to compute
!     flood fractions for the ISBA scheme.
!
!!
!!**  IMPLICIT ARGUMENTS
!!    ------------------
!!       NONE          
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      B. Decharme       * Meteo France *
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    25/05/08
!--------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
!
!-------------------------------------------------------------------------------
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
 CONTAINS
!-------------------------------------------------------------------------------
!
!     ######################################################
      FUNCTION flood_frac_ground(PPSNG,PFFLOOD) RESULT(PFFG)
!     ######################################################
!
REAL, DIMENSION(:), INTENT(IN)  :: ppsng   ! Snow fraction over the ground
REAL, DIMENSION(:), INTENT(IN)  :: pfflood ! Effective floodplain fraction
REAL, DIMENSION(SIZE(PPSNG))    :: pffg    ! Floodplain fraction over the ground
REAL(KIND=JPRB) :: zhook_handle
!
IF (lhook) CALL dr_hook('MODE_SURF_FLOOD_FRAC:FLOOD_FRAC_GROUND',0,zhook_handle)
pffg(:) = pfflood(:)
!
WHERE(pfflood(:)>(1.0-ppsng(:)))pffg(:)=1.0-ppsng(:)
IF (lhook) CALL dr_hook('MODE_SURF_FLOOD_FRAC:FLOOD_FRAC_GROUND',1,zhook_handle)
!
END FUNCTION flood_frac_ground
!
!-------------------------------------------------------------------------------
!
!     ########################################################
      FUNCTION flood_frac_veg(PLAI,PPSNV,PFFLOOD) RESULT(PFFV)
!     ########################################################
!
USE modd_flood_par, ONLY : xcffv
!
REAL, DIMENSION(:), INTENT(IN)  :: plai    ! leaf area index
REAL, DIMENSION(:), INTENT(IN)  :: ppsnv   ! Snow fraction over the vegetation
REAL, DIMENSION(:), INTENT(IN)  :: pfflood ! Effective floodplain fraction
REAL, DIMENSION(SIZE(PPSNV))    :: pffv    ! Floodplain fraction over vegetation
REAL(KIND=JPRB) :: zhook_handle
!
IF (lhook) CALL dr_hook('MODE_SURF_FLOOD_FRAC:FLOOD_FRAC_VEG',0,zhook_handle)
pffv(:)=pfflood(:)*min(1.0,xcffv/max(plai(:),0.1))  
!
WHERE(pffv(:)>(1.0-ppsnv(:)))pffv(:)=1.0-ppsnv(:)
IF (lhook) CALL dr_hook('MODE_SURF_FLOOD_FRAC:FLOOD_FRAC_VEG',1,zhook_handle)
!
END FUNCTION flood_frac_veg
!
!-------------------------------------------------------------------------------
!
!     ############################################################
      FUNCTION flood_frac_nat(PVEG,PFFG,PFFV,PFFLOOD) RESULT(PFF)
!     ############################################################
!
REAL, DIMENSION(:), INTENT(IN)  :: pveg    ! Vegetation cover fraction
REAL, DIMENSION(:), INTENT(IN)  :: pffg    ! Floodplain fraction over the ground
REAL, DIMENSION(:), INTENT(IN)  :: pffv    ! Floodplain fraction over vegetation
REAL, DIMENSION(:), INTENT(IN)  :: pfflood ! Effective floodplain fraction
REAL, DIMENSION(SIZE(PVEG))     :: pff     ! Floodplain fraction at the surface
REAL(KIND=JPRB) :: zhook_handle
!
IF (lhook) CALL dr_hook('MODE_SURF_FLOOD_FRAC:FLOOD_FRAC_NAT',0,zhook_handle)
pff(:) = pveg(:)*pffv(:) + (1-pveg(:))*pffg(:)
!
pff(:) = min(pff(:),pfflood(:))
IF (lhook) CALL dr_hook('MODE_SURF_FLOOD_FRAC:FLOOD_FRAC_NAT',1,zhook_handle)
!
END FUNCTION flood_frac_nat
!
!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
!
END MODULE mode_surf_flood_frac