ini_var_from_data.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
MODULE modi_ini_var_from_data
!
INTERFACE ini_var_from_data
!
SUBROUTINE ini_var_from_data_1d (DTCO, DGU, UG, U, USS, DTI, &
                                 hprogram, hatype, hname, htype, hfnam, hftyp, punif, pfield, opresent)
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_diag_surf_atm_n, ONLY : diag_surf_atm_t
USE modd_surf_atm_grid_n, ONLY : surf_atm_grid_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_surf_atm_sso_n, ONLY : surf_atm_sso_t
USE modd_data_isba_n, ONLY : data_isba_t
!
TYPE(data_cover_t), INTENT(INOUT) :: dtco
TYPE(diag_surf_atm_t), INTENT(INOUT) :: dgu
TYPE(surf_atm_grid_t), INTENT(INOUT) :: ug
TYPE(surf_atm_t), INTENT(INOUT) :: u
TYPE(surf_atm_sso_t), INTENT(INOUT) :: uss
TYPE(data_isba_t), INTENT(INOUT) :: dti
!
 CHARACTER(LEN=6), INTENT(IN) :: hprogram
 CHARACTER(LEN=3), INTENT(IN) :: hatype
 CHARACTER(LEN=*), INTENT(IN) :: hname
 CHARACTER(LEN=3), INTENT(IN) :: htype
 CHARACTER(LEN=28), DIMENSION(:), INTENT(IN) :: hfnam
 CHARACTER(LEN=6), DIMENSION(:), INTENT(IN) :: hftyp
REAL, DIMENSION(:), INTENT(IN) :: punif
REAL, DIMENSION(:,:), INTENT(OUT) :: pfield
LOGICAL, INTENT(OUT) :: opresent
!
END SUBROUTINE ini_var_from_data_1d
!
!
      SUBROUTINE ini_var_from_data_2d (DTCO, DGU, UG, U, USS, DTI, &
                                       hprogram, hatype, hname, htype, hfnam, hftyp, punif, pfield_time, opresent)
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_diag_surf_atm_n, ONLY : diag_surf_atm_t
USE modd_surf_atm_grid_n, ONLY : surf_atm_grid_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_surf_atm_sso_n, ONLY : surf_atm_sso_t
USE modd_data_isba_n, ONLY : data_isba_t
!
!
TYPE(data_cover_t), INTENT(INOUT) :: dtco
TYPE(diag_surf_atm_t), INTENT(INOUT) :: dgu
TYPE(surf_atm_grid_t), INTENT(INOUT) :: ug
TYPE(surf_atm_t), INTENT(INOUT) :: u
TYPE(surf_atm_sso_t), INTENT(INOUT) :: uss
TYPE(data_isba_t), INTENT(INOUT) :: dti
!
 CHARACTER(LEN=6), INTENT(IN) :: hprogram
 CHARACTER(LEN=3), INTENT(IN) :: hatype
 CHARACTER(LEN=*), INTENT(IN) :: hname
 CHARACTER(LEN=3), INTENT(IN) :: htype
 CHARACTER(LEN=28), DIMENSION(:,:), INTENT(IN) :: hfnam
 CHARACTER(LEN=6), DIMENSION(:,:), INTENT(IN) :: hftyp
REAL, DIMENSION(:,:), INTENT(IN) :: punif
REAL, DIMENSION(:,:,:), INTENT(OUT) :: pfield_time
LOGICAL, INTENT(OUT) :: opresent
!
END SUBROUTINE ini_var_from_data_2d
!
!
END INTERFACE ini_var_from_data
!
END MODULE modi_ini_var_from_data
!
!
!     #########
      SUBROUTINE ini_var_from_data_1d (DTCO, DGU, UG, U, USS, DTI, &
                                       hprogram, hatype, hname ,htype, hfnam, hftyp, punif, pfield, opresent)
