hor_interpol_cartesian.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE hor_interpol_cartesian(KLUOUT,PFIELDIN,PFIELDOUT)
!     #################################################################################
!
!
USE modd_prep,           ONLY : xlat_out, xlon_out, xx_out, xy_out, linterp
USE modd_grid_cartesian, ONLY : xx, xy, nx, ny
USE modd_surf_par,   ONLY : xundef
!
USE mode_gridtype_cartesian
USE modi_bilin
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
INTEGER,            INTENT(IN)  :: kluout    ! logical unit of output listing
REAL, DIMENSION(:,:), INTENT(IN)  :: pfieldin  ! field to interpolate horizontally
REAL, DIMENSION(:,:), INTENT(OUT) :: pfieldout ! interpolated field
!
!*      0.2    declarations of local variables
!
REAL, DIMENSION(:),   ALLOCATABLE :: zx       ! X coordinate
REAL, DIMENSION(:),   ALLOCATABLE :: zy       ! Y coordinate
INTEGER                           :: ino      ! output number of points
REAL, DIMENSION(:,:,:), ALLOCATABLE :: zfieldin ! input field
!
INTEGER                           :: ji       ! loop index
INTEGER                           :: jj       ! loop index
INTEGER                           :: jl       ! loop index
REAL(KIND=JPRB) :: zhook_handle

!-------------------------------------------------------------------------------------
!
!*      1.    Allocations
!
IF (lhook) CALL dr_hook('HOR_INTERPOL_CARTESIAN',0,zhook_handle)
ino = SIZE(xx_out)
!
ALLOCATE(zx(ino))
ALLOCATE(zy(ino))
!
!*      2.    Transformation of latitudes/longitudes into metric coordinates of output grid
!
!* WARNING : here, because the input grid is not geographic, one assumes that
!            coordinates are coherent between input and output grid, but without
!            any way to check it.
!
zx = xx_out
zy = xy_out
!
!
!*      3.    Put input field on its squared grid
!
ALLOCATE(zfieldin(nx,ny,SIZE(pfieldin,2)))
!
DO jj=1,ny
  DO ji=1,nx
    zfieldin(ji,jj,:) = pfieldin(ji+nx*(jj-1),:)
  END DO
END DO
!
!*      4.    Interpolation with bilinear
!
DO jl=1,SIZE(pfieldin,2)
  CALL bilin(kluout,xx,xy,zfieldin(:,:,jl),zx,zy,pfieldout(:,jl),linterp)
END DO
!
!
!*      5.    Deallocations
!
!
DEALLOCATE(zx)
DEALLOCATE(zy)
DEALLOCATE(zfieldin)
IF (lhook) CALL dr_hook('HOR_INTERPOL_CARTESIAN',1,zhook_handle)
!
!-------------------------------------------------------------------------------------
END SUBROUTINE hor_interpol_cartesian