init_isba_mixpar.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE init_isba_mixpar (DTCO, DTI, IG, I, &
                                   hisba,kdecade,kdecade2,pcover,ocover,hphoto,hsftype)
!     ##############################################################
!
!!**** *INIT_ISBA_MIXPAR* 
!!
!!    PURPOSE
!!    -------
!!   This routine makes pre-calculations relative to dependances between
!!    parameters. 
!! 
!!    METHOD
!!    ------
!!   First are treated parameters varying in time. Then, other ones. 
!!   * XPAR_VEGTYPE is needed as soon as 1 LDATA_ is true to use av_pgd_param. 
!!   * XPAR_LAI is needed as soon as av_pgd_param is called with YLAI
!!   * XPAR_VEG is needed as soon as av_pgd_param is called with YVEG
!!   * XPAR_H_TREE is needed as soon as Z0 is calculated by ini_data_param by point
!!
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    S. Faroux        Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original    16/11/10
!!    P. Samuelsson  10/2014  MEB
!!
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_data_isba_n, ONLY : data_isba_t
USE modd_isba_grid_n, ONLY : isba_grid_t
USE modd_isba_n, ONLY : isba_t
!
USE modd_surf_par,       ONLY : xundef
USE modd_data_cover_par, ONLY : nvegtype
!
!
USE modd_data_cover,     ONLY : xdata_lai, xdata_h_tree, xdata_veg,         &
                                xdata_irrig, xdata_watsup
!     
USE modi_ini_data_param
USE modi_av_pgd
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
!
TYPE(data_cover_t), INTENT(INOUT) :: dtco
TYPE(data_isba_t), INTENT(INOUT) :: dti
TYPE(isba_grid_t), INTENT(INOUT) :: ig
TYPE(isba_t), INTENT(INOUT) :: i
!
 CHARACTER(LEN=*), INTENT(IN)          :: hisba 
INTEGER,                INTENT(IN)    :: kdecade
INTEGER,                INTENT(OUT)   :: kdecade2
REAL, DIMENSION(:,:),   INTENT(IN)    :: pcover
LOGICAL, DIMENSION(:),  INTENT(IN)    :: ocover
 CHARACTER(LEN=*),       INTENT(IN)    :: hphoto  ! type of photosynthesis
 CHARACTER(LEN=*),       INTENT(IN)    :: hsftype ! nature / garden
!
!
!*    0.2    Declaration of local variables
!            ------------------------------
!
REAL, DIMENSION(19)   :: xstress   ! 1. if defensive /0. if offensive
REAL, DIMENSION(19)   :: xstress_noagri   ! 1. if defensive /0. if offensive
!
 CHARACTER(LEN=3)  :: ytree, ynat, yveg
!
INTEGER               :: jvegtype
!
INTEGER               :: isize_lmeb_patch  ! Number of patches with MEB=true
!
!*    0.3    Declaration of namelists
!            ------------------------
!
REAL(KIND=JPRB) :: zhook_handle
!
DATA xstress        /1.,1.,1.,0.,1.,0.,1.,0.,1.,0.,0.,0.,0.,0.,1.,0.,1.,0.,0./
DATA xstress_noagri /1.,1.,1.,0.,1.,0.,0.,0.,0.,0.,0.,0.,0.,0.,1.,0.,1.,0.,0./
!-------------------------------------------------------------------------------
!
!*    1.      Initializations
!             ---------------
!
IF (lhook) CALL dr_hook('INIT_ISBA_MIXPAR',0,zhook_handle)
!
isize_lmeb_patch=count(i%LMEB_PATCH(:))
!
IF (.NOT.dti%LDATA_MIXPAR) THEN
  IF (lhook) CALL dr_hook('INIT_ISBA_MIXPAR',1,zhook_handle)
  RETURN
ENDIF
!
IF (hsftype=='NAT') THEN
  ynat='NAT'
  ytree='TRE'
  yveg='VEG'
ELSEIF (hsftype=='GRD') THEN
  ynat='GRD'
  ytree='GRT'
  yveg='GRV'
ENDIF
!
kdecade2 = kdecade
IF (dti%NTIME==2) kdecade2 = kdecade2 + 10 
kdecade2 = (kdecade2-1) * dti%NTIME / 36 + 1
IF (dti%NTIME==2 .AND. kdecade2==3) kdecade2 = 1
!
!          1. Arrays needed further
!          ------------------------
!
!XPAR_VEGTYPE will be needed to use ini_data_param by point
IF (.NOT.dti%LDATA_VEGTYPE) THEN
  ALLOCATE(dti%XPAR_VEGTYPE   (ig%NDIM,nvegtype))
  DO jvegtype=1,nvegtype
    CALL av_pgd(dtco, &
                 dti%XPAR_VEGTYPE(:,jvegtype),pcover ,dtco%XDATA_VEGTYPE(:,jvegtype),ynat,'ARI',ocover)
  END DO