!     ##############################################################
!
!!
!!    PURPOSE
!!    -------
!!
!!    METHOD
!!    ------
!!   
!
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    S. Faroux        Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original    16/11/10
!!
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_diag_surf_atm_n, ONLY : diag_surf_atm_t
USE modd_surf_atm_grid_n, ONLY : surf_atm_grid_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_surf_atm_sso_n, ONLY : surf_atm_sso_t
USE modd_data_isba_n, ONLY : data_isba_t
!
USE modd_data_cover_par, ONLY : nvegtype
!
USE modi_ini_var_from_data_0d
USE modi_abor1_sfx
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
TYPE(data_cover_t), INTENT(INOUT) :: dtco
TYPE(diag_surf_atm_t), INTENT(INOUT) :: dgu
TYPE(surf_atm_grid_t), INTENT(INOUT) :: ug
TYPE(surf_atm_t), INTENT(INOUT) :: u
TYPE(surf_atm_sso_t), INTENT(INOUT) :: uss
TYPE(data_isba_t), INTENT(INOUT) :: dti
!
 CHARACTER(LEN=6), INTENT(IN) :: hprogram
 CHARACTER(LEN=3), INTENT(IN) :: hatype
 CHARACTER(LEN=*), INTENT(IN) :: hname
 CHARACTER(LEN=3), INTENT(IN) :: htype
 CHARACTER(LEN=28), DIMENSION(:), INTENT(IN) :: hfnam
 CHARACTER(LEN=6), DIMENSION(:), INTENT(IN) :: hftyp
REAL, DIMENSION(:), INTENT(IN) :: punif
REAL, DIMENSION(:,:), INTENT(OUT) :: pfield
LOGICAL, INTENT(OUT) :: opresent
!
!
!*    0.2    Declaration of local variables
!            ------------------------------
!
 CHARACTER(LEN=40) :: yname
LOGICAL, DIMENSION(SIZE(PFIELD,2)) :: lpresent 
INTEGER               :: ji, jj  ! loop counter on vegtypes
!
REAL(KIND=JPRB) :: zhook_handle
!

!-------------------------------------------------------------------------------
!
!*    1.      Initializations
!             ---------------
!
IF (lhook) &
  CALL dr_hook('MODI_INI_VAR_FROM_DATA:INI_VAR_FROM_DATA_1D',0,zhook_handle)
!
opresent=.false.
yname=adjustl(hname)
!
DO ji=1,SIZE(pfield,2)
  CALL ini_var_from_data_0d(dtco, dgu, ug, u, uss, &
                            hprogram, hatype, hname, htype, hfnam(ji), &
              hftyp(ji), punif(ji), pfield(:,ji), lpresent(ji))
