mode_soil.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      MODULE mode_soil 
!     ################
!
!!****  *MODE_SOIL * - contains soil characteristics functions
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!    
!!    All clay and sand proportions are given in FRACTION!!!
!!    (not in percentages).
!!    
!!
!!    EXTERNAL
!!    --------
!!       
!!    IMPLICIT ARGUMENTS
!!    ------------------ 
!!
!!    REFERENCE
!!    ---------
!!      Book2 of the documentation (routine READ_GR_FIELD)
!!      
!!
!!    AUTHOR
!!    ------
!!      V. Masson       * Meteo France *
!!
!!    MODIFICATIONS
!!    -------------
!!      Original        3/12/98
!!
!!       02/2014       B. Decharme correction for W33 functions
!!                                 Add ANISO_FUNC
!-----------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
INTERFACE wsat_func
  MODULE PROCEDURE wsat_func_2d
  MODULE PROCEDURE wsat_func_1d
END INTERFACE
INTERFACE wwilt_func
  MODULE PROCEDURE wwilt_func_2d
  MODULE PROCEDURE wwilt_func_1d
END INTERFACE
INTERFACE wfc_func
  MODULE PROCEDURE wfc_func_2d
  MODULE PROCEDURE wfc_func_1d
END INTERFACE
INTERFACE w33_func
  MODULE PROCEDURE w33_func_2d
  MODULE PROCEDURE w33_func_1d
END INTERFACE
INTERFACE bcoef_func
  MODULE PROCEDURE bcoef_func_2d
  MODULE PROCEDURE bcoef_func_1d
END INTERFACE
INTERFACE matpotsat_func
  MODULE PROCEDURE matpotsat_func_2d
  MODULE PROCEDURE matpotsat_func_1d
END INTERFACE
INTERFACE hydcondsat_func
  MODULE PROCEDURE hydcondsat_func_2d
  MODULE PROCEDURE hydcondsat_func_1d
END INTERFACE
INTERFACE cgsat_func
  MODULE PROCEDURE cgsat_func_2d
  MODULE PROCEDURE cgsat_func_1d
END INTERFACE
INTERFACE c1sat_func
  MODULE PROCEDURE c1sat_func_2d
  MODULE PROCEDURE c1sat_func_1d
END INTERFACE
INTERFACE c2ref_func
  MODULE PROCEDURE c2ref_func_2d
  MODULE PROCEDURE c2ref_func_1d
END INTERFACE
INTERFACE c3_func
  MODULE PROCEDURE c3_func_2d
  MODULE PROCEDURE c3_func_1d
END INTERFACE
INTERFACE c4b_func
  MODULE PROCEDURE c4b_func_2d
  MODULE PROCEDURE c4b_func_1d
END INTERFACE
INTERFACE c4ref_func
  MODULE PROCEDURE c4ref_func_2d
  MODULE PROCEDURE c4ref_func_1d
END INTERFACE
INTERFACE acoef_func
  MODULE PROCEDURE acoef_func_2d
  MODULE PROCEDURE acoef_func_1d
END INTERFACE
INTERFACE pcoef_func
  MODULE PROCEDURE pcoef_func_2d
  MODULE PROCEDURE pcoef_func_1d
END INTERFACE
INTERFACE aniso_func
  MODULE PROCEDURE aniso_func_2d
  MODULE PROCEDURE aniso_func_1d
END INTERFACE
!
!-------------------------------------------------------------------------------
 CONTAINS
