hydro_dt92.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE hydro_dt92(PTSTEP,                                 &
                              prunoffb, pwwilt,                       &
                              prunoffd, pwsat,                        &
                              pwg2, pwgi2,                            &
                              ppg, pruisdt                            )  
!     #####################################################################
!
!!****  *HYDRO_DT92*  
!!
!!    PURPOSE
!!    -------
!
!     Calculates the evolution of the water variables, i.e., the superficial
!     and deep-soil volumetric water content (wg and w2), the equivalent
!     liquid water retained in the vegetation canopy (Wr), the equivalent
!     water of the snow canopy (Ws), and also of the albedo and density of
!     the snow (i.e., ALBS and RHOS).  Also determine the runoff and drainage
!     into the soil.
!         
!     
!!**  METHOD
!!    ------
!
!!    EXTERNAL
!!    --------
!!
!!    none
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------ 
!!
!!
!!      
!!    REFERENCE
!!    ---------
!!
!!    Noilhan and Planton (1989)
!!    Belair (1995)
!!      
!!    AUTHOR
!!    ------
!!
!!      S. Belair           * Meteo-France *
!!
!!    MODIFICATIONS
!!    -------------
!!
!!      Original    14/03/95 
!!                  31/08/98 (V. Masson and F. Habets) add Dumenil et Todini
!!                           runoff scheme
!!                  16/05/02 (A. Boone) comments, F90 code standardization
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
USE modd_csts,ONLY : xrholw
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
!
REAL, INTENT(IN)                  :: ptstep
!                                    timestep of the integration (s)
!
REAL, DIMENSION(:), INTENT(IN)    :: pwwilt   ! the wilting point volumetric
!                                             ! water content (m3 m-3)
REAL, DIMENSION(:), INTENT(IN)    :: prunoffb ! slope of the runoff curve (-)
!
!
REAL, DIMENSION(:), INTENT(IN)    :: prunoffd, pwsat
!                                    PRUNOFFD = soil depth over which degree of saturation
!                                               used for runoff calculation (m)
!                                    PWSAT    = saturation volumetric water content
!                                               of the soil (m3 m-3)
!
REAL, DIMENSION(:), INTENT(IN)    :: pwg2, pwgi2
!                                    PWG2 = bulk root-soil moisture at 't+dt' (m3 m-3)
!                                    PWGI2 = bulk deep-soil ice at 't+dt' (m3 m-3)
!
REAL, DIMENSION(:), INTENT(INOUT) :: ppg       
!                                    PPG = enters as rainfall/Canopy drip/snowmelt 
!                                          throughfall rate, leaves as infiltration
!                                          rate for Force-Restore method, and potential
!                                          infiltration rate for diffusion method (kg m-2 s-1)
REAL, DIMENSION(:), INTENT(OUT)   :: pruisdt
!                                    PRUISDT = sub-grid surface runoff rate (kg m-2 s-1)
!
!
!*      0.2    declarations of local variables
!
! 
REAL, DIMENSION(SIZE(PRUNOFFD))    :: zpas, zpg_ini, zwg2
REAL(KIND=JPRB) :: zhook_handle
!                                     ZWG2   = Total vol. water content
!                                              of layer for calculating runoff (m3 m-3)
!
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('HYDRO_DT92',0,zhook_handle)
zpas(:)    = 0.
zpg_ini(:) = 0.
zwg2(:)    = 0.
!
pruisdt(:) = 0.
!
!-------------------------------------------------------------------------------
!
!
!*       1.     Dumenil et Todini (1992)  RUNOFF SCHEME
!               ---------------------------------------
!
zpg_ini(:)= ppg(:)
!
zwg2(:)   = min(pwsat(:), pwg2(:) + pwgi2(:)) 
!
! Setting the expression below to 0 and solving for PG yields the critical throughfall rate:
!
zpas(:)   = (1.- (zwg2(:)-pwwilt(:))/(pwsat(:)-pwwilt(:)) )**(1./ (1.+prunoffb(:)) ) -   &
                ppg(:)*ptstep/(xrholw*prunoffd(:) )/( (1. + prunoffb(:))* (pwsat(:)-pwwilt(:)) )  
!
zpas(:)   = max(0.0, zpas(:))  ! Limit it to within a physical range:
!
! Surface runoff calculation:
! If PAS is <= 0 (i.e. throughfall rate is large enough), then method 
! collapses into a saturated bucket type model.
!
pruisdt(:)  = ppg(:)*ptstep/(xrholw*prunoffd(:) ) - ( pwsat(:)-zwg2(:) ) &
                 + (pwsat(:)-pwwilt(:))* ( zpas(:)**(1.+prunoffb(:)) )  
!
pruisdt(:) = max(0.0, pruisdt(:))
!
! Reduce infiltration into the soil by the runoff:
!
ppg(:)     = ppg(:) - pruisdt(:)/ptstep*xrholw*prunoffd(:)
!
! Supress numerical artifacts:
!
WHERE (ppg(:)<=0. .OR. pruisdt(:)<=0.)
  pruisdt(:) = 0.
  ppg(:)     = zpg_ini(:)
END WHERE
!
! supress runoff over sufficiently dry soils: HERE chosen to be if the average 
! water content is less than the wilting point:
!
WHERE (zwg2(:)<=pwwilt(:)) 
  pruisdt(:) = 0.
  ppg(:)     = zpg_ini(:)
END WHERE
IF (lhook) CALL dr_hook('HYDRO_DT92',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE hydro_dt92