init_snow_lw.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE init_snow_lw(PEMISSN,TPSNOW)
!     #######################################
!
!!****  *INIT_SNOW_LW* - routine to initialize snow surf. temp and emissivity
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      V. Masson   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2003 
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
USE modd_type_snow
USE modd_surf_par,   ONLY : xundef
USE modd_csts,       ONLY : xtt, xlmtt
!
USE mode_snow3l
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
REAL,                 INTENT(IN)    :: pemissn ! snow emissivity
TYPE(surf_snow),      INTENT(INOUT) :: tpsnow  ! snow characteristics
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
INTEGER :: jpatch ! loop counter on tiles
REAL(KIND=JPRB) :: zhook_handle
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('INIT_SNOW_LW',0,zhook_handle)
DO jpatch=1,SIZE(tpsnow%WSNOW,3)
!
!*       1.    Emissivity
!              ----------
!
  IF (tpsnow%SCHEME=='1-L' .OR. tpsnow%SCHEME=='3-L' .OR. tpsnow%SCHEME=='CRO') THEN
    WHERE(tpsnow%WSNOW(:,1,jpatch)==0. .OR. tpsnow%WSNOW(:,1,jpatch)==xundef )
      tpsnow%EMIS (:,jpatch)= xundef
    ELSEWHERE
      tpsnow%EMIS (:,jpatch)= pemissn
    END WHERE
  END IF
!
!*      2.     Surface temperature
!              -------------------
!
  IF (tpsnow%SCHEME=='1-L') THEN
    WHERE(tpsnow%WSNOW(:,1,jpatch)==0. .OR. tpsnow%WSNOW(:,1,jpatch)==xundef )
      tpsnow%TS (:,jpatch)= xundef
    ELSEWHERE
      tpsnow%TS(:,jpatch) = tpsnow%T(:, tpsnow%NLAYER,jpatch)
    END WHERE
  END IF
!
  IF (tpsnow%SCHEME=='3-L' .OR. tpsnow%SCHEME=='CRO') THEN
    WHERE(tpsnow%WSNOW(:,1,jpatch)==0. .OR. tpsnow%WSNOW(:,1,jpatch)==xundef )
      tpsnow%TS (:,jpatch)= xundef
    ELSEWHERE
      tpsnow%TS(:,jpatch) = xtt +  (tpsnow%HEAT(:,1,jpatch)              &
                                      +  xlmtt * tpsnow%RHO(:,1,jpatch) )  &
                                      /  snow3lscap(tpsnow%RHO(:,1,jpatch))  
      tpsnow%TS(:,jpatch) = min(xtt, tpsnow%TS(:,jpatch))
    END WHERE
  END IF
!
END DO
IF (lhook) CALL dr_hook('INIT_SNOW_LW',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE init_snow_lw