!
   FUNCTION wsat_func_2d(PCLAY,PSAND,HPEDOTF)
   USE modd_surf_par,   ONLY : xundef
   IMPLICIT NONE
   REAL, DIMENSION(:,:), INTENT(IN)     :: pclay   
   REAL, DIMENSION(:,:), INTENT(IN)     :: psand
   CHARACTER(LEN=4),     INTENT(IN)     :: hpedotf   
   REAL, DIMENSION(SIZE(PSAND,1),SIZE(PSAND,2)) :: wsat_func_2d
   REAL(KIND=JPRB) :: zhook_handle
   !
   IF (lhook) CALL dr_hook('MODE_SOIL:WSAT_FUNC_2D',0,zhook_handle)
   SELECT CASE (hpedotf)
     CASE ('CH78')
       WHERE(psand/=xundef) wsat_func_2d = 0.001 * (-108.*psand+494.305)
     CASE ('CO84')
       WHERE(psand/=xundef) wsat_func_2d = 0.505-0.142*psand-0.037*pclay            
   END SELECT   
   !
   WHERE (psand==xundef) wsat_func_2d = xundef
   IF (lhook) CALL dr_hook('MODE_SOIL:WSAT_FUNC_2D',1,zhook_handle)
   !
   END FUNCTION wsat_func_2d
   !
   !
   !
   FUNCTION wwilt_func_2d(PCLAY,PSAND,HPEDOTF)
   USE modd_surf_par,   ONLY : xundef
   IMPLICIT NONE
   REAL, DIMENSION(:,:), INTENT(IN)     :: pclay
   REAL, DIMENSION(:,:), INTENT(IN)     :: psand
   CHARACTER(LEN=4),     INTENT(IN)     :: hpedotf   
   REAL, DIMENSION(SIZE(PCLAY,1),SIZE(PCLAY,2)) :: wwilt_func_2d
   REAL(KIND=JPRB) :: zhook_handle
   !
   IF (lhook) CALL dr_hook('MODE_SOIL:WWILT_FUNC_2D',0,zhook_handle)
   SELECT CASE (hpedotf)
     CASE ('CH78')
       WHERE(pclay/=xundef) wwilt_func_2d = 37.1342e-3*(pclay*100.)**0.5
     CASE ('CO84')
       WHERE(pclay/=xundef) &
       wwilt_func_2d = 0.15333-0.147*psand+0.33*pclay-0.102*(pclay**2)
   END SELECT
   
   WHERE (pclay==xundef) wwilt_func_2d = xundef
   IF (lhook) CALL dr_hook('MODE_SOIL:WWILT_FUNC_2D',1,zhook_handle)
   !
   END FUNCTION wwilt_func_2d
   !
   !
   !
   FUNCTION wfc_func_2d(PCLAY,PSAND,HPEDOTF)
   USE modd_surf_par,   ONLY : xundef
   IMPLICIT NONE
   REAL, DIMENSION(:,:), INTENT(IN)     :: pclay
   REAL, DIMENSION(:,:), INTENT(IN)     :: psand
   CHARACTER(LEN=4),     INTENT(IN)     :: hpedotf   
   REAL, DIMENSION(SIZE(PCLAY,1),SIZE(PCLAY,2)) :: wfc_func_2d
   REAL(KIND=JPRB) :: zhook_handle
   !
   IF (lhook) CALL dr_hook('MODE_SOIL:WFC_FUNC_2D',0,zhook_handle)
   SELECT CASE (hpedotf)
     CASE ('CH78')
       WHERE(pclay/=xundef) wfc_func_2d = 89.0467e-3*(pclay*100.)**0.3496
     CASE ('CO84')
       WHERE(pclay/=xundef) &
         wfc_func_2d = 0.1537-0.1233*psand+0.2685*pclay**(1./3.)
   END SELECT
   
   WHERE (pclay==xundef) wfc_func_2d = xundef
   IF (lhook) CALL dr_hook('MODE_SOIL:WFC_FUNC_2D',1,zhook_handle)
   !
   END FUNCTION wfc_func_2d
   !
   !
   !
   FUNCTION w33_func_2d(PCLAY,PSAND,HPEDOTF)
   USE modd_surf_par,   ONLY : xundef
   IMPLICIT NONE
   REAL, DIMENSION(:,:), INTENT(IN)     :: pclay
   REAL, DIMENSION(:,:), INTENT(IN)     :: psand
   CHARACTER(LEN=4),     INTENT(IN)     :: hpedotf   
   REAL, DIMENSION(SIZE(PCLAY,1),SIZE(PCLAY,2)) :: w33_func_2d
   REAL(KIND=JPRB) :: zhook_handle
   !
   IF (lhook) CALL dr_hook('MODE_SOIL:W33_FUNC_2D',0,zhook_handle)
   SELECT CASE (hpedotf)
     CASE ('CH78')
       WHERE(pclay/=xundef) &
         w33_func_2d = 0.2298915119-0.4062575773*psand+0.0874218705*pclay    &
                     + 0.2942558675*psand**(1./3.)+0.0413771051*pclay**(1./3.)
     CASE ('CO84')
       WHERE(pclay/=xundef) &
         w33_func_2d = 0.2016592588-0.5785747196*psand+0.1113006987*pclay    &
                     + 0.4305771483*psand**(1./3.)-0.0080618093*pclay**(1./3.) 
   END SELECT
   
   WHERE (pclay==xundef) w33_func_2d = xundef
   IF (lhook) CALL dr_hook('MODE_SOIL:W33_FUNC_2D',1,zhook_handle)
   !
   END FUNCTION w33_func_2d
   !
   !
   !
   FUNCTION bcoef_func_2d(PCLAY,PSAND,HPEDOTF)
   USE modd_surf_par,   ONLY : xundef
   IMPLICIT NONE
   REAL, DIMENSION(:,:), INTENT(IN)     :: pclay
   REAL, DIMENSION(:,:), INTENT(IN)     :: psand
   CHARACTER(LEN=4),     INTENT(IN)     :: hpedotf   
   REAL, DIMENSION(SIZE(PCLAY,1),SIZE(PCLAY,2)) :: bcoef_func_2d
   REAL(KIND=JPRB) :: zhook_handle
   !
   IF (lhook) CALL dr_hook('MODE_SOIL:BCOEF_FUNC_2D',0,zhook_handle)
   SELECT CASE (hpedotf)
     CASE ('CH78')
       WHERE (pclay/=xundef) bcoef_func_2d = 13.7*pclay + 3.501
     CASE ('CO84')
       WHERE (pclay/=xundef) bcoef_func_2d = 3.10+15.7*pclay-0.3*psand
   END SELECT
   
   WHERE (pclay==xundef) bcoef_func_2d = xundef
   IF (lhook) CALL dr_hook('MODE_SOIL:BCOEF_FUNC_2D',1,zhook_handle)
   !
   END FUNCTION bcoef_func_2d
   !
   !
   !
   FUNCTION matpotsat_func_2d(PCLAY,PSAND,HPEDOTF)
   USE modd_surf_par,   ONLY : xundef
   IMPLICIT NONE
   REAL, DIMENSION(:,:), INTENT(IN)     :: pclay   
   REAL, DIMENSION(:,:), INTENT(IN)     :: psand
   CHARACTER(LEN=4),     INTENT(IN)     :: hpedotf   
   REAL, DIMENSION(SIZE(PSAND,1),SIZE(PSAND,2)) :: matpotsat_func_2d
   REAL(KIND=JPRB) :: zhook_handle
   !
   IF (lhook) CALL dr_hook('MODE_SOIL:MATPOTSAT_FUNC_2D',0,zhook_handle)
   SELECT CASE (hpedotf)
     CASE ('CH78')
       WHERE(psand/=xundef) matpotsat_func_2d = -0.01*(10.**(1.85 - 0.88*psand))
     CASE ('CO84')
       WHERE(psand/=xundef) &
         matpotsat_func_2d = -0.01*(10.0**(1.54-0.95*psand+0.63*(1.-psand-pclay)))
   END SELECT
   
   WHERE (psand==xundef) matpotsat_func_2d = xundef
   IF (lhook) CALL dr_hook('MODE_SOIL:MATPOTSAT_FUNC_2D',1,zhook_handle)
   !
   END FUNCTION matpotsat_func_2d
   !
   !
   FUNCTION hydcondsat_func_2d(PCLAY,PSAND,HPEDOTF)
   USE modd_surf_par,   ONLY : xundef
   IMPLICIT NONE
   REAL, DIMENSION(:,:), INTENT(IN)     :: pclay
   REAL, DIMENSION(:,:), INTENT(IN)     :: psand
   CHARACTER(LEN=4),     INTENT(IN)     :: hpedotf
   REAL, DIMENSION(SIZE(PCLAY,1),SIZE(PCLAY,2)) :: hydcondsat_func_2d
   REAL(KIND=JPRB) :: zhook_handle
   !
   IF (lhook) CALL dr_hook('MODE_SOIL:HYDCONDSAT_FUNC_2D',0,zhook_handle)
   SELECT CASE (hpedotf)
     CASE ('CH78')
       WHERE(pclay/=xundef)
         hydcondsat_func_2d = 1.0e-6*(10.0**(0.161874e+01                               &
                            - 0.581989e+01*pclay(:,:)    - 0.907123e-01*psand(:,:)      &
                            + 0.529268e+01*pclay(:,:)**2 + 0.120332e+01*psand(:,:)**2))
       END WHERE
     CASE ('CO84')
       WHERE(pclay/=xundef) &
         hydcondsat_func_2d = 0.0254*(10.0**(-0.6+1.26*psand-0.64*pclay))/3600.
   END SELECT
   !
   WHERE(pclay==xundef) hydcondsat_func_2d = xundef
   IF (lhook) CALL dr_hook('MODE_SOIL:HYDCONDSAT_FUNC_2D',1,zhook_handle)
   !
   END FUNCTION hydcondsat_func_2d
   !
   !
   !
   FUNCTION cgsat_func_2d(PCLAY,PSAND)
   USE modd_surf_par,   ONLY : xundef
   IMPLICIT NONE
   REAL, DIMENSION(:,:), INTENT(IN)     :: pclay
   REAL, DIMENSION(:,:), INTENT(IN)     :: psand
   REAL, DIMENSION(SIZE(PCLAY,1),SIZE(PCLAY,2)) :: cgsat_func_2d
   REAL(KIND=JPRB) :: zhook_handle
   !
   IF (lhook) CALL dr_hook('MODE_SOIL:CGSAT_FUNC_2D',0,zhook_handle)
   WHERE (pclay/=xundef)
     cgsat_func_2d = ( -1.5571*psand - 1.441*pclay + 4.70217 )*1.e-6
   ELSEWHERE
     cgsat_func_2d = xundef
   END WHERE
   IF (lhook) CALL dr_hook('MODE_SOIL:CGSAT_FUNC_2D',1,zhook_handle)
   !
   END FUNCTION cgsat_func_2d
   !
   !
   !
   FUNCTION c1sat_func_2d(PCLAY)
   USE modd_surf_par,   ONLY : xundef
   IMPLICIT NONE
   REAL, DIMENSION(:,:), INTENT(IN)     :: pclay
   REAL, DIMENSION(SIZE(PCLAY,1),SIZE(PCLAY,2)) :: c1sat_func_2d
   REAL(KIND=JPRB) :: zhook_handle
   !
   IF (lhook) CALL dr_hook('MODE_SOIL:C1SAT_FUNC_2D',0,zhook_handle)
   WHERE (pclay/=xundef)
     c1sat_func_2d = 0.01*(558.*pclay+84.88)
   ELSEWHERE
     c1sat_func_2d = xundef
   END WHERE
   IF (lhook) CALL dr_hook('MODE_SOIL:C1SAT_FUNC_2D',1,zhook_handle)
   !
   END FUNCTION c1sat_func_2d
   !
   !
   !
   FUNCTION c2ref_func_2d(PCLAY)
   USE modd_surf_par,   ONLY : xundef
   IMPLICIT NONE
   REAL, DIMENSION(:,:), INTENT(IN)     :: pclay
   REAL, DIMENSION(SIZE(PCLAY,1),SIZE(PCLAY,2)) :: c2ref_func_2d
   REAL(KIND=JPRB) :: zhook_handle
   !
   IF (lhook) CALL dr_hook('MODE_SOIL:C2REF_FUNC_2D',0,zhook_handle)
   WHERE (pclay/=xundef)
     c2ref_func_2d = 13.815*(pclay*100.)**(-0.954)
   ELSEWHERE
     c2ref_func_2d = xundef
   END WHERE
   IF (lhook) CALL dr_hook('MODE_SOIL:C2REF_FUNC_2D',1,zhook_handle)
   !
   END FUNCTION c2ref_func_2d
   !
   !
   !
   FUNCTION c3_func_2d(PCLAY)
   USE modd_surf_par,   ONLY : xundef
   IMPLICIT NONE
   REAL, DIMENSION(:,:), INTENT(IN)     :: pclay
   REAL, DIMENSION(SIZE(PCLAY,1),SIZE(PCLAY,2)) :: c3_func_2d
   REAL(KIND=JPRB) :: zhook_handle
   !
   IF (lhook) CALL dr_hook('MODE_SOIL:C3_FUNC_2D',0,zhook_handle)
   WHERE (pclay/=xundef)
     c3_func_2d = 5.327*(pclay*100.)**(-1.043)
   ELSEWHERE
     c3_func_2d = xundef
   END WHERE
   IF (lhook) CALL dr_hook('MODE_SOIL:C3_FUNC_2D',1,zhook_handle)
   !
   END FUNCTION c3_func_2d
   !
   !
   !
   FUNCTION c4b_func_2d(PCLAY)
   USE modd_surf_par,   ONLY : xundef
   IMPLICIT NONE
   REAL, DIMENSION(:,:), INTENT(IN)     :: pclay
   REAL, DIMENSION(SIZE(PCLAY,1),SIZE(PCLAY,2)) :: c4b_func_2d
   REAL(KIND=JPRB) :: zhook_handle
   !
   IF (lhook) CALL dr_hook('MODE_SOIL:C4B_FUNC_2D',0,zhook_handle)
   WHERE (pclay/=xundef)
     c4b_func_2d = 5.14+11.47*pclay
   ELSEWHERE
     c4b_func_2d = xundef
   END WHERE
   IF (lhook) CALL dr_hook('MODE_SOIL:C4B_FUNC_2D',1,zhook_handle)
   !
   END FUNCTION c4b_func_2d
   !
   !
   !
   FUNCTION c4ref_func_2d(PCLAY,PSAND,PD2,PD3)
   USE modd_surf_par,   ONLY : xundef
   IMPLICIT NONE
   REAL, DIMENSION(:,:), INTENT(IN)     :: pclay
   REAL, DIMENSION(:,:), INTENT(IN)     :: psand
   REAL, DIMENSION(:,:), INTENT(IN)     :: pd2
   REAL, DIMENSION(:,:), INTENT(IN)     :: pd3
   REAL, DIMENSION(SIZE(PCLAY,1),SIZE(PCLAY,2)) :: c4ref_func_2d
   REAL(KIND=JPRB) :: zhook_handle
   !
   IF (lhook) CALL dr_hook('MODE_SOIL:C4REF_FUNC_2D',0,zhook_handle)
   WHERE (pclay/=xundef .AND. pd2/=xundef .AND. pd3/=xundef)
     c4ref_func_2d = 10.0**(  4.421                                    &
                              + 0.4881  * psand     - 25.73  * pclay     &
                              + 5.927   *(psand**2) + 88.63  *(pclay**2) &
                              - 6.085   *(psand**3) - 81.33  *(pclay**3) )  
   !
   ! Scale the C4 coefficient as a function of grid geometry:
   ! NOTE that 2.0 represents the value for a coefficient which
   !      represents the baseline grid geometry with units of m**2
   !      so that the scaling is dimensionless.
   !
     c4ref_func_2d = c4ref_func_2d*2.0*(pd3-pd2)/(pd2*pd3*pd3)
   !
   ELSEWHERE
     c4ref_func_2d = xundef
   END WHERE
   IF (lhook) CALL dr_hook('MODE_SOIL:C4REF_FUNC_2D',1,zhook_handle)
   !
   END FUNCTION c4ref_func_2d
   !
   !
   !
   FUNCTION acoef_func_2d(PCLAY)
   USE modd_surf_par,   ONLY : xundef
   IMPLICIT NONE
   REAL, DIMENSION(:,:), INTENT(IN)     :: pclay
   REAL, DIMENSION(SIZE(PCLAY,1),SIZE(PCLAY,2)) :: acoef_func_2d
   REAL(KIND=JPRB) :: zhook_handle
   !
   IF (lhook) CALL dr_hook('MODE_SOIL:ACOEF_FUNC_2D',0,zhook_handle)
   WHERE (pclay/=xundef)
     acoef_func_2d = 732.42e-3*(pclay*100.)**(-0.539)
   ELSEWHERE
     acoef_func_2d = xundef
   END WHERE
   IF (lhook) CALL dr_hook('MODE_SOIL:ACOEF_FUNC_2D',1,zhook_handle)
   !
   END FUNCTION acoef_func_2d
   !
   !
   !
   FUNCTION pcoef_func_2d(PCLAY)
   USE modd_surf_par,   ONLY : xundef
   IMPLICIT NONE
   REAL, DIMENSION(:,:), INTENT(IN)     :: pclay
   REAL, DIMENSION(SIZE(PCLAY,1),SIZE(PCLAY,2)) :: pcoef_func_2d
   REAL(KIND=JPRB) :: zhook_handle
   !
   IF (lhook) CALL dr_hook('MODE_SOIL:PCOEF_FUNC_2D',0,zhook_handle)
   WHERE (pclay/=xundef)
     pcoef_func_2d = 13.4*pclay+3.4
   ELSEWHERE
     pcoef_func_2d = xundef
   END WHERE
   IF (lhook) CALL dr_hook('MODE_SOIL:PCOEF_FUNC_2D',1,zhook_handle)
   !
   END FUNCTION pcoef_func_2d
   !
   !
   !
   FUNCTION aniso_func_2d(PCLAY)
   USE modd_surf_par,   ONLY : xundef
   IMPLICIT NONE
   REAL, DIMENSION(:,:), INTENT(IN)     :: pclay
   REAL, DIMENSION(SIZE(PCLAY,1),SIZE(PCLAY,2)) :: aniso_func_2d
   REAL(KIND=JPRB) :: zhook_handle
   !
   IF (lhook) CALL dr_hook('MODE_SOIL:ANISO_FUNC_2D',0,zhook_handle)
   WHERE (pclay/=xundef)
     aniso_func_2d = 1.55+32.85*pclay(:,:)+65.637*pclay(:,:)**2
   ELSEWHERE
     aniso_func_2d = xundef
   END WHERE
   IF (lhook) CALL dr_hook('MODE_SOIL:ANISO_FUNC_2D',1,zhook_handle)
   !
   END FUNCTION aniso_func_2d
   