ENDIF
!
!xpar_lai: needed for av_pgd_param with YLAI
IF (.NOT.dti%LDATA_LAI) THEN
  ALLOCATE(dti%XPAR_LAI(ig%NDIM,dti%NTIME,nvegtype))
  CALL av_pgd(dtco, &
                 dti%XPAR_LAI(:,kdecade2,:),pcover,xdata_lai(:,kdecade,:),yveg,'ARI',ocover,kdecade=kdecade2)
ENDIF
!veg
IF (.NOT.dti%LDATA_VEG) THEN
  ALLOCATE(dti%XPAR_VEG(ig%NDIM,dti%NTIME,nvegtype))
  IF (dti%LDATA_LAI) THEN
    CALL ini_data_param(dti%XPAR_VEGTYPE,oagri_to_grass=i%LAGRI_TO_GRASS,plai=dti%XPAR_LAI,pveg_out=dti%XPAR_VEG)
    dti%LDATA_VEG=.true.
  ELSE
    CALL av_pgd(dtco, &
                 dti%XPAR_VEG(:,kdecade2,:),pcover,xdata_veg(:,kdecade,:),ynat,'ARI',ocover,kdecade=kdecade2)
  ENDIF
ENDIF
!ht: needed to calculate z0, if not calculated yet during extrapolation 
IF (.NOT.dti%LDATA_H_TREE .AND. .NOT.dti%LDATA_Z0 .AND. dti%LDATA_LAI) THEN
  ALLOCATE(dti%XPAR_H_TREE(ig%NDIM,nvegtype))
  CALL av_pgd(dtco, &
                 dti%XPAR_H_TREE,pcover,xdata_h_tree,ytree,'ARI',ocover,kdecade=kdecade2)
  dti%LDATA_H_TREE = .true.
ENDIF
!
!dg: initialization for ROOTFRAC
!ROOTFRAC depends on ROOT_DEPTH, DG, ROOT_EXT, ROOT_LIN
IF (.NOT.dti%LDATA_ROOTFRAC .AND. hisba=='DIF' .AND. dti%LDATA_ROOT_DEPTH) THEN
  !
  IF (.NOT.dti%LDATA_ROOT_EXTINCTION) THEN
    ALLOCATE(dti%XPAR_ROOT_EXTINCTION(ig%NDIM,nvegtype))
    CALL ini_data_param(dti%XPAR_VEGTYPE,oagri_to_grass=i%LAGRI_TO_GRASS,proot_extinction=dti%XPAR_ROOT_EXTINCTION)
    dti%LDATA_ROOT_EXTINCTION = .true.
  ENDIF
  !
  IF (.NOT.dti%LDATA_ROOT_LIN) THEN
    ALLOCATE(dti%XPAR_ROOT_LIN(ig%NDIM,nvegtype))
    CALL ini_data_param(dti%XPAR_VEGTYPE,oagri_to_grass=i%LAGRI_TO_GRASS,proot_lin=dti%XPAR_ROOT_LIN)
    dti%LDATA_ROOT_LIN = .true.
  ENDIF
  !
ENDIF
!
! MEB roots
IF (.NOT.dti%LDATA_ROOTFRACGV .AND. hisba=='DIF' .AND. dti%LDATA_ROOT_DEPTHGV) THEN
  !
  IF (.NOT.dti%LDATA_ROOT_EXTINCTIONGV) THEN
    ALLOCATE(dti%XPAR_ROOT_EXTINCTIONGV(ig%NDIM,nvegtype))
    CALL ini_data_param(dti%XPAR_VEGTYPE,proot_extinctiongv=dti%XPAR_ROOT_EXTINCTIONGV)
    dti%LDATA_ROOT_EXTINCTIONGV = .true.
  ENDIF
  !
ENDIF
!
!dice: depth of the soil column for the calculation of the frozen soil fraction (m)
IF (dti%LDATA_DG .AND. .NOT.dti%LDATA_DICE) THEN
  !
  ALLOCATE(dti%XPAR_DICE(ig%NDIM,nvegtype))
  !
  IF(hisba/='DIF')THEN
    dti%XPAR_DICE(:,:)=max(0.2,0.8*dti%XPAR_DG(:,2,:))
    dti%LDATA_DICE=.true.
  ENDIF
