isba_emis_meb.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     ##########################################################################
      SUBROUTINE isba_emis_meb(PPSN, PPSNA, PSIGMA_F, PSIGMA_FN,  &
                               pemis_n, pemis                     )
!     ##########################################################################
!
!!****  *ISBA_EMIS_MEB*  
!!
!!    PURPOSE
!!    -------
!
!     Calculates the total emissivity for a MEB patch
!     
!!**  METHOD
!!    ------
!
!!    EXTERNAL
!!    --------
!!
!!    none
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------ 
!!
!!
!!      
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!      A. Boone           * Meteo-France *
!!      P. Samuelsson      * SMHI *
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    07/2014 
!!
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
USE modd_isba_par,       ONLY : xemissoil, xemisveg
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
REAL, DIMENSION(:),   INTENT(IN)   :: ppsn, ppsna
!                                     PPSN     = fraction of snow on ground and understory vegetation          (-)
!                                     PPSNA    = fraction of vegetation canopy buried by ground-based snowpack (-)
!
REAL, DIMENSION(:),   INTENT(IN)   :: psigma_f, psigma_fn, pemis_n
!
REAL, DIMENSION(:),   INTENT(OUT)  :: pemis
!                                     PEMIS    = effective (aggregated) net surface emissivity (-)
!
!*      0.2    declarations of local variables
!
REAL, DIMENSION(SIZE(PPSN))        :: zpn, zemisg, zemisn, zsigma_fa
!                                     ZPN       = working snow fraction (-)
!                                     ZEMISG    = understory surface emissivity for computing effective value (-)
!                                     ZEMISN    = snowpack surface emissivity for computing effective value (-)
!                                     ZSIGMA_FA = zworking shading factor (-)
!
REAL(KIND=JPRB) :: zhook_handle
!-------------------------------------------------------------------------------
!
!*       0.     Initialization:
!               ---------------
!
IF (lhook) CALL dr_hook('ISBA_EMIS_MEB',0,zhook_handle)
!-------------------------------------------------------------------------------
!
!*       1.     Compute effective emissivity
!               ----------------------------
! (this is consistent with the LW flux computations in isba_lwnet_meb.f90):
!
zpn(:)        = ppsn(:)*(1.-ppsna(:))
zsigma_fa(: ) = (1.-zpn(:))*psigma_f(:) + zpn(:)*psigma_fn(:)
zemisg(:)     = zsigma_fa(:)*xemisveg + (1.0-zsigma_fa(:))*xemissoil
!
zpn(:)        = ppsn(:) + ppsna(:)*(1.0-ppsn(:))
zsigma_fa(: ) = (1.-zpn(:))*psigma_f(:) + zpn(:)*psigma_fn(:)
zemisn(:)     = zsigma_fa(:)*xemisveg + (1.0-zsigma_fa(:))*pemis_n(:)
!
pemis(:)      = (1.0-ppsn(:))*zemisg(:) + ppsn(:)*zemisn(:)
!
!
IF (lhook) CALL dr_hook('ISBA_EMIS_MEB',1,zhook_handle)
!
END SUBROUTINE isba_emis_meb