init_water_sbl.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
    SUBROUTINE init_water_sbl(KLVL, PPA, PPS, PTA, PQA, PRHOA, PU, PV, PRAIN, PSNOW,     &
                              psfth, psftq, pzref, puref, pts, pz0, pz,                  &
                              pt, pq, pwind, ptke, pp)
!     #################################################################################
!
!!****  *INIT_WATER_SBL* - inits water SBL profiles
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     S. Riette
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    03/2010
!!------------------------------------------------------------------
!
USE modd_csts,             ONLY : xcpd, xrd, xp00, xtt, xg
USE modd_canopy_turb,      ONLY : xalpsbl
!
USE modi_cls_wind
USE modi_cls_tq
USE modi_water_flux
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
INTEGER           , INTENT(IN)  :: klvl      ! number      of levels in canopy
REAL, DIMENSION(:), INTENT(IN)  :: ppa       ! pressure at forcing level             (Pa)
REAL, DIMENSION(:), INTENT(IN)  :: pps       ! pressure at atmospheric model surface (Pa)
REAL, DIMENSION(:), INTENT(IN)  :: pta       ! air temperature forcing               (K)
REAL, DIMENSION(:), INTENT(IN)  :: pqa       ! air humidity forcing                  (kg/m3)
REAL, DIMENSION(:), INTENT(IN)  :: prhoa     ! air density                           (kg/m3)
REAL, DIMENSION(:), INTENT(IN)  :: pu        ! zonal wind                            (m/s)
REAL, DIMENSION(:), INTENT(IN)  :: pv        ! meridian wind                         (m/s)
REAL, DIMENSION(:), INTENT(IN)  :: psnow     ! snow precipitation                    (kg/m2/s)
REAL, DIMENSION(:), INTENT(IN)  :: prain     ! liquid precipitation                  (kg/m2/s)
REAL, DIMENSION(:), INTENT(IN)  :: pzref     ! height of T,q forcing                 (m)
REAL, DIMENSION(:), INTENT(IN)  :: puref     ! height of wind forcing                (m)
REAL, DIMENSION(:), INTENT(IN)  :: pts       ! surface temperature
REAL, DIMENSION(:,:), INTENT(IN):: pz        ! height of middle of each level grid   (m)
REAL, DIMENSION(:), INTENT(INOUT) :: pz0       ! roughness length
REAL, DIMENSION(:), INTENT(OUT) :: psfth     ! flux of heat                          (W/m2)
REAL, DIMENSION(:), INTENT(OUT) :: psftq     ! flux of water vapor                   (kg/m2/s)
!
REAL, DIMENSION(:,:), INTENT(OUT) :: pt   ! temperature at each level in SBL      (m/s)
REAL, DIMENSION(:,:), INTENT(OUT) :: pq   ! humidity    at each level in SBL      (kg/m3)
REAL, DIMENSION(:,:), INTENT(OUT) :: pwind! wind        at each level in SBL      (m/s)
REAL, DIMENSION(:,:), INTENT(OUT) :: ptke ! Tke         at each level in SBL      (m2/s2)
REAL, DIMENSION(:,:), INTENT(OUT) :: pp   ! pressure    at each level in SBL      (kg/m3)
!
!*      0.2    declarations of local variables
!
!* forcing variables
!
REAL, DIMENSION(SIZE(PTA))   :: zwind    ! lowest atmospheric level wind speed           (m/s)
REAL, DIMENSION(SIZE(PTA))   :: zexna    ! Exner function at lowest SBL scheme level     (-)
REAL, DIMENSION(SIZE(PTA))   :: zqa      ! specific humidity                             (kg/m3)
!
! SBL turbulence scheme
!
REAL, DIMENSION(SIZE(PTA))   :: zustar       ! friction velocity (m/s)
!
REAL, DIMENSION(SIZE(PTA))   :: zexns
REAL, DIMENSION(SIZE(PTA))   :: zqsat
REAL, DIMENSION(SIZE(PTA))   :: zcd
REAL, DIMENSION(SIZE(PTA))   :: zcdn
REAL, DIMENSION(SIZE(PTA))   :: zch
REAL, DIMENSION(SIZE(PTA))   :: zri
REAL, DIMENSION(SIZE(PTA))   :: zresa_sea
REAL, DIMENSION(SIZE(PTA))   :: zz0h
REAL, DIMENSION(SIZE(PTA))   :: zcls_wind_zon
REAL, DIMENSION(SIZE(PTA))   :: zcls_wind_mer
REAL, DIMENSION(SIZE(PTA))   :: ztnm
REAL, DIMENSION(SIZE(PTA))   :: zqnm
REAL, DIMENSION(SIZE(PTA))   :: zhunm
REAL, DIMENSION(SIZE(PTA))   :: zhu
INTEGER                      :: j
INTEGER                      :: jlayer
LOGICAL                      :: ghandle_sic = .false. ! no sea-ice model
REAL(KIND=JPRB) :: zhook_handle
!-------------------------------------------------------------------------------------
!
!*     1.2     Initialisation at first time step
!              ---------------------------------
!
IF (lhook) CALL dr_hook('INIT_WATER_SBL',0,zhook_handle)
!
zexna(:) = (ppa(:)/xp00)**(xrd/xcpd)
zexns(:) = (pps(:)/xp00)**(xrd/xcpd)
zqa(:) = pqa(:) / prhoa(:)
zwind(:) = sqrt(pu**2+pv**2)
!
!We choose the case CSEA_FLUX=DIRECT to compute CD, CDN, CH, RI and ZZ0H
!Iterative computation of PZ0 / CD, CDN, CH, ZH0
DO j=1,5
  CALL water_flux(pz0,                                            &
                  pta, zexna, prhoa, pts, zexns, zqa, prain,      &
                  psnow, xtt, zwind, pzref, puref,                &
                  pps, ghandle_sic, zqsat,  psfth, psftq, zustar, &
                  zcd, zcdn, zch, zri, zresa_sea, zz0h            )
ENDDO
!
!Initialisation of T, Q, Wind and TKE on all canopy levels
zhu(:)=1.
DO jlayer=1,klvl
  !
  CALL cls_tq(pta, zqa, ppa, pps, pzref, zcd, zch, zri, pts, zhu, zz0h, &
              pz(:,jlayer), ztnm, zqnm, zhunm                           )
  !
  pt(:,jlayer)=ztnm
  pq(:,jlayer)=zqnm
  !
  CALL cls_wind(pu, pv, puref, zcd, zcdn, zri, pz(:,jlayer), &
                zcls_wind_zon, zcls_wind_mer                 )
  !
  pwind(:,jlayer) = sqrt( zcls_wind_zon(:)**2 + zcls_wind_mer(:)**2 )
  ptke(:,jlayer) = xalpsbl * zcd(:) * ( pu(:)**2 + pv(:)**2 )
  pp(:,jlayer) = ppa(:) + xg * prhoa(:) * ( pz(:,klvl) - pz(:,jlayer) )
  !
ENDDO
!
IF (lhook) CALL dr_hook('INIT_WATER_SBL',1,zhook_handle)
!
END SUBROUTINE init_water_sbl