!
ENDIF
!
!          2. Calculations of parameters dependant on others
!          -------------------------------------------------
!
!emis
IF (.NOT.dti%LDATA_EMIS .AND. dti%LDATA_VEG) THEN
   ALLOCATE(dti%XPAR_EMIS(ig%NDIM,dti%NTIME,nvegtype))
   CALL ini_data_param(dti%XPAR_VEGTYPE,oagri_to_grass=i%LAGRI_TO_GRASS,pveg_in=dti%XPAR_VEG,pemis_eco=dti%XPAR_EMIS)
   dti%LDATA_EMIS=.true.
ENDIF
!
!z0
!
IF (.NOT.dti%LDATA_Z0 .AND. (dti%LDATA_LAI .OR.dti%LDATA_H_TREE)) THEN
   ALLOCATE(dti%XPAR_Z0(ig%NDIM,dti%NTIME,nvegtype))
   CALL ini_data_param(dti%XPAR_VEGTYPE,oagri_to_grass=i%LAGRI_TO_GRASS,plai=dti%XPAR_LAI,ph_tree=dti%XPAR_H_TREE,pz0=dti%XPAR_Z0)
   dti%LDATA_Z0=.true.
ENDIF
!
!RSMIN
IF (dti%LDATA_LAI) THEN
  IF (.NOT.dti%LDATA_RSMIN) THEN
    ALLOCATE(dti%XPAR_RSMIN(ig%NDIM,nvegtype))
    CALL ini_data_param(dti%XPAR_VEGTYPE,oagri_to_grass=i%LAGRI_TO_GRASS,prsmin=dti%XPAR_RSMIN)
  ENDIF
  dti%LDATA_RSMIN=.true.
ENDIF

