latlon_gridtype_ign.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########################################################################
      SUBROUTINE latlon_gridtype_ign(KGRID_PAR,KL,PGRID_PAR,PLAT,PLON,PMESH_SIZE,PDIR)
!     #########################################################################
!
!!****  *LATLON_GRIDTYPE_IGN* - routine to compute the horizontal geographic fields
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      E. Martin   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    10/2007 
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
USE modd_csts,     ONLY : xpi
USE modd_ign, ONLY : xa, xdelty
!
USE mode_gridtype_ign
!
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
INTEGER,                    INTENT(IN)  :: kgrid_par  ! size of PGRID_PAR
INTEGER,                    INTENT(IN)  :: kl         ! number of points
REAL, DIMENSION(KGRID_PAR), INTENT(IN)  :: pgrid_par  ! parameters defining this grid
REAL, DIMENSION(KL),        INTENT(OUT) :: plat       ! latitude  (degrees)
REAL, DIMENSION(KL),        INTENT(OUT) :: plon       ! longitude (degrees)
REAL, DIMENSION(KL),        INTENT(OUT) :: pmesh_size ! mesh size (m2)
REAL, DIMENSION(KL),        INTENT(OUT) :: pdir ! direction of main grid Y axis (deg. from N, clockwise)
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
REAL, DIMENSION(:),   ALLOCATABLE :: zx       ! X Lambert coordinate
REAL, DIMENSION(:),   ALLOCATABLE :: zy       ! Y  Lambertcoordinate
REAL, DIMENSION(:),   ALLOCATABLE :: zmap     ! map factor
REAL, DIMENSION(:),   ALLOCATABLE :: zdx      ! size in X Lambert coordinate
REAL, DIMENSION(:),   ALLOCATABLE :: zdy      ! size in Y Lambert coordinate
REAL, DIMENSION(:),   ALLOCATABLE :: zydelty  ! Y + DELTY Lambert coordinate            
REAL, DIMENSION(:),   ALLOCATABLE :: zlatdy   ! latitude 
REAL, DIMENSION(:),   ALLOCATABLE :: zlondy   ! longitude
!
INTEGER :: ilambert ! Lambert type
REAL(KIND=JPRB) :: zhook_handle
!---------------------------------------------------------------------------
!
!*       1.    Projection and 2D grid parameters
!              ---------------------------------
!
IF (lhook) CALL dr_hook('LATLON_GRIDTYPE_IGN',0,zhook_handle)
ALLOCATE(zx(SIZE(plat)))
ALLOCATE(zy(SIZE(plat)))
ALLOCATE(zdx(SIZE(plat)))
ALLOCATE(zdy(SIZE(plat)))
!
 CALL get_gridtype_ign(pgrid_par,klambert=ilambert,px=zx,py=zy,pdx=zdx,pdy=zdy      )
!
!---------------------------------------------------------------------------
!
!*       2.    Computation of latitude and longitude
!              -------------------------------------
!
 CALL latlon_ign(ilambert,zx,zy,plat,plon)
!
!-----------------------------------------------------------------------------
!
!*       3.    Compute grid size (2D array)
!              -----------------
!
!        3.1   Map factor
!              ----------
!
ALLOCATE(zmap(SIZE(plat)))
!
 CALL map_factor_ign(ilambert,zx,zy,zmap)
!
!        3.2   Grid size
!              ---------
!
pmesh_size(:) = zdx(:) * zdy(:) / zmap(:)**2
!
!-----------------------------------------------------------------------------
!
!*       4.    Direction of Y axis (from North) for each grid point
!              ----------------------------------------------------
!
!* the following formulae is given for clockwise angles.
ALLOCATE(zydelty(SIZE(plat)))
ALLOCATE(zlatdy(SIZE(plat)))
ALLOCATE(zlondy(SIZE(plat)))
zydelty=zy+xdelty
 CALL latlon_ign(ilambert,zx,zydelty,zlatdy,zlondy)
!
pdir(:)= atan( (xa(ilambert)*(zlondy(:)-plon(:))*xpi/180.) / xdelty) * xpi/180.
!
!---------------------------------------------------------------------------
DEALLOCATE(zx)
DEALLOCATE(zy)
DEALLOCATE(zmap)
DEALLOCATE(zdx)
DEALLOCATE(zdy)
DEALLOCATE(zydelty)
DEALLOCATE(zlatdy)
DEALLOCATE(zlondy)
IF (lhook) CALL dr_hook('LATLON_GRIDTYPE_IGN',1,zhook_handle)
!---------------------------------------------------------------------------
!
END SUBROUTINE latlon_gridtype_ign