ENDDO
!
IF (any(lpresent(:))) THEN

  opresent=.true.

  IF (SIZE(pfield,2)==nvegtype .AND. yname(1:7).NE.'VEGTYPE') THEN

    !if a vegtype are missing, the last present gives it his values
    DO ji=2,SIZE(pfield,2)
      IF (.NOT.lpresent(ji)) THEN
        DO jj=ji,1,-1
          IF (lpresent(jj)) THEN
            pfield(:,ji)=pfield(:,jj)
            lpresent(ji)=.true.
            EXIT
          ENDIF
        ENDDO
      ENDIF
    ENDDO

    DO ji=1,SIZE(pfield,2)
      IF (lpresent(ji)) THEN
        WHERE (dti%XPAR_VEGTYPE(:,ji).EQ.0.) pfield(:,ji)=0.0
      ELSE
        pfield(:,ji)=0.
      ENDIF
    ENDDO

  ELSEIF (.NOT.all(lpresent)) THEN
    CALL abor1_sfx("INI_VAR_FROM_DATA_1D: MISSING INPUT DATA FOR "//hname)
  ENDIF
ENDIF
!
IF (lhook) &
  CALL dr_hook('MODI_INI_VAR_FROM_DATA:INI_VAR_FROM_DATA_1D',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE ini_var_from_data_1d
!
!     #########
      SUBROUTINE ini_var_from_data_2d (DTCO, DGU, UG, U, USS, DTI, &
                                       hprogram, hatype, hname, htype, hfnam, hftyp, punif, pfield_time, opresent)
!     ##############################################################
!
!!
!!    PURPOSE
!!    -------
!!
!!    METHOD
!!    ------
!!   
!
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    S. Faroux        Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original    16/11/10
!!
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_diag_surf_atm_n, ONLY : diag_surf_atm_t
USE modd_surf_atm_grid_n, ONLY : surf_atm_grid_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_surf_atm_sso_n, ONLY : surf_atm_sso_t
USE modd_data_isba_n, ONLY : data_isba_t
!
USE modd_data_cover_par, ONLY : nvegtype
!
USE modi_ini_var_from_data_0d
USE modi_put_in_time
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_abor1_sfx
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
TYPE(data_cover_t), INTENT(INOUT) :: dtco
TYPE(diag_surf_atm_t), INTENT(INOUT) :: dgu
TYPE(surf_atm_grid_t), INTENT(INOUT) :: ug
TYPE(surf_atm_t), INTENT(INOUT) :: u
TYPE(surf_atm_sso_t), INTENT(INOUT) :: uss
TYPE(data_isba_t), INTENT(INOUT) :: dti
!
 CHARACTER(LEN=6), INTENT(IN) :: hprogram
 CHARACTER(LEN=3), INTENT(IN) :: hatype
 CHARACTER(LEN=*), INTENT(IN) :: hname
 CHARACTER(LEN=3), INTENT(IN) :: htype
 CHARACTER(LEN=28), DIMENSION(:,:), INTENT(IN) :: hfnam
 CHARACTER(LEN=6), DIMENSION(:,:), INTENT(IN) :: hftyp
REAL, DIMENSION(:,:), INTENT(IN) :: punif
REAL, DIMENSION(:,:,:), INTENT(OUT) :: pfield_time
LOGICAL, INTENT(OUT) :: opresent
!
!
!*    0.2    Declaration of local variables
!            ------------------------------
!
LOGICAL, DIMENSION(SIZE(PFIELD_TIME,3)) :: lpresent
LOGICAL, DIMENSION(SIZE(PFIELD_TIME,2)) :: lpresent_time
INTEGER               :: ji, jj  ! loop counter on vegtypes
INTEGER               :: jtime
INTEGER               :: itime
!
REAL(KIND=JPRB) :: zhook_handle
!

!-------------------------------------------------------------------------------
!
!*    1.      Initializations
!             ---------------
!
IF (lhook) &
  CALL dr_hook('MODI_INI_VAR_FROM_DATA:INI_VAR_FROM_DATA_2D',0,zhook_handle)
!
opresent=.false.
lpresent_time(:)=.false.
itime=0
!
DO jtime=1,SIZE(pfield_time,2)

  DO ji=1,SIZE(pfield_time,3)

    CALL ini_var_from_data_0d(dtco, dgu, ug, u, uss, &
                            hprogram, hatype, hname, htype, hfnam(ji,jtime), &
              hftyp(ji,jtime), punif(ji,jtime), pfield_time(:,jtime,ji),&
              lpresent(ji))

  ENDDO 

  IF (any(lpresent(:))) THEN

    lpresent_time(jtime)=.true.
    opresent=.true.
    itime=itime+1

    IF (SIZE(pfield_time,3)==nvegtype) THEN

      DO ji=2,SIZE(pfield_time,3)
        IF (.NOT.lpresent(ji)) THEN
          DO jj=ji,1,-1
            IF (lpresent(jj)) THEN
              pfield_time(:,jtime,ji)=pfield_time(:,jtime,jj)
              lpresent(ji)=.true.
              EXIT
            ENDIF
          ENDDO
        ENDIF
      ENDDO
      DO ji=1,SIZE(pfield_time,3)
        IF (lpresent(ji)) THEN
          WHERE (dti%XPAR_VEGTYPE(:,ji).EQ.0.) pfield_time(:,jtime,ji)=0.0
        ELSE
          pfield_time(:,jtime,ji)=0.
        ENDIF
      ENDDO

    ELSEIF (.NOT.all(lpresent)) THEN
      CALL abor1_sfx("INI_VAR_FROM_DATA_1D: MISSING INPUT DATA FOR "//hname)
    ENDIF

  ENDIF

ENDDO
!
IF (opresent) THEN
  IF (SIZE(pfield_time,2)==36) THEN
     CALL put_in_time(hname,htype,itime,36,pfield_time)
  ELSE
    IF (any(lpresent_time(:)) .AND. .NOT.all(lpresent_time(:))) &
      CALL abor1_sfx("INI_VAR_FROM_DATA_2D: MISSING INPUT DATA FOR "//hname)
  ENDIF
ENDIF
!
!
IF (lhook) &
  CALL dr_hook('MODI_INI_VAR_FROM_DATA:INI_VAR_FROM_DATA_2D',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE ini_var_from_data_2d