!parameters calculated on veg fraction
IF (dti%LDATA_VEG) THEN
  !
  IF (.NOT.dti%LDATA_GAMMA) ALLOCATE(dti%XPAR_GAMMA     (ig%NDIM,nvegtype))
  IF (.NOT.dti%LDATA_WRMAX_CF) ALLOCATE(dti%XPAR_WRMAX_CF  (ig%NDIM,nvegtype))
  IF (.NOT.dti%LDATA_RGL) ALLOCATE(dti%XPAR_RGL       (ig%NDIM,nvegtype))
  IF (.NOT.dti%LDATA_CV) ALLOCATE(dti%XPAR_CV        (ig%NDIM,nvegtype))
  IF (.NOT.dti%LDATA_ALBNIR_VEG) ALLOCATE(dti%XPAR_ALBNIR_VEG(ig%NDIM,nvegtype))
  IF (.NOT.dti%LDATA_ALBVIS_VEG) ALLOCATE(dti%XPAR_ALBVIS_VEG(ig%NDIM,nvegtype))
  IF (.NOT.dti%LDATA_ALBUV_VEG) ALLOCATE(dti%XPAR_ALBUV_VEG (ig%NDIM,nvegtype))
  IF (.NOT.dti%LDATA_GMES) ALLOCATE(dti%XPAR_GMES      (ig%NDIM,nvegtype))
  IF (.NOT.dti%LDATA_BSLAI) ALLOCATE(dti%XPAR_BSLAI     (ig%NDIM,nvegtype))
  IF (.NOT.dti%LDATA_SEFOLD) ALLOCATE(dti%XPAR_SEFOLD    (ig%NDIM,nvegtype))
  IF (.NOT.dti%LDATA_GC) ALLOCATE(dti%XPAR_GC        (ig%NDIM,nvegtype))
  IF (.NOT.dti%LDATA_LAIMIN) ALLOCATE(dti%XPAR_LAIMIN    (ig%NDIM,nvegtype))
  IF (.NOT.dti%LDATA_F2I) ALLOCATE(dti%XPAR_F2I       (ig%NDIM,nvegtype))
  IF (.NOT.dti%LDATA_CE_NITRO) ALLOCATE(dti%XPAR_CE_NITRO  (ig%NDIM,nvegtype))
  IF (.NOT.dti%LDATA_CF_NITRO) ALLOCATE(dti%XPAR_CF_NITRO  (ig%NDIM,nvegtype))
  IF (.NOT.dti%LDATA_CNA_NITRO) ALLOCATE(dti%XPAR_CNA_NITRO (ig%NDIM,nvegtype))
  !
  IF (.NOT.dti%LDATA_GAMMA) CALL ini_data_param(dti%XPAR_VEGTYPE,oagri_to_grass=i%LAGRI_TO_GRASS,pgamma=dti%XPAR_GAMMA)
  IF (.NOT.dti%LDATA_WRMAX_CF) CALL ini_data_param(dti%XPAR_VEGTYPE,oagri_to_grass=i%LAGRI_TO_GRASS,pwrmax_cf=dti%XPAR_WRMAX_CF)
  IF (.NOT.dti%LDATA_RGL) CALL ini_data_param(dti%XPAR_VEGTYPE,oagri_to_grass=i%LAGRI_TO_GRASS,prgl=dti%XPAR_RGL)
  IF (.NOT.dti%LDATA_CV) CALL ini_data_param(dti%XPAR_VEGTYPE,oagri_to_grass=i%LAGRI_TO_GRASS,pcv=dti%XPAR_CV)
  IF (.NOT.dti%LDATA_ALBNIR_VEG) &
     CALL ini_data_param(dti%XPAR_VEGTYPE,oagri_to_grass=i%LAGRI_TO_GRASS,palbnir_veg=dti%XPAR_ALBNIR_VEG)
  IF (.NOT.dti%LDATA_ALBVIS_VEG) &
     CALL ini_data_param(dti%XPAR_VEGTYPE,oagri_to_grass=i%LAGRI_TO_GRASS,palbvis_veg=dti%XPAR_ALBVIS_VEG)
  IF (.NOT.dti%LDATA_ALBUV_VEG) CALL ini_data_param(dti%XPAR_VEGTYPE,oagri_to_grass=i%LAGRI_TO_GRASS,palbuv_veg=dti%XPAR_ALBUV_VEG)
  IF (isize_lmeb_patch>0)  THEN
    IF (.NOT.dti%LDATA_BSLAI) CALL ini_data_param(dti%XPAR_VEGTYPE,pbslai=dti%XPAR_BSLAI)
  ENDIF
  IF (hphoto == 'AST' .OR. hphoto == 'LST' .OR. hphoto == 'NIT' .OR. hphoto=='NCB')  THEN
    IF (.NOT.dti%LDATA_GMES) CALL ini_data_param(dti%XPAR_VEGTYPE,oagri_to_grass=i%LAGRI_TO_GRASS,pgmes_st=dti%XPAR_GMES)
    IF (.NOT.dti%LDATA_BSLAI) CALL ini_data_param(dti%XPAR_VEGTYPE,oagri_to_grass=i%LAGRI_TO_GRASS,pbslai_st=dti%XPAR_BSLAI)
    IF (.NOT.dti%LDATA_SEFOLD) CALL ini_data_param(dti%XPAR_VEGTYPE,oagri_to_grass=i%LAGRI_TO_GRASS,psefold_st=dti%XPAR_SEFOLD)
    IF (.NOT.dti%LDATA_GC) CALL ini_data_param(dti%XPAR_VEGTYPE,oagri_to_grass=i%LAGRI_TO_GRASS,pgc_st=dti%XPAR_GC)
  ELSE
    IF (.NOT.dti%LDATA_GMES) CALL ini_data_param(dti%XPAR_VEGTYPE,oagri_to_grass=i%LAGRI_TO_GRASS,pgmes=dti%XPAR_GMES)
    IF (.NOT.dti%LDATA_BSLAI) CALL ini_data_param(dti%XPAR_VEGTYPE,oagri_to_grass=i%LAGRI_TO_GRASS,pbslai=dti%XPAR_BSLAI)
    IF (.NOT.dti%LDATA_SEFOLD) CALL ini_data_param(dti%XPAR_VEGTYPE,oagri_to_grass=i%LAGRI_TO_GRASS,psefold=dti%XPAR_SEFOLD)
    IF (.NOT.dti%LDATA_GC) CALL ini_data_param(dti%XPAR_VEGTYPE,oagri_to_grass=i%LAGRI_TO_GRASS,pgc=dti%XPAR_GC)
  ENDIF
  IF (.NOT.dti%LDATA_LAIMIN) CALL ini_data_param(dti%XPAR_VEGTYPE,oagri_to_grass=i%LAGRI_TO_GRASS,plaimin_out=dti%XPAR_LAIMIN)
  IF (.NOT.dti%LDATA_F2I) CALL ini_data_param(dti%XPAR_VEGTYPE,oagri_to_grass=i%LAGRI_TO_GRASS,pf2i=dti%XPAR_F2I)
  IF (.NOT.dti%LDATA_CE_NITRO) CALL ini_data_param(dti%XPAR_VEGTYPE,oagri_to_grass=i%LAGRI_TO_GRASS,pce_nitro=dti%XPAR_CE_NITRO)
  IF (.NOT.dti%LDATA_CF_NITRO) CALL ini_data_param(dti%XPAR_VEGTYPE,oagri_to_grass=i%LAGRI_TO_GRASS,pcf_nitro=dti%XPAR_CF_NITRO)
  IF (.NOT.dti%LDATA_CNA_NITRO) CALL ini_data_param(dti%XPAR_VEGTYPE,oagri_to_grass=i%LAGRI_TO_GRASS,pcna_nitro=dti%XPAR_CNA_NITRO)
  !
  dti%LDATA_GAMMA=.true.
  dti%LDATA_WRMAX_CF=.true.
  dti%LDATA_RGL=.true.
  dti%LDATA_CV=.true.
  dti%LDATA_ALBNIR_VEG=.true.
  dti%LDATA_ALBVIS_VEG=.true.
  dti%LDATA_ALBUV_VEG=.true.
  dti%LDATA_GMES=.true.
  dti%LDATA_BSLAI=.true.
  dti%LDATA_SEFOLD=.true.
  dti%LDATA_GC=.true.
  dti%LDATA_LAIMIN=.true.
  dti%LDATA_F2I=.true.
  dti%LDATA_CE_NITRO=.true.
  dti%LDATA_CF_NITRO=.true.
  dti%LDATA_CNA_NITRO=.true.
  !
  dti%LDATA_STRESS=.true.
  !
  ALLOCATE(dti%LPAR_STRESS   (ig%NDIM,nvegtype))  
  dti%LPAR_STRESS(:,:) = .true.
  IF(i%LAGRI_TO_GRASS)THEN
    DO jvegtype=1,nvegtype
      IF(xstress_noagri(jvegtype)<1.) dti%LPAR_STRESS(:,jvegtype) = .false.
    ENDDO 
  ELSE
    DO jvegtype=1,nvegtype
      IF(xstress(jvegtype)<1.) dti%LPAR_STRESS(:,jvegtype) = .false.
    ENDDO
  ENDIF
  !
  IF (.NOT.dti%LDATA_IRRIG) THEN
    ALLOCATE(dti%XPAR_IRRIG     (ig%NDIM,dti%NTIME,nvegtype))
    CALL av_pgd(dtco, &
                 dti%XPAR_IRRIG(:,kdecade2,:),pcover,xdata_irrig(:,:),yveg,'ARI',ocover,kdecade=kdecade2)
    dti%LDATA_IRRIG=.true.
  ENDIF
  !
  IF (.NOT.dti%LDATA_WATSUP) THEN
    ALLOCATE(dti%XPAR_WATSUP     (ig%NDIM,dti%NTIME,nvegtype))
    CALL av_pgd(dtco, &
                 dti%XPAR_WATSUP(:,kdecade2,:),pcover,xdata_watsup(:,:),yveg,'ARI',ocover,kdecade=kdecade2)
    dti%LDATA_WATSUP=.true.
  ENDIF
