hor_interpol_arome.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE hor_interpol_arome(KLUOUT,PFIELDIN,PFIELDOUT)
!     #################################################################################
!
!!****  *HOR_INTERPOL_AROME * - Interpolation from an AROME grid
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     V. Masson 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004
!!------------------------------------------------------------------
!
!
!
USE modd_prep,       ONLY : xlat_out, xlon_out,linterp 
USE modd_grid_arome, ONLY : xx, xy, nx, ny, xlat0, xlon0, xlator, xlonor, xrpk, xbeta
USE modd_grid_grib,  ONLY : nni
USE modd_surf_par,   ONLY : xundef
!
USE mode_gridtype_conf_proj
USE modi_horibl_surf
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
INTEGER,            INTENT(IN)  :: kluout    ! logical unit of output listing
REAL, DIMENSION(:,:), INTENT(IN)  :: pfieldin  ! field to interpolate horizontally
REAL, DIMENSION(:,:), INTENT(OUT) :: pfieldout ! interpolated field
!
!*      0.2    declarations of local variables
!
REAL, DIMENSION(:), ALLOCATABLE :: zx       ! X coordinate
REAL, DIMENSION(:), ALLOCATABLE :: zy       ! Y coordinate
INTEGER, DIMENSION(:), ALLOCATABLE :: imaskin  ! input mask
INTEGER, DIMENSION(:), ALLOCATABLE :: imaskout ! output mask
INTEGER                         :: ino      ! output number of points
INTEGER                         :: jl       ! loop counter
INTEGER, DIMENSION(:), ALLOCATABLE  :: ix  ! number of points on each line
REAL(KIND=JPRB) :: zhook_handle
!
!-------------------------------------------------------------------------------------
!
!*      1.    Allocations
!
IF (lhook) CALL dr_hook('HOR_INTERPOL_AROME',0,zhook_handle)
ino = SIZE(xlat_out)
!
ALLOCATE(imaskin(nni))
!
ALLOCATE(zx(ino))
ALLOCATE(zy(ino))
ALLOCATE(imaskout(ino))
imaskout = 1
ALLOCATE(ix(ny))
ix=nx
!
!*      2.    Transformation of latitudes/longitudes into metric coordinates of input grid
!
 CALL xy_conf_proj(xlat0,xlon0,xrpk,xbeta,xlator,xlonor,zx,zy,xlat_out,xlon_out)
!
!
!*      3.    Input mask
!
DO jl=1,SIZE(pfieldin,2)
  imaskin(:) = 1
  WHERE(pfieldin(:,jl)==xundef) imaskin = 0
!
!
!*      4.    Interpolation with horibl
!
  CALL horibl_surf(0.,0.,xy,xx,ny,ix,nni,pfieldin(:,jl),ino,zx,zy,pfieldout(:,jl), &
                     .false.,kluout,linterp,imaskin,imaskout)  
END DO
!
!*      5.    Deallocations
!
DEALLOCATE(zx)
DEALLOCATE(ix)
DEALLOCATE(zy)
DEALLOCATE(imaskin )
DEALLOCATE(imaskout)
IF (lhook) CALL dr_hook('HOR_INTERPOL_AROME',1,zhook_handle)

!-------------------------------------------------------------------------------------
END SUBROUTINE hor_interpol_arome