latlon_gridtype_conf_proj.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########################################################################
      SUBROUTINE latlon_gridtype_conf_proj(KGRID_PAR,KL,PGRID_PAR,PLAT,PLON,PMESH_SIZE,PDIR)
!     #########################################################################
!
!!****  *LATLON_GRIDTYPE_CONF_PROJ* - routine to compute the horizontal geographic fields
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      V. Masson   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004 
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
USE modd_csts,     ONLY : xpi
!
USE mode_gridtype_conf_proj
!
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
INTEGER,                    INTENT(IN)  :: kgrid_par  ! size of PGRID_PAR
INTEGER,                    INTENT(IN)  :: kl         ! number of points
REAL, DIMENSION(KGRID_PAR), INTENT(IN)  :: pgrid_par  ! parameters defining this grid
REAL, DIMENSION(KL),        INTENT(OUT) :: plat       ! latitude  (degrees)
REAL, DIMENSION(KL),        INTENT(OUT) :: plon       ! longitude (degrees)
REAL, DIMENSION(KL),        INTENT(OUT) :: pmesh_size ! mesh size (m2)
REAL, DIMENSION(KL),        INTENT(OUT) :: pdir ! direction of main grid Y axis (deg. from N, clockwise)
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
REAL                              :: zlat0    ! reference latitude
REAL                              :: zlon0    ! reference longitude
REAL                              :: zrpk     ! projection parameter 
!                                             !   K=1 : stereographic north pole
!                                             ! 0<K<1 : Lambert, north hemisphere
!                                             !   K=0 : Mercator
!                                             !-1<K<0 : Lambert, south hemisphere
!                                             !   K=-1: stereographic south pole
REAL                              :: zbeta    ! angle between grid and reference longitude
REAL                              :: zlator   ! latitude  of point of coordinates X=0, Y=0
REAL                              :: zlonor   ! longitude of point of coordinates X=0, Y=0
REAL, DIMENSION(:),   ALLOCATABLE :: zx       ! X conformal coordinate
REAL, DIMENSION(:),   ALLOCATABLE :: zy       ! Y conformal coordinate
REAL, DIMENSION(:),   ALLOCATABLE :: zmap     ! map factor
REAL, DIMENSION(:),   ALLOCATABLE :: zdx      ! size in X conformal coordinate
REAL, DIMENSION(:),   ALLOCATABLE :: zdy      ! size in Y conformal coordinate
REAL(KIND=JPRB) :: zhook_handle
!
!---------------------------------------------------------------------------
!
!*       1.    Projection and 2D grid parameters
!              ---------------------------------
!
IF (lhook) CALL dr_hook('LATLON_GRIDTYPE_CONF_PROJ',0,zhook_handle)
ALLOCATE(zx(SIZE(plat)))
ALLOCATE(zy(SIZE(plat)))
ALLOCATE(zdx(SIZE(plat)))
ALLOCATE(zdy(SIZE(plat)))
!
 CALL get_gridtype_conf_proj(pgrid_par,zlat0,zlon0,zrpk,zbeta,&
                              zlator,zlonor,                   &
                              px=zx,py=zy,pdx=zdx,pdy=zdy      )  
!
!---------------------------------------------------------------------------
!
!*       2.    Computation of latitude and longitude
!              -------------------------------------
!
 CALL latlon_conf_proj(zlat0,zlon0,zrpk,zbeta,zlator,zlonor,zx,zy,plat,plon)
!
!-----------------------------------------------------------------------------
!
!*       3.    Compute grid size (2D array)
!              -----------------
!
!        3.1   Map factor
!              ----------
!
ALLOCATE(zmap(SIZE(plat)))
!
 CALL map_factor_conf_proj(zlat0,zrpk,plat,zmap)
!
!        3.2   Grid size
!              ---------
!
pmesh_size(:) = zdx(:) * zdy(:) / zmap(:)**2
!
!-----------------------------------------------------------------------------
!
!*       4.    Direction of Y axis (from North) for each grid point
!              ----------------------------------------------------
!
!* the following formulae is given for clockwise angles.
pdir(:) = zrpk * (plon(:) - zlon0) - zbeta
!
WHERE (pdir(:) <0.)    pdir = pdir + 360.
WHERE (pdir(:) >=360.) pdir = pdir - 360.
!
!---------------------------------------------------------------------------
DEALLOCATE(zx)
DEALLOCATE(zy)
DEALLOCATE(zmap)
DEALLOCATE(zdx)
DEALLOCATE(zdy)
IF (lhook) CALL dr_hook('LATLON_GRIDTYPE_CONF_PROJ',1,zhook_handle)
!---------------------------------------------------------------------------
!
END SUBROUTINE latlon_gridtype_conf_proj