!
! MEB stuff
!
  IF (.NOT.dti%LDATA_GAMMAGV) ALLOCATE(dti%XPAR_GAMMAGV     (ig%NDIM,nvegtype))
  IF (.NOT.dti%LDATA_WRMAX_CFGV) ALLOCATE(dti%XPAR_WRMAX_CFGV  (ig%NDIM,nvegtype))
  IF (.NOT.dti%LDATA_RGLGV) ALLOCATE(dti%XPAR_RGLGV       (ig%NDIM,nvegtype))
  IF (.NOT.dti%LDATA_RSMINGV) ALLOCATE(dti%XPAR_RSMINGV     (ig%NDIM,nvegtype))
  !
  IF (.NOT.dti%LDATA_GAMMAGV) CALL ini_data_param(dti%XPAR_VEGTYPE,pgammagv=dti%XPAR_GAMMAGV)
  IF (.NOT.dti%LDATA_WRMAX_CFGV) CALL ini_data_param(dti%XPAR_VEGTYPE,pwrmax_cfgv=dti%XPAR_WRMAX_CFGV)
  IF (.NOT.dti%LDATA_RGLGV) CALL ini_data_param(dti%XPAR_VEGTYPE,prglgv=dti%XPAR_RGLGV)
  IF (.NOT.dti%LDATA_RSMINGV) CALL ini_data_param(dti%XPAR_VEGTYPE,prsmingv=dti%XPAR_RSMINGV)
  !
  dti%LDATA_GAMMAGV=.true.
  dti%LDATA_WRMAX_CFGV=.true.
  dti%LDATA_RGLGV=.true.
  dti%LDATA_RSMINGV=.true.
