hydro_veg.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE hydro_veg(HRAIN, PTSTEP, PMUF, PRR, PLEV, PLETR,    &
                              pveg, ppsnv, pwr, pwrmax, ppg, pdrip,    &
                              prrveg, plvtt  )    
!     #####################################################################
!
!!****  *HYDRO_VEG*  
!!
!!    PURPOSE
!!    -------
!
!     Calculates the evolution of the liquid water retained in the vegetation 
!     canopy (Wr). Also determine the runoff from the canopy that reaches the
!     ground (Mahfouf et al. 1995). This routine take into account the spatially 
!     exponential distribution of precip introduced by Entekhabi and Eagleson (1989).
!         
!     
!!**  METHOD
!!    ------
!
!!    EXTERNAL
!!    --------
!!
!!    none
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------ 
!!
!!    USE MODD_CST
!!      
!!    REFERENCE
!!    ---------
!!
!!    Noilhan and Planton (1989)
!!    Belair (1995)
!!    Mahfouf et al. 1995
!!    Decharme and Douville (2006)
!!      
!!    AUTHOR
!!    ------
!!
!!      S. Belair           * Meteo-France *
!!
!!    MODIFICATIONS
!!    -------------
!!
!!      Original    14/03/95 
!!                  31/08/98 (V. Masson and F. Habets) add Dumenil et Todini
!!                           runoff scheme
!!                  31/08/98 (V. Masson and A. Boone) add the third soil-water
!!                           reservoir (WG3,D3)
!!                  31/05/04 (B. Decharme) add the rainfall spatial distribution
!!                      2008 (B. Decharme) add the dripping rate as new diag
!!                  11/2009  (S.Senesi) returns precipitation intercepted by  
!                               the vegetation 
!!                  07/2011  (B. Decharme) delete SGH for very fine precipitation
!!                  09/2012  (B. Decharme) Computation efficiency for HRAIN=='SGH'
!!                  10/2012  (B. Decharme) PPG intent(out)
!
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
USE modd_sgh_par, ONLY : x001
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
 CHARACTER(LEN=*),     INTENT(IN)   :: hrain   ! Rainfall spatial distribution
                                              ! 'DEF' = No rainfall spatial distribution
                                              ! 'SGH' = Rainfall exponential spatial distribution
                                              ! 
