init_output_oln.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE init_output_ol_n (YSC)
!     ######################
!
!!****  *INIT_OUTPUT_OL* Keep in memory the netcdf ID of the output files
!!
!!    PURPOSE
!!    -------
!
!!
!!**  IMPLICIT ARGUMENTS
!!    ------------------
!!      None 
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!      F. Habets   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      modified 05/04 by P. LeMoigne *Meteo France*
!!      modified 06/10 by S. Faroux *Meteo France*
!!=================================================================
!
!*       0.   DECLARATIONS
!             ------------
!
USE modd_surfex_n, ONLY : surfex_t
!
USE modd_ol_fileid, ONLY : xvar_to_fileout,         &
                           xid, xout,               &
                           xvar_surf, xid_surf,     &
                           xvar_nature, xid_nature, &
                           xvar_sea, xid_sea,       &
                           xvar_water, xid_water,   &
                           xvar_town, xid_town  
USE modd_io_surf_ol
!
USE modd_surfex_mpi, ONLY : nrank, npio
!
USE modi_init_outfn_flake_n
USE modi_init_outfn_isba_n
USE modi_init_outfn_sea_n
USE modi_init_outfn_surf_atm_n
USE modi_init_outfn_teb_n
USE modi_init_outfn_water_n
!
USE modd_surfex_mpi, ONLY : wlog_mpi
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!
TYPE(surfex_t), INTENT(INOUT) :: ysc
!
!
INTEGER           :: iret
INTEGER           :: iluout
REAL(KIND=JPRB)  :: zhook_handle
!------------------------------------------------------------------------------ 
IF (lhook) CALL dr_hook('INIT_OUTPUT_OL_N',0,zhook_handle)
!
iluout = 0
!
IF (nrank==npio) THEN
  !
  IF (.NOT. ldefined_surf_atm) THEN         
    CALL init_outfn_surf_atm_n(ysc%CHE, ysc%CHN, ysc%CHU, ysc%DGU, ysc%UG, ysc%U, ysc%SV, &
                               "NC    ",iluout)
    CALL allocate_fill_var(xvar_surf, xid_surf)
    ldefined_surf_atm=.true.
  ENDIF
  !
  IF (.NOT. ldefined_nature .AND. ysc%U%NDIM_NATURE>0) THEN
    IF (ysc%U%CNATURE=='ISBA  '.OR.ysc%U%CNATURE=='TSZ0  ') THEN 
      CALL init_outfn_isba_n(ysc%IM%CHI, ysc%IM%DGEI, ysc%IM%DGI, ysc%IM%DGMI, &
                             ysc%DGU, ysc%IM%GB, ysc%IM%ICP, ysc%IM%I, ysc%UG, ysc%U, &
                             "NC    ",iluout)
      CALL allocate_fill_var(xvar_nature, xid_nature)
    ENDIF
    ldefined_nature=.true.
  ENDIF
  !
  IF (.NOT. ldefined_sea .AND. ysc%U%NDIM_SEA>0) THEN
    IF (ysc%U%CSEA=='SEAFLX') THEN 
      CALL init_outfn_sea_n(ysc%SM%CHS, ysc%SM%DGO, ysc%SM%DGS, ysc%SM%DGSI, &
                            ysc%DGU, ysc%SM%O, ysc%SM%S, ysc%SM%SSB, ysc%UG, ysc%U, &
                            "NC    ",iluout)
      CALL allocate_fill_var(xvar_sea, xid_sea)
    ENDIF
    ldefined_sea=.true.
  ENDIF
  !
  IF (.NOT. ldefined_water .AND. ysc%U%NDIM_WATER>0) THEN
    IF (ysc%U%CWATER=='WATFLX') CALL init_outfn_water_n(ysc%WM%CHW, ysc%DGU, ysc%WM%DGW, &
                                                   ysc%UG, ysc%U, ysc%WM%W, ysc%WM%WSB, &
                                                   "NC    ",iluout)
    IF (ysc%U%CWATER=='FLAKE ') CALL init_outfn_flake_n(ysc%WM%CHW, ysc%FM%DGF, ysc%DGU, &
                                                    ysc%FM%F, ysc%FM%FSB, ysc%UG, ysc%U, &
                                                   "NC    ",iluout)
    IF (ysc%U%CWATER=='WATFLX' .OR. ysc%U%CWATER=='FLAKE') CALL allocate_fill_var(xvar_water, xid_water)
    ldefined_water=.true.
  ENDIF
  !
  IF (.NOT. ldefined_town .AND. ysc%U%NDIM_TOWN>0) THEN
    IF (ysc%U%CTOWN=='TEB   ') THEN 
      CALL init_outfn_teb_n(ysc%TM%BOP, ysc%TM%CHT, ysc%TM%DGMTO, ysc%DGU, ysc%TM%DGT, ysc%TM%DGUT, &
                            ysc%UG, ysc%U, ysc%TM%TCP, ysc%GDM%TGD, ysc%GDM%TGDO, ysc%GRM%TGR, &
                            ysc%GRM%TGRO, ysc%TM%T, ysc%TM%TOP, ysc%GDM%TVG, &
                            "NC    ",iluout)
      CALL allocate_fill_var(xvar_town, xid_town)
    ENDIF
    ldefined_town=.true.
  ENDIF
  !
ENDIF
!
!------------------------------------------------------------------------------
IF (lhook) CALL dr_hook('INIT_OUTPUT_OL_N',1,zhook_handle)
 CONTAINS 
!------------------------------------------------------------------------------
SUBROUTINE allocate_fill_var(HVAR, NVAR)
  
 CHARACTER(LEN=20),DIMENSION(:), POINTER :: hvar
INTEGER*4, DIMENSION(:), POINTER :: nvar
REAL(KIND=JPRB) :: zhook_handle

IF (lhook) CALL dr_hook('ALLOCATE_FILL_VAR',0,zhook_handle)
ALLOCATE(hvar(xout))
ALLOCATE(nvar(xout))
hvar(:)=xvar_to_fileout(1:xout)
nvar(:)=xid(1:xout)
IF (lhook) CALL dr_hook('ALLOCATE_FILL_VAR',1,zhook_handle)

END SUBROUTINE allocate_fill_var
!------------------------------------------------------------------------------
!
END SUBROUTINE init_output_ol_n