mode_crodebug.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!##########################
MODULE mode_crodebug
!##########################
!
!! *MODE_CRODEBUG*
!!
!! PURPOSE
!! -------
! CROCUS debugging mode

!!
!!**  IMPLICIT ARGUMENTS
!!    ------------------
!!       NONE          
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!      M. Lafaysse       * Meteo France *
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    11/06/2012
!!      Modification M Lafaysse 03/10/2012 : add energy balance control
!--------------------------------------------------------------------------------
!
IMPLICIT NONE
!
! To stop simulation if mass/energy balances not closed
LOGICAL,PARAMETER :: LPSTOPBALANCE = .FALSE.
!
LOGICAL :: LCRODAILYINFO = .FALSE.
LOGICAL :: LCRODEBUG = .FALSE.
LOGICAL :: LCRODEBUGDETAILS = .FALSE.
LOGICAL :: LCRODEBUGATM = .FALSE.
LOGICAL :: LPRINTGRAN = .FALSE.
LOGICAL :: LCONTROLBALANCE = .FALSE.
!
INTEGER :: NPOINTCRODEBUG = 1
INTEGER :: NTIMECRODEBUG = 0
INTEGER :: NENDCRODEBUG = 99999999
INTEGER :: NHOURCRODEBUG = 0
!
REAL :: XLATCRODEBUG = -999.
REAL :: XLONCRODEBUG = -999.
!
REAL :: XWARNING_MASSBALANCE=1.E-4
REAL :: XWARNING_ENERGYBALANCE=1.E-4
!
 CONTAINS
!
SUBROUTINE init_crodebug (I)
! Check environment variables to activate crocus debugging mode if required
!
!
!
USE modd_isba_n, ONLY : isba_t
!
!
TYPE(isba_t), INTENT(INOUT) :: i
!
 CHARACTER(1) :: ycrocus_info,ycrocus_debug,ycrocus_balance
 CHARACTER(8) :: ycrocus_debug_time
 CHARACTER(2) :: ycrocus_debug_hour
 CHARACTER(6) :: ycrocus_debug_point
 CHARACTER(12) :: ycrocus_debug_lat,ycrocus_debug_lon
!
IF (i%TSNOW%SCHEME=='CRO') THEN
  !
  CALL getenv("CROCUS_INFO",ycrocus_info)
  SELECT CASE (ycrocus_info)
    CASE ("1")
      print*,"CROCUS : print daily informations."
      lcrodailyinfo=.true.
    CASE default
      lcrodailyinfo=.false.
  END SELECT
  !
  CALL getenv("CROCUS_DEBUG",ycrocus_debug)
  SELECT CASE (ycrocus_debug)
    CASE ("1")
      print*,"CROCUS DEBUGGING MODE : print snow profile at the end of each time step"
      lcrodebug=.true.
      lcrodebugdetails=.false.
      lcrodebugatm=.false.
      lprintgran=.false.
    CASE ("2")
      print*,"CROCUS DEBUGGING MODE : print snow profile after each CROCUS routine"
      lcrodebug=.true.
      lcrodebugdetails=.true.
      lcrodebugatm=.false.
      lprintgran=.false.
    CASE ("3")
      print*,"CROCUS DEBUGGING MODE : print snow profile at the end of each &
            & time step and forcing data"
      lcrodebug=.true.
      lcrodebugdetails=.false.
      lcrodebugatm=.true.
      lprintgran=.false.
    CASE ("4")
      print*,"CROCUS DEBUGGING MODE : print snow profile after each CROCUS routine &
            & and forcing data"
      lcrodebug=.true.
      lcrodebugdetails=.true.
      lcrodebugatm=.true.
      lprintgran=.false.
    CASE ("5")
      print*,"CROCUS DEBUGGING MODE : print everything"
      lcrodebug=.true.
      lcrodebugdetails=.true.
      lcrodebugatm=.true.
      lprintgran=.true.
    CASE default
      lcrodebug=.false.
      lcrodebugdetails=.false.
      lcrodebugatm=.false.
      lprintgran=.false.
  END SELECT
  !
  CALL getenv("CROCUS_BALANCE",ycrocus_balance)
  SELECT CASE (ycrocus_balance)
    CASE ("1")
      print*,"CROCUS DEBUGGING MODE : print mass and energy balance diagnostics."
      lcontrolbalance=.true.
    CASE default
      lcontrolbalance=.false.
  END SELECT
  !
  IF (lcrodebug .OR. lcontrolbalance) THEN
    !
    CALL getenv("CROCUS_DEBUG_DATE",ycrocus_debug_time)
    IF ( len_trim(ycrocus_debug_time)>0 ) THEN
      READ(ycrocus_debug_time,'(I8)')ntimecrodebug
      print*,"after the date : ",ntimecrodebug
    ELSE
      ntimecrodebug = 0
    END IF
    !
    CALL getenv("CROCUS_DEBUG_DATE_END",ycrocus_debug_time)
    IF (len_trim(ycrocus_debug_time)>0) THEN
      READ(ycrocus_debug_time,'(I8)')nendcrodebug
      print*,"before the date : ",nendcrodebug
    ELSE
      nendcrodebug = 99999999
    END IF
    !
    CALL getenv("CROCUS_DEBUG_HOUR",ycrocus_debug_hour)
    IF (len_trim(ycrocus_debug_hour)>0) THEN
      READ(ycrocus_debug_hour,'(I2)')nhourcrodebug
      print*,"after the hour : ",nhourcrodebug
    ELSE
      nhourcrodebug = 0
    END IF
    !
    CALL getenv("CROCUS_DEBUG_POINT",ycrocus_debug_point)
    IF (len_trim(ycrocus_debug_point)>0) THEN
      READ(ycrocus_debug_point,'(I6)')npointcrodebug
    ELSE
      npointcrodebug = 1
    END IF
    !
    CALL getenv("CROCUS_DEBUG_LAT",ycrocus_debug_lat)
    IF (len_trim(ycrocus_debug_lat)>0) THEN
      READ(ycrocus_debug_lat,*)xlatcrodebug
    ELSE 
      xlatcrodebug = -999.
    END IF
    !
    CALL getenv("CROCUS_DEBUG_LON",ycrocus_debug_lon)
    IF (len_trim(ycrocus_debug_lon)>0) THEN
      READ(ycrocus_debug_lon,*)xloncrodebug
    ELSE
      xloncrodebug=-999.
    END IF
    !
  END IF
  !
END IF
!
END SUBROUTINE init_crodebug
!
SUBROUTINE getpoint_crodebug(PLAT,PLON,KDEBUG)
! gives the point to output for debugging
REAL,DIMENSION(:),INTENT(IN) :: plat,plon
INTEGER,INTENT(OUT) :: kdebug
!
kdebug=minloc( (plat-xlatcrodebug)**2 + (plon-xloncrodebug)**2, 1 )
!
END SUBROUTINE getpoint_crodebug
!
END MODULE mode_crodebug