!
REAL, INTENT(IN)                    :: ptstep
!                                      timestep of the integration
!
REAL, DIMENSION(:), INTENT(IN)    :: prr,  plev, pletr, pmuf, plvtt
!                                      PRR   = rain rate
!                                      PLEV = latent heat of evaporation over vegetation
!                                      PLETR = evapotranspiration of the vegetation
!                                      PMUF   = fraction of the grid cell reached by the precipitation
!                                      PLVTT  = latent heat of vaporization (J/kg)
!
REAL, DIMENSION(:), INTENT(IN)    :: pveg, pwrmax
!                                      PVEG   = fraction of vegetation
!                                      PWRMAX = maximum equivalent water content
!                                               in the vegetation canopy
!
REAL, DIMENSION(:), INTENT(IN)    :: ppsnv
!                                      PPSNV = vegetation covered by snow
!
REAL, DIMENSION(:), INTENT(INOUT) :: pwr
!                                      PWR = liquid water retained on the foliage
!                                             of the vegetation at time 't+dt'
!
REAL, DIMENSION(:), INTENT(OUT)   :: ppg,pdrip
!                                      PPG   = total water reaching the ground
!                                      PDRIP = Dripping from the vegetation
REAL, DIMENSION(:), INTENT(OUT)   :: prrveg  
!                                      PRRVEG = Precip. intercepted by vegetation (kg/m2/s)
!
!
!*      0.2    declarations of local variables
!
REAL, DIMENSION(SIZE(PVEG)) :: zer
!                                  ZER = evaporation rate from the canopy
!
REAL, DIMENSION(SIZE(PVEG)) :: zwr ! for time stability scheme
!
REAL, DIMENSION(SIZE(PVEG)) :: zruir, zruir2 ! dripping from the vegetation
!
REAL                        :: zlim
!
REAL(KIND=JPRB) :: zhook_handle
!
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('HYDRO_VEG',0,zhook_handle)
zruir(:) = 0.
zruir2(:) = 0.
pdrip(:) = 0.
zwr(:) = 0.
!
!*       1.     EVOLUTION OF THE EQUIVALENT WATER CONTENT Wr
!               --------------------------------------------
!
!evaporation rates
!
zer(:)    = (plev(:)-pletr(:))  / plvtt(:)
!
!intercepted rainfall rate
!
prrveg(:) = pveg(:) * (1.-ppsnv(:)) * prr(:)
!
!evolution of the intercepted water
!(if we don't consider the runoff)
!
pwr(:)  = pwr(:) - ptstep * (zer(:) - prrveg(:))
!
!When Wr < 0, the direct evaporation
!(i.e., EV-ETR) removes too much
!liquid water from the vegetation
!reservoir.  This is considered as
!negative runoff, and it is stocked
!in ZRUIR2.
!
zruir2(:) = min(0.,pwr(:)/ptstep)
!
!Wr must be positive
!
pwr(:)    = max(0., pwr(:))
!
IF(hrain=='SGH')THEN
!        
!*       2.     SPATIALLY EXPONENTIAL DISTRIBUTION OF PRECIPITATION
!               ---------------------------------------------------
!
!
!  Subgrid dripping from Wr
!
   zlim=x001/ptstep
!
   WHERE(prrveg(:)>zlim.AND.pwr(:)>0.0)
        zruir(:) = prrveg(:)*exp(pmuf(:)*(pwr(:)-pwrmax(:))/(prrveg(:)*ptstep))
        zruir(:) = min(zruir(:),pwr(:)/ptstep) 
   ENDWHERE
!
   IF(ptstep>300.)THEN
!
!    if the isba time step is coarser than 5min, the "prediction/correction" method is applied
!    to Wr using the predicted Wr* at the end of the time step for time numerical stability
!
     zwr(:)   = pwr(:)-ptstep*zruir(:)
     zruir(:) = 0.0
!
!    if the dripping is too big, the "prediction/correction" method is applied to Wr using
!    the predicted Wr* at the midle of the time step for time numerical stability 
!    (<=> Runge-Kutta order 1 rang 1)
!
     WHERE(prrveg(:)>zlim.AND.zwr(:)<=0.0)
           zruir(:) = prrveg(:)*exp(pmuf(:)*(pwr(:)-pwrmax(:))/(prrveg(:)*ptstep/2.))
           zruir(:) = min(zruir(:),pwr(:)/(ptstep/2.))
           zwr(:) = pwr(:)-ptstep*zruir(:)/2.
           zruir(:) = 0.0
     ENDWHERE
!
!    Calculate the corrected dripping from the predicted Wr*
!
     WHERE(prrveg(:)>zlim.AND.zwr(:)>0.0)
          zruir(:) = prrveg(:)*exp(pmuf(:)*(zwr(:)-pwrmax(:))/(prrveg(:)*ptstep))
          zruir(:) = min(zruir(:),pwr(:)/ptstep) 
     ENDWHERE
!
   ENDIF
!
   pwr(:)   = pwr(:)-ptstep*zruir(:)  
!
!  As previously Wr must be positive (numerical artefact)
!
   zruir2(:) = zruir2(:) + min(0.,pwr(:)/ptstep)
   pwr(:)    = max( 0., pwr(:) )
!
!  Wr must be smaller then Wrmax
!  Then if Wr remain > Wrmax, there is runoff
!
   zruir(:) = zruir(:) + max(0., (pwr(:) - pwrmax(:)) / ptstep )
!   
ELSE
!
! if Wr > Wrmax, there is runoff
!
  zruir(:) = max(0., (pwr(:) - pwrmax(:)) / ptstep )
!
ENDIF
!
!Wr must be smaller then Wrmax
!
pwr(:)   = min(pwr(:), pwrmax(:))
!
!
!*       3.     LIQUID WATER REACHING THE GROUND Pg
!               -----------------------------------
!
!Thus, the rate of liquid water reaching the ground is the 
!precipitation plus the vegetation runoff (we also consider the
!negative runoff).
!
ppg(:) = (1.-pveg(:)*(1-ppsnv(:))) * prr(:) + zruir(:) + zruir2(:)
!
pdrip(:) = zruir(:) + zruir2(:)
IF (lhook) CALL dr_hook('HYDRO_VEG',1,zhook_handle)

!
!-------------------------------------------------------------------------------
!
END SUBROUTINE hydro_veg