lailoss.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
    SUBROUTINE lailoss(PVEG, PSEFOLD, PANMAX, PANDAY, PANFM, PBIOMASS)  
!   ###############################################################
!!****  *LAILOSS*  
!!
!!    PURPOSE
!!    -------
!
!     Calculates the time change in LAI due to senesence 
!     and cutting: ie losses/decreases to LAI. This in turn
!     reduces the dry biomass of the canopy.
!              
!!**  METHOD
!!    ------
!     Calvet at al (1997) [from model of Jacobs(1994)]
!!
!!    EXTERNAL
!!    --------
!!    none
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!      
!!    none
!!
!!    REFERENCE
!!    ---------
!!
!!    Calvet et al. (1997)
!!      
!!    AUTHOR
!!    ------
!!
!!      A. Boone           * Meteo-France *
!!      (following Belair)
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    27/10/97 
!!      Modified    12/03/04  by P LeMoigne: ZXSEFOLD in days
!!      L. Jarlan   27/10/04  add RHOA as input to express PANMAX in
!!                            kgCO2 m-2s-1 instead of kgCO2 kgAir-1 m s-1
!!      P Le Moigne 09/2005 AGS modifs of L. Jarlan
!!      S. Lafont   03/2011 modification for consistency with nitro_decline
!!
!-------------------------------------------------------------------------------
!
USE modd_csts,  ONLY : xday
USE modd_co2v_par, ONLY: xmc, xmco2, xpcco2
!
!*       0.     DECLARATIONS
!               ------------
!
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
REAL,   DIMENSION(:),INTENT(IN)    :: pveg      ! vegetation fraction
REAL,   DIMENSION(:), INTENT(IN)   :: psefold   ! e-folding time for senescence (s)
REAL,   DIMENSION(:), INTENT(IN)   :: panmax    ! maximum photosynthesis rate
REAL,   DIMENSION(:), INTENT(IN)   :: panday    ! daily net CO2 accumulation
!
REAL,   DIMENSION(:), INTENT(INOUT) :: panfm    ! maximum leaf assimilation
REAL,   DIMENSION(:), INTENT(INOUT) :: pbiomass ! total dry canopy biomass 
!
!*      0.2    declarations of local variables
!
REAL,    DIMENSION(SIZE(PSEFOLD))  :: zxsefold, zxm
REAL                               :: zbmcoef
REAL(KIND=JPRB) :: zhook_handle
!
!-----------------------------------------------------------------
IF (lhook) CALL dr_hook('LAILOSS',0,zhook_handle)
!
zbmcoef     = xmc/(xmco2*xpcco2)
!
! Once a day (at midnight), adjust biomass:
! ----------------------------------------
!
WHERE((pveg(:)>0) )
  !
  ! leaf life expectancy
  !
  zxsefold(:) = psefold(:)*min(1.0, panfm(:)/panmax(:))/xday
  !
  ! avoid possible but unlikely division by zero
  !
  zxsefold(:) = max(1.0e-8,zxsefold(:))
  !
  ! limitation of leaf life expectancy
  !
  zxsefold(:) = max(5.,zxsefold(:))
  !
  ! senesence of active biomass
  !
  zxm(:)      = pbiomass(:)*(1.0-exp(-1.0/zxsefold(:)))
  !
  ! decrease biomass:
  !
  pbiomass(:) = pbiomass(:) - zxm(:)
  !
  ! same modification than nitro_decline.f90
  ! now the assimilation is added here
  ! in that way laigain.f90 is consistant between the different carbon options.
  pbiomass(:) =  pbiomass(:) + panday(:)*zbmcoef
  !
  ! maximum leaf assimilation (kgCO2 kgAir-1 m s-1):
  !
  panfm(:)    = 0.0
  !
END WHERE
!
IF (lhook) CALL dr_hook('LAILOSS',1,zhook_handle)
!
END SUBROUTINE lailoss