!
!LAIGV
  IF (.NOT.dti%LDATA_LAIGV) THEN
    ALLOCATE(dti%XPAR_LAIGV(ig%NDIM,dti%NTIME,nvegtype))
    CALL ini_data_param(dti%XPAR_VEGTYPE,plai=dti%XPAR_LAI,plaimin_in=dti%XPAR_LAIMIN,plaigv_out=dti%XPAR_LAIGV)
    dti%LDATA_LAIGV=.true.
  ENDIF
!
!Z0LITTER
  IF (.NOT.dti%LDATA_Z0LITTER) THEN
    ALLOCATE(dti%XPAR_Z0LITTER(ig%NDIM,dti%NTIME,nvegtype))
    CALL ini_data_param(dti%XPAR_VEGTYPE,plai=dti%XPAR_LAI,plaigv_in=dti%XPAR_LAIGV,  &
                        pz0litter=dti%XPAR_Z0LITTER)
    dti%LDATA_Z0LITTER=.true.
  ENDIF
!
!H_VEG
  IF (.NOT.dti%LDATA_H_VEG .AND. dti%LDATA_LAI .AND. dti%LDATA_H_TREE) THEN
    ALLOCATE(dti%XPAR_H_VEG(ig%NDIM,dti%NTIME,nvegtype))
    CALL ini_data_param(dti%XPAR_VEGTYPE,ph_veg=dti%XPAR_H_VEG,plai=dti%XPAR_LAI,  &
                        ph_tree=dti%XPAR_H_TREE)
    dti%LDATA_H_VEG=.true.
  ENDIF
!
!GNDLITTER
  IF (.NOT.dti%LDATA_GNDLITTER .AND. dti%LDATA_LAIGV) THEN
    ALLOCATE(dti%XPAR_GNDLITTER(ig%NDIM,dti%NTIME,nvegtype))
    CALL ini_data_param(dti%XPAR_VEGTYPE,plai=dti%XPAR_LAI,plaigv_in=dti%XPAR_LAIGV, &
                        pgndlitter=dti%XPAR_GNDLITTER)
    dti%LDATA_GNDLITTER=.true.
  ENDIF
  !
ENDIF
!
!
IF (dti%LDATA_VEGTYPE) THEN
  IF (.NOT.dti%LDATA_Z0_O_Z0H) ALLOCATE(dti%XPAR_Z0_O_Z0H  (ig%NDIM,nvegtype))
  IF (.NOT.dti%LDATA_DMAX) ALLOCATE(dti%XPAR_DMAX      (ig%NDIM,nvegtype))
  IF (.NOT.dti%LDATA_RE25) ALLOCATE(dti%XPAR_RE25      (ig%NDIM,nvegtype))
  IF (.NOT.dti%LDATA_Z0_O_Z0H) CALL ini_data_param(dti%XPAR_VEGTYPE,oagri_to_grass=i%LAGRI_TO_GRASS,pz0_o_z0h=dti%XPAR_Z0_O_Z0H)
  IF (hphoto == 'AST' .OR. hphoto == 'LST' .OR. hphoto == 'NIT' .OR. hphoto=='NCB')  THEN
    IF (.NOT.dti%LDATA_DMAX) CALL ini_data_param(dti%XPAR_VEGTYPE,oagri_to_grass=i%LAGRI_TO_GRASS,pdmax_st=dti%XPAR_DMAX)
  ELSE
    IF (.NOT.dti%LDATA_DMAX) CALL ini_data_param(dti%XPAR_VEGTYPE,oagri_to_grass=i%LAGRI_TO_GRASS,pdmax=dti%XPAR_DMAX)
  ENDIF
  IF (.NOT.dti%LDATA_RE25) CALL ini_data_param(dti%XPAR_VEGTYPE,oagri_to_grass=i%LAGRI_TO_GRASS,pre25=dti%XPAR_RE25)
  !
  dti%LDATA_Z0_O_Z0H=.true.
  dti%LDATA_DMAX=.true.
  dti%LDATA_RE25=.true.
ENDIF
!
IF (lhook) CALL dr_hook('INIT_ISBA_MIXPAR',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE init_isba_mixpar