latlonmask_ign.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     ##################################
      SUBROUTINE latlonmask_ign(KGRID_PAR,PGRID_PAR,OLATLONMASK)
!     ##################################
!
!!**** *LATLONMASK* builds the latitude and longitude mask including the grid
!!
!!    PURPOSE
!!    -------
!!
!!    METHOD
!!    ------
!!
!!    A simple method is used :
!!
!!   XMIN, XMAX, YMIN, YMAX are calculated for the grid 
!!   This domain is extended to account for deformation between lambert and lat lon.
!!   All lat lon values in this extended domains are set to true in the mask.
!!   
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!      E. Martin       Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!      
!!      Original        10/2007  
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
USE mode_gridtype_ign
USE modd_ign, ONLY : xexpand
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
INTEGER,                       INTENT(IN)  :: kgrid_par   ! size of PGRID_PAR
REAL,    DIMENSION(KGRID_PAR), INTENT(IN)  :: pgrid_par   ! parameters defining this grid
LOGICAL, DIMENSION(720,360),   INTENT(OUT) :: olatlonmask ! mask where data are to be read
!
!*    0.2    Declaration of local variables
!            ------------------------------
!
REAL                              :: zxmin    ! minimum of X for domain
REAL                              :: zxmax    ! maximum of X for domain
REAL                              :: zymin    ! minimum of Y for domain
REAL                              :: zymax    ! maximum of Y for domain
REAL, DIMENSION(720,360)          :: zx_mask  ! mask points X value
REAL, DIMENSION(720,360)          :: zy_mask  ! mask points Y value
REAL, DIMENSION(720,360)          :: zlon_mask! mask points longitudes
REAL, DIMENSION(720,360)          :: zlat_mask! mask points latitudes
REAL, DIMENSION(:), ALLOCATABLE   :: zx       ! X Lambert   coordinate
REAL, DIMENSION(:), ALLOCATABLE   :: zy       ! Y Lambert   coordinate
REAL, DIMENSION(:), ALLOCATABLE   :: zdx      ! Grid dimension in X 
REAL, DIMENSION(:), ALLOCATABLE   :: zdy      ! Grid dimension in Y 
!
INTEGER                           :: ilambert ! Lambert projection type
INTEGER                           :: il       ! Number og grid points
INTEGER                           :: jlat, jlon
REAL(KIND=JPRB) :: zhook_handle
!----------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('LATLONMASK_IGN',0,zhook_handle)
olatlonmask(:,:) = .false.
!
!-------------------------------------------------------------------------------
!
!*      1.   Limits of the domain in Lambert IGN coordinates 
!            (including expansion factor)
!            ------------------------------------------------
!
     CALL get_gridtype_ign(pgrid_par,klambert=ilambert,kl=il)
!
     ALLOCATE(zx(il))
     ALLOCATE(zy(il))
     ALLOCATE(zdx(il))
     ALLOCATE(zdy(il))
!
     CALL get_gridtype_ign(pgrid_par,px=zx,py=zy,pdx=zdx,pdy=zdy)
!
!*    2.     Limits of grid meshes in x and y
!            --------------------------------
!
     zxmin = minval(zx(:)-zdx(:)/2.) - xexpand
     zxmax = maxval(zx(:)+zdx(:)/2.) + xexpand
     zymin = minval(zy(:)-zdy(:)/2.) - xexpand
     zymax = maxval(zy(:)+zdy(:)/2.) + xexpand
     DEALLOCATE(zx )
     DEALLOCATE(zy )
     DEALLOCATE(zdx)
     DEALLOCATE(zdy)
!
!-------------------------------------------------------------------------------
!
!*      2.   Definition of the coordinates at center of the mask meshes
!            ----------------------------------------------------------
!
!
zlon_mask(:,:)= spread( (/ (  jlon     /2. - 0.25 , jlon=1,720 ) /) , dim=2, ncopies=360 )
zlat_mask(:,:)= spread( (/ ( (jlat-180)/2. - 0.25 , jlat=1,360 ) /) , dim=1, ncopies=720 )
!
!*      3.   Longitude correction (-180 /+180 )
!            --------------------------------
!
zlon_mask(:,:)=zlon_mask(:,:)+nint((-zlon_mask(:,:))/360.)*360.
!
!
!*      4.   X and Y of the points of the mask
!            ---------------------------------
!
 CALL get_gridtype_ign(pgrid_par, klambert=ilambert)
DO jlat=1,SIZE(zlat_mask,2)
  CALL xy_ign(ilambert,zx_mask(:,jlat),zy_mask(:,jlat),          &
                zlat_mask(:,jlat),zlon_mask(:,jlat)   )  

END DO
!
!*      5.   Are the points in the domain?
!            ----------------------------
!
WHERE (        zx_mask(:,:) >= zxmin .AND. zx_mask(:,:) <= zxmax   &
           .AND. zy_mask(:,:) >= zymin .AND. zy_mask(:,:) <= zymax )  
  olatlonmask(:,:) = .true.
END WHERE
IF (lhook) CALL dr_hook('LATLONMASK_IGN',1,zhook_handle)
!
!-------------------------------------------------------------------------------
END SUBROUTINE latlonmask_ign