mode_coare30_psi.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
MODULE mode_coare30_psi
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
 INTERFACE psifctu
  MODULE PROCEDURE psifunctu
 END INTERFACE
 INTERFACE psifctt
  MODULE PROCEDURE psifunctt
 END INTERFACE
!
 CONTAINS
!
!---------------------------------------------------------------------------------------
!
!#######################################################################################
FUNCTION psifunctu(PZL) RESULT(PSIFCTU)
!#######################################################################################
!
!****  *PSIFUNCTU*
!
!       PURPOSE
!       -------
!       To evaluate the stability function psi for wind speed (if KID=1) or
!       for temperature or humidity profiles (if KID.ne.1) from stability parameter
!       z/L. 
!
!       EXTERNAL
!       --------
!
!       IMPLICIT ARGUMENTS
!       ------------------
!
!       REFERENCE
!       ---------
!       Lik79 : Liu, W. T., K. B. Katsaros, and J. A. Businger, 1979: 
!       Bulk parameterization of air-sea exchanges of heat and water vapor including 
!       the molecular constraints at the interface. J. Atm. Sci., 36, 1722--1735.
!       DyH70 : Dyer, A. J., and B. B. Hicks, 1970: Flux-gradient relationship 
!       in the constant flux layer. Quart. J. Roy. Meteor. Soc., 96, 715--721.
!
!       AUTHOR
!       ------
!
!       MODIFICATIONS
!       -------------
!-------------------------------------------------------------------------------
IMPLICIT NONE
!
!        0.  Declaration
!
!        0.1 declaration of arguments
!
REAL, DIMENSION(:), INTENT(IN)    :: pzl  !Obukhovs stability parameter
REAL, DIMENSION(SIZE(PZL))        :: psifctu !function psi value
!        0.2 declaration of local variables
REAL, DIMENSION(SIZE(PZL)) :: zy,zx,zc,zpsic,zpsik,zf
INTEGER :: jj
REAL(KIND=JPRB) :: zhook_handle
!
IF (lhook) CALL dr_hook('MODE_COARE30_PSI:PSIFUNCTU',0,zhook_handle)
DO jj=1,SIZE(pzl)
  IF(pzl(jj)<0.) THEN
    zx(jj)   = (1.0 - 15. * pzl(jj))**0.25         ! Kansas unstable
    zpsik(jj)= 2.0 * log((1.0+zx(jj)       )/2.0) &
             +       log((1.0+zx(jj)*zx(jj))/2.0) &
             - 2.0 * atan(zx(jj)) &
             + 2.0 * atan(1.0)  
    !
    zy(jj)   = (1.0 - 10.15 * pzl(jj))**0.3333     ! Convective
    zpsic(jj)= 1.5 * log((zy(jj)*zy(jj)+zy(jj)+1.)/3.) &
             - (3.0**0.5) * atan((2.0*zy(jj)+1.0)/(3.0**0.5)) &
             + 4.0        * atan(1.0)/(3.0**0.5) 
    !
    zf(jj)   =pzl(jj) * pzl(jj) / (1.0+pzl(jj)*pzl(jj)) 
    !
    psifctu(jj)=(1.-zf(jj)) * zpsik(jj) + zf(jj) * zpsic(jj)
  ELSE
    zc(jj)=min(50.,0.35*pzl(jj))           ! Stable
    psifctu(jj)=-((1.+1.*pzl(jj))**1. + 0.6667*(pzl(jj)-14.28)/exp(zc(jj)) + 8.525)
  ENDIF
ENDDO
IF (lhook) CALL dr_hook('MODE_COARE30_PSI:PSIFUNCTU',1,zhook_handle)

END FUNCTION psifunctu
!---------------------------------------------------------------------------------------
!
!#######################################################################################
FUNCTION psifunctt(PZL) RESULT(PSIFCTT)
!#######################################################################################
!
!****  *PSIFUNCTU*
!
!       PURPOSE
!       -------
!       To evaluate the stability function psi for wind speed (if KID=1) or
!       for temperature or humidity profiles (if KID.ne.1) from stability parameter
!       z/L. 
!
!       EXTERNAL
!       --------
!
!       IMPLICIT ARGUMENTS
!       ------------------
!
!       REFERENCE
!       ---------
!       Lik79 : Liu, W. T., K. B. Katsaros, and J. A. Businger, 1979: 
!       Bulk parameterization of air-sea exchanges of heat and water vapor including 
!       the molecular constraints at the interface. J. Atm. Sci., 36, 1722--1735.
!       DyH70 : Dyer, A. J., and B. B. Hicks, 1970: Flux-gradient relationship 
!       in the constant flux layer. Quart. J. Roy. Meteor. Soc., 96, 715--721.
!
!       AUTHOR
!       ------
!
!       MODIFICATIONS
!       -------------
!-------------------------------------------------------------------------------
IMPLICIT NONE
!
!        0.  Declaration
!
!        0.1 declaration of arguments
!
REAL, DIMENSION(:), INTENT(IN)    :: pzl  !Obukhovs stability parameter
REAL, DIMENSION(SIZE(PZL))        :: psifctt !function psi value
!        0.2 declaration of local variables
REAL, DIMENSION(SIZE(PZL)) :: zx,zy,zc,zpsic,zpsik,zf
INTEGER :: jj
REAL(KIND=JPRB) :: zhook_handle
!
IF (lhook) CALL dr_hook('MODE_COARE30_PSI:PSIFUNCTT',0,zhook_handle)
DO jj=1,SIZE(pzl)
  IF(pzl(jj)<0.) THEN
    zx(jj)   = (1. - 15. * pzl(jj))**.5         ! Kansas unstable
    zpsik(jj)= 2.0 * log((1.0+zx(jj)       )/2.0)
    !
    zy(jj)   = (1.0 - 34.15 * pzl(jj))**0.3333  ! Convective
    zpsic(jj)= 1.5 * log((zy(jj)*zy(jj)+zy(jj)+1.0)/3.) &
             - (3.0**0.5) * atan((2.0*zy(jj)+1.0)/(3.0**0.5)) &
             + 4.0        * atan(1.0)/(3.0**0.5)  
    !
    zf(jj)   = pzl(jj) * pzl(jj) / (1.0+pzl(jj)*pzl(jj)) 
    !
    psifctt(jj)= (1.-zf(jj)) * zpsik(jj) + zf(jj) * zpsic(jj)
  ELSE
    zc(jj)=min(50.,0.35*pzl(jj))           ! Stable
    psifctt(jj)=-((1.+2.*pzl(jj)/3.)**1.5 + 0.6667*(pzl(jj)-14.28)/exp(zc(jj)) + 8.525)
  ENDIF
ENDDO
IF (lhook) CALL dr_hook('MODE_COARE30_PSI:PSIFUNCTT',1,zhook_handle)

END FUNCTION psifunctt
!
END MODULE mode_coare30_psi