!                                                          
!
!-------------------------------------------------------------------------------
!
   FUNCTION wsat_func_1d(PCLAY,PSAND,HPEDOTF)
   USE modd_surf_par,   ONLY : xundef
   IMPLICIT NONE
   REAL, DIMENSION(:), INTENT(IN)     :: pclay   
   REAL, DIMENSION(:), INTENT(IN)     :: psand
   CHARACTER(LEN=4),   INTENT(IN)     :: hpedotf   
   REAL, DIMENSION(SIZE(PSAND))       :: wsat_func_1d
   REAL(KIND=JPRB) :: zhook_handle
   !
   IF (lhook) CALL dr_hook('MODE_SOIL:WSAT_FUNC_1D',0,zhook_handle)
   SELECT CASE (hpedotf)
     CASE ('CH78')
       WHERE(psand/=xundef) wsat_func_1d = 0.001 * (-108.*psand+494.305)
     CASE ('CO84')
       WHERE(psand/=xundef) wsat_func_1d = 0.505-0.142*psand-0.037*pclay            
   END SELECT   

   WHERE (psand==xundef) wsat_func_1d = xundef
   IF (lhook) CALL dr_hook('MODE_SOIL:WSAT_FUNC_1D',1,zhook_handle)
   !
   END FUNCTION wsat_func_1d
   !
   !
   !
   FUNCTION wwilt_func_1d(PCLAY,PSAND,HPEDOTF)
   USE modd_surf_par,   ONLY : xundef
   IMPLICIT NONE
   REAL, DIMENSION(:), INTENT(IN)     :: pclay
   REAL, DIMENSION(:), INTENT(IN)     :: psand
   CHARACTER(LEN=4),   INTENT(IN)     :: hpedotf   
   REAL, DIMENSION(SIZE(PCLAY))       :: wwilt_func_1d
   REAL(KIND=JPRB) :: zhook_handle
   !
   IF (lhook) CALL dr_hook('MODE_SOIL:WWILT_FUNC_1D',0,zhook_handle)
   SELECT CASE (hpedotf)
     CASE ('CH78')
       WHERE(pclay/=xundef) wwilt_func_1d = 37.1342e-3*(pclay*100.)**0.5
     CASE ('CO84')
       WHERE(pclay/=xundef) &
       wwilt_func_1d = 0.15333-0.147*psand+0.33*pclay-0.102*(pclay**2)
   END SELECT   
   !
   WHERE (pclay==xundef) wwilt_func_1d = xundef
   IF (lhook) CALL dr_hook('MODE_SOIL:WWILT_FUNC_1D',1,zhook_handle)
   !
   END FUNCTION wwilt_func_1d
   !
   !
   !
   FUNCTION wfc_func_1d(PCLAY,PSAND,HPEDOTF)
   USE modd_surf_par,   ONLY : xundef
   IMPLICIT NONE
   REAL, DIMENSION(:), INTENT(IN)     :: pclay
   REAL, DIMENSION(:), INTENT(IN)     :: psand
   CHARACTER(LEN=4),   INTENT(IN)     :: hpedotf   
   REAL, DIMENSION(SIZE(PCLAY))       :: wfc_func_1d
   REAL(KIND=JPRB) :: zhook_handle
   !
   IF (lhook) CALL dr_hook('MODE_SOIL:WFC_FUNC_1D',0,zhook_handle)
   SELECT CASE (hpedotf)
     CASE ('CH78')
       WHERE(pclay/=xundef) wfc_func_1d = 89.0467e-3*(pclay*100.)**0.3496
     CASE ('CO84')
       WHERE(pclay/=xundef) &
         wfc_func_1d = 0.1537-0.1233*psand+0.2685*pclay**(1./3.)
   END SELECT 
   !
   WHERE (pclay==xundef) wfc_func_1d = xundef
   IF (lhook) CALL dr_hook('MODE_SOIL:WFC_FUNC_1D',1,zhook_handle)
   !
   END FUNCTION wfc_func_1d
   !
   !
   !
   FUNCTION w33_func_1d(PCLAY,PSAND,HPEDOTF)
   USE modd_surf_par,   ONLY : xundef
   IMPLICIT NONE
   REAL, DIMENSION(:), INTENT(IN)     :: pclay
   REAL, DIMENSION(:), INTENT(IN)     :: psand
   CHARACTER(LEN=4),   INTENT(IN)     :: hpedotf   
   REAL, DIMENSION(SIZE(PCLAY))       :: w33_func_1d
   REAL(KIND=JPRB) :: zhook_handle
   !
   IF (lhook) CALL dr_hook('MODE_SOIL:W33_FUNC_1D',0,zhook_handle)
   SELECT CASE (hpedotf)
     CASE ('CH78')
       WHERE(pclay/=xundef) &
         w33_func_1d = 0.2298915119-0.4062575773*psand+0.0874218705*pclay    &
                     + 0.2942558675*psand**(1./3.)+0.0413771051*pclay**(1./3.)                     
     CASE ('CO84')
       WHERE(pclay/=xundef) &
         w33_func_1d = 0.2016592588-0.5785747196*psand+0.1113006987*pclay    &
                     + 0.4305771483*psand**(1./3.)-0.0080618093*pclay**(1./3.) 
   END SELECT
   
   WHERE (pclay==xundef) w33_func_1d = xundef
   IF (lhook) CALL dr_hook('MODE_SOIL:W33_FUNC_1D',1,zhook_handle)
   !
   END FUNCTION w33_func_1d  
   !
   !
   !   
   FUNCTION bcoef_func_1d(PCLAY,PSAND,HPEDOTF)
   USE modd_surf_par,   ONLY : xundef
   IMPLICIT NONE
   REAL, DIMENSION(:), INTENT(IN)     :: pclay
   REAL, DIMENSION(:), INTENT(IN)     :: psand
   CHARACTER(LEN=4),   INTENT(IN)     :: hpedotf   
   REAL, DIMENSION(SIZE(PCLAY))       :: bcoef_func_1d
   REAL(KIND=JPRB) :: zhook_handle
   !
   IF (lhook) CALL dr_hook('MODE_SOIL:BCOEF_FUNC_1D',0,zhook_handle)
   SELECT CASE (hpedotf)
     CASE ('CH78')
       WHERE (pclay/=xundef) bcoef_func_1d = 13.7*pclay + 3.501
     CASE ('CO84')
       WHERE (pclay/=xundef) bcoef_func_1d = 3.10+15.7*pclay-0.3*psand
   END SELECT   

   WHERE (pclay==xundef) bcoef_func_1d = xundef
   IF (lhook) CALL dr_hook('MODE_SOIL:BCOEF_FUNC_1D',1,zhook_handle)
   !
   END FUNCTION bcoef_func_1d
   !
   !
   !
   FUNCTION matpotsat_func_1d(PCLAY,PSAND,HPEDOTF)
   USE modd_surf_par,   ONLY : xundef
   IMPLICIT NONE
   REAL, DIMENSION(:), INTENT(IN)     :: pclay
   REAL, DIMENSION(:), INTENT(IN)     :: psand
   CHARACTER(LEN=4),   INTENT(IN)     :: hpedotf
   REAL, DIMENSION(SIZE(PSAND))       :: matpotsat_func_1d
   REAL(KIND=JPRB) :: zhook_handle
   !
   IF (lhook) CALL dr_hook('MODE_SOIL:MATPOTSAT_FUNC_1D',0,zhook_handle)
   SELECT CASE (hpedotf)
     CASE ('CH78')
       WHERE(psand/=xundef) matpotsat_func_1d = -0.01*(10.**(1.85 - 0.88*psand))
     CASE ('CO84')
       WHERE(psand/=xundef) &
         matpotsat_func_1d = -0.01*(10.0**(1.54-0.95*psand+0.63*(1.-psand-pclay)))
   END SELECT   

   WHERE (psand==xundef) matpotsat_func_1d = xundef
   IF (lhook) CALL dr_hook('MODE_SOIL:MATPOTSAT_FUNC_1D',1,zhook_handle)
   !
   END FUNCTION matpotsat_func_1d
   !
   !
   !
   FUNCTION hydcondsat_func_1d(PCLAY,PSAND,HPEDOTF)
   USE modd_surf_par,   ONLY : xundef
   IMPLICIT NONE
   REAL, DIMENSION(:), INTENT(IN)     :: pclay
   REAL, DIMENSION(:), INTENT(IN)     :: psand
   CHARACTER(LEN=4),   INTENT(IN)     :: hpedotf   
   REAL, DIMENSION(SIZE(PCLAY))       :: hydcondsat_func_1d
   REAL(KIND=JPRB) :: zhook_handle
   !
   IF (lhook) CALL dr_hook('MODE_SOIL:HYDCONDSAT_FUNC_1D',0,zhook_handle)
   SELECT CASE (hpedotf)
     CASE ('CH78')
       WHERE(pclay/=xundef)
         hydcondsat_func_1d = 1.0e-6*(10.0**(0.161874e+01                   &
                            - 0.581989e+01*pclay    - 0.907123e-01*psand    &
                            + 0.529268e+01*pclay**2 + 0.120332e+01*psand**2))
       END WHERE
     CASE ('CO84')
       WHERE(pclay/=xundef) &
         hydcondsat_func_1d = 0.0254*(10.0**(-0.6+1.26*psand-0.64*pclay))/3600.
   END SELECT   
   !
   WHERE(pclay==xundef) hydcondsat_func_1d = xundef
   IF (lhook) CALL dr_hook('MODE_SOIL:HYDCONDSAT_FUNC_1D',1,zhook_handle)
   !
   END FUNCTION hydcondsat_func_1d
   !
   !
   !
   FUNCTION cgsat_func_1d(PCLAY,PSAND)
   USE modd_surf_par,   ONLY : xundef
   IMPLICIT NONE
   REAL, DIMENSION(:), INTENT(IN)     :: pclay
   REAL, DIMENSION(:), INTENT(IN)     :: psand
   REAL, DIMENSION(SIZE(PCLAY))       :: cgsat_func_1d
   REAL(KIND=JPRB) :: zhook_handle
   !
   IF (lhook) CALL dr_hook('MODE_SOIL:CGSAT_FUNC_1D',0,zhook_handle)
   WHERE (pclay/=xundef)
     cgsat_func_1d = ( -1.5571*psand - 1.441*pclay + 4.70217 )*1.e-6
   ELSEWHERE
     cgsat_func_1d = xundef
   END WHERE
   IF (lhook) CALL dr_hook('MODE_SOIL:CGSAT_FUNC_1D',1,zhook_handle)
   !
   END FUNCTION cgsat_func_1d
   !
   !
   !
   FUNCTION c1sat_func_1d(PCLAY)
   USE modd_surf_par,   ONLY : xundef
   IMPLICIT NONE
   REAL, DIMENSION(:), INTENT(IN)     :: pclay
   REAL, DIMENSION(SIZE(PCLAY))       :: c1sat_func_1d
   REAL(KIND=JPRB) :: zhook_handle
   !
   IF (lhook) CALL dr_hook('MODE_SOIL:C1SAT_FUNC_1D',0,zhook_handle)
   WHERE (pclay/=xundef)
     c1sat_func_1d = 0.01*(558.*pclay+84.88)
   ELSEWHERE
     c1sat_func_1d = xundef
   END WHERE
   IF (lhook) CALL dr_hook('MODE_SOIL:C1SAT_FUNC_1D',1,zhook_handle)
   !
   END FUNCTION c1sat_func_1d
   !
   !
   !
   FUNCTION c2ref_func_1d(PCLAY)
   USE modd_surf_par,   ONLY : xundef
   IMPLICIT NONE
   REAL, DIMENSION(:), INTENT(IN)     :: pclay
   REAL, DIMENSION(SIZE(PCLAY))       :: c2ref_func_1d
   REAL(KIND=JPRB) :: zhook_handle
   !
   IF (lhook) CALL dr_hook('MODE_SOIL:C2REF_FUNC_1D',0,zhook_handle)
   WHERE (pclay/=xundef)
     c2ref_func_1d = 13.815*(pclay*100.)**(-0.954)
   ELSEWHERE
     c2ref_func_1d = xundef
   END WHERE
   IF (lhook) CALL dr_hook('MODE_SOIL:C2REF_FUNC_1D',1,zhook_handle)
   !
   END FUNCTION c2ref_func_1d
   !
   !
   !
   FUNCTION c3_func_1d(PCLAY)
   USE modd_surf_par,   ONLY : xundef
   IMPLICIT NONE
   REAL, DIMENSION(:), INTENT(IN)     :: pclay
   REAL, DIMENSION(SIZE(PCLAY))       :: c3_func_1d
   REAL(KIND=JPRB) :: zhook_handle
   !
   IF (lhook) CALL dr_hook('MODE_SOIL:C3_FUNC_1D',0,zhook_handle)
   WHERE (pclay/=xundef)
     c3_func_1d = 5.327*(pclay*100.)**(-1.043)
   ELSEWHERE
     c3_func_1d = xundef
   END WHERE
   IF (lhook) CALL dr_hook('MODE_SOIL:C3_FUNC_1D',1,zhook_handle)
   !
   END FUNCTION c3_func_1d
   !
   !
   !
   FUNCTION c4b_func_1d(PCLAY)
   USE modd_surf_par,   ONLY : xundef
   IMPLICIT NONE
   REAL, DIMENSION(:), INTENT(IN)     :: pclay
   REAL, DIMENSION(SIZE(PCLAY))       :: c4b_func_1d
   REAL(KIND=JPRB) :: zhook_handle
   !
   IF (lhook) CALL dr_hook('MODE_SOIL:C4B_FUNC_1D',0,zhook_handle)
   WHERE (pclay/=xundef)
     c4b_func_1d = 5.14+11.47*pclay
   ELSEWHERE
     c4b_func_1d = xundef
   END WHERE
   IF (lhook) CALL dr_hook('MODE_SOIL:C4B_FUNC_1D',1,zhook_handle)
   !
   END FUNCTION c4b_func_1d
   !
   !
   !
   FUNCTION c4ref_func_1d(PCLAY,PSAND,PD2,PD3)
   USE modd_surf_par,   ONLY : xundef
   IMPLICIT NONE
   REAL, DIMENSION(:), INTENT(IN)     :: pclay
   REAL, DIMENSION(:), INTENT(IN)     :: psand
   REAL, DIMENSION(:), INTENT(IN)     :: pd2
   REAL, DIMENSION(:), INTENT(IN)     :: pd3
   REAL, DIMENSION(SIZE(PCLAY))       :: c4ref_func_1d
   REAL(KIND=JPRB) :: zhook_handle
   !
   IF (lhook) CALL dr_hook('MODE_SOIL:C4REF_FUNC_1D',0,zhook_handle)
   WHERE (pclay/=xundef .AND. pd2/=xundef .AND. pd3/=xundef)
     c4ref_func_1d = 10.0**(  4.421                                    &
                              + 0.4881  * psand     - 25.73  * pclay     &
                              + 5.927   *(psand**2) + 88.63  *(pclay**2) &
                              - 6.085   *(psand**3) - 81.33  *(pclay**3) )  
   !
   ! Scale the C4 coefficient as a function of grid geometry:
   ! NOTE that 2.0 represents the value for a coefficient which
   !      represents the baseline grid geometry with units of m**2
   !      so that the scaling is dimensionless.
   !
     c4ref_func_1d = c4ref_func_1d*2.0*(pd3-pd2)/(pd2*pd3*pd3)
   !
   ELSEWHERE
     c4ref_func_1d = xundef
   END WHERE
   IF (lhook) CALL dr_hook('MODE_SOIL:C4REF_FUNC_1D',1,zhook_handle)
   !
   END FUNCTION c4ref_func_1d
   !
   !
   !
   FUNCTION acoef_func_1d(PCLAY)
   USE modd_surf_par,   ONLY : xundef
   IMPLICIT NONE
   REAL, DIMENSION(:), INTENT(IN)     :: pclay
   REAL, DIMENSION(SIZE(PCLAY))       :: acoef_func_1d
   REAL(KIND=JPRB) :: zhook_handle
   !
   IF (lhook) CALL dr_hook('MODE_SOIL:ACOEF_FUNC_1D',0,zhook_handle)
   WHERE (pclay/=xundef)
     acoef_func_1d = 732.42e-3*(pclay*100.)**(-0.539)
   ELSEWHERE
     acoef_func_1d = xundef
   END WHERE
   IF (lhook) CALL dr_hook('MODE_SOIL:ACOEF_FUNC_1D',1,zhook_handle)
   !
   END FUNCTION acoef_func_1d
   !
   !
   !
   FUNCTION pcoef_func_1d(PCLAY)
   USE modd_surf_par,   ONLY : xundef
   IMPLICIT NONE
   REAL, DIMENSION(:), INTENT(IN)     :: pclay
   REAL, DIMENSION(SIZE(PCLAY))       :: pcoef_func_1d
   REAL(KIND=JPRB) :: zhook_handle
   !
   IF (lhook) CALL dr_hook('MODE_SOIL:PCOEF_FUNC_1D',0,zhook_handle)
   WHERE (pclay/=xundef)
     pcoef_func_1d = 13.4*pclay+3.4
   ELSEWHERE
     pcoef_func_1d = xundef
   END WHERE
   IF (lhook) CALL dr_hook('MODE_SOIL:PCOEF_FUNC_1D',1,zhook_handle)
   !
   END FUNCTION pcoef_func_1d
   !
   !
   !
   FUNCTION aniso_func_1d(PCLAY)
   USE modd_surf_par,   ONLY : xundef
   IMPLICIT NONE
   REAL, DIMENSION(:), INTENT(IN)     :: pclay
   REAL, DIMENSION(SIZE(PCLAY))       :: aniso_func_1d
   REAL(KIND=JPRB) :: zhook_handle
   !
   IF (lhook) CALL dr_hook('MODE_SOIL:ANISO_FUNC_1D',0,zhook_handle)
   WHERE (pclay/=xundef)
     aniso_func_1d = 1.55+32.85*pclay(:)+65.637*pclay(:)**2
   ELSEWHERE
     aniso_func_1d = xundef
   END WHERE
   IF (lhook) CALL dr_hook('MODE_SOIL:ANISO_FUNC_1D',1,zhook_handle)
   !
   END FUNCTION aniso_func_1d
                                                          
!-------------------------------------------------------------------------------
!
END MODULE mode_soil