hor_interpol_latlon.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE hor_interpol_latlon(KLUOUT,PFIELDIN,PFIELDOUT)
!     #################################################################################
!
!!****  *HOR_INTERPOL_LATLON* - Interpolation from a lat/lon regular grid
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     C. Lebeaupin Brossier 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004
!!     B. Decharme  07/2014 use usual HORIBL_SURF for regular lat/lon grid
!!                         (ADAPT_HORIBL_SURF is not up to date and is wrong
!!                          for interpolation from a coarse grid to a finer)
!!  
!!------------------------------------------------------------------
!
!
!
USE modd_prep,             ONLY : xlat_out, xlon_out, linterp
USE modd_grid_latlonregul, ONLY : xilat1, xilon1, xilat2, xilon2,    &
                                  ninlat, ninlon, nilength,xilatarray  
USE modd_surf_par,   ONLY : xundef
!
USE modi_horibl_surf
USE modi_adapt_horibl_surf
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
INTEGER,              INTENT(IN)    :: kluout    ! logical unit of output listing
REAL, DIMENSION(:,:), INTENT(IN)    :: pfieldin  ! field to interpolate horizontally
REAL, DIMENSION(:,:), INTENT(OUT)   :: pfieldout ! interpolated field
!
!*      0.2    declarations of local variables
!
INTEGER, DIMENSION(:), ALLOCATABLE :: imaskin  ! input mask
INTEGER, DIMENSION(:), ALLOCATABLE :: imaskout ! output mask
INTEGER                            :: ino      ! output number of points
INTEGER                            :: jl       ! loop counter
LOGICAL                            :: gregular
REAL                               :: zdlat,zdlat_reg
!
REAL(KIND=JPRB) :: zhook_handle
!
!-------------------------------------------------------------------------------------
!*      1.    Allocations
!
IF (lhook) CALL dr_hook('HOR_INTERPOL_LATLON',0,zhook_handle)
!
ino = SIZE(xlat_out)
!
ALLOCATE(imaskin(nilength))
!
ALLOCATE(imaskout(ino))
!
!*      2.    Initializations
!
gregular= .true.
!
imaskout = 1
!
zdlat_reg = (xilat2-xilat1)/REAL(ninlat-1)
!
DO jl=2,ninlat
   zdlat=xilatarray(jl)-xilatarray(jl-1)
   IF(zdlat/=zdlat_reg)THEN
     gregular=.false.
   ENDIF
ENDDO
!
!
!*      3. Interpolation with horibl
!
IF(gregular)THEN
  DO jl=1,SIZE(pfieldin,2)
     imaskin(:) = 1
     WHERE(pfieldin(:,jl)==xundef) imaskin(:) = 0
     CALL horibl_surf(xilat1,xilon1,xilat2,xilon2,ninlat,ninlon,nilength,            &
                      pfieldin(:,jl),ino,xlon_out,xlat_out,pfieldout(:,jl),.false.,  &
                      kluout,linterp,imaskin,imaskout)
  ENDDO
ELSE 
  DO jl=1,SIZE(pfieldin,2)
     imaskin(:) = 1
     WHERE(pfieldin(:,jl)==xundef) imaskin(:) = 0
     CALL adapt_horibl_surf(xilatarray,xilat1,xilon1,xilat2,xilon2,ninlat,ninlon,nilength, &
                            pfieldin(:,jl),ino,xlon_out,xlat_out,pfieldout(:,jl),.false.,  &
                            kluout,linterp,imaskin,imaskout)
  ENDDO 
ENDIF
!
!*      6.    Deallocations
!
IF (ALLOCATED(imaskin )) DEALLOCATE(imaskin )
IF (ALLOCATED(imaskout)) DEALLOCATE(imaskout)
!
IF (lhook) CALL dr_hook('HOR_INTERPOL_LATLON',1,zhook_handle)
!-------------------------------------------------------------------------------
END SUBROUTINE hor_interpol_latlon