grid_modif_cartesian.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     ################################################################
      SUBROUTINE grid_modif_cartesian(KLUOUT,KLUNAM,KGRID_PAR,KL,PGRID_PAR, &
                                               kgrid_par2,kl2,omodif,pgrid_par2      )  
!     ################################################################
!
!!****  *GRID_MODIF_CARTESIAN* - routine to read in namelist the horizontal grid
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      V. Masson   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004 
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
USE modd_surf_par, ONLY : nundef

USE mode_pos_surf
USE mode_gridtype_cartesian
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_regular_grid_spawn
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
INTEGER,                      INTENT(IN)    :: kluout     ! output listing logical unit
INTEGER,                      INTENT(IN)    :: klunam     ! namelist file logical unit
INTEGER,                      INTENT(IN)    :: kl         ! number of points
INTEGER,                      INTENT(IN)    :: kgrid_par  ! size of PGRID_PAR
REAL, DIMENSION(KGRID_PAR),   INTENT(IN)    :: pgrid_par  ! parameters defining the grid
INTEGER,                      INTENT(INOUT) :: kl2        ! number of points in modified grid
INTEGER,                      INTENT(INOUT) :: kgrid_par2 ! size of PGRID_PAR2
LOGICAL,                      INTENT(IN)    :: omodif     ! flag to modify the grid
REAL, DIMENSION(KGRID_PAR2),  INTENT(OUT)   :: pgrid_par2 ! parameters defining the modified grid
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
!* initial grid
REAL                              :: zlat0    ! reference latitude
REAL                              :: zlon0    ! reference longitude
INTEGER                           :: iimax1   ! number of points in I direction
INTEGER                           :: ijmax1   ! number of points in J direction
REAL, DIMENSION(:),   ALLOCATABLE :: zx1      ! X conformal coordinate of grid mesh
REAL, DIMENSION(:),   ALLOCATABLE :: zy1      ! Y conformal coordinate of grid mesh
REAL, DIMENSION(:),   ALLOCATABLE :: zdx1     ! X grid mesh size
REAL, DIMENSION(:),   ALLOCATABLE :: zdy1     ! Y grid mesh size
!
!* new grid
INTEGER                           :: iimax2   ! number of points in I direction
INTEGER                           :: ijmax2   ! number of points in J direction
REAL, DIMENSION(:),   ALLOCATABLE :: zx2      ! X conformal coordinate of grid mesh
REAL, DIMENSION(:),   ALLOCATABLE :: zy2      ! Y conformal coordinate of grid mesh
REAL, DIMENSION(:),   ALLOCATABLE :: zdx2     ! X grid mesh size
REAL, DIMENSION(:),   ALLOCATABLE :: zdy2     ! Y grid mesh size
!
!* other variables
LOGICAL :: gfound
REAL, DIMENSION(:), POINTER       :: zgrid_par
!
!
!*       0.3   Declarations of namelist
!              ------------------------
!
INTEGER :: ixor = 1            ! position of modified bottom left point
INTEGER :: iyor = 1            ! according to initial grid
INTEGER :: ixsize = -999       ! number of grid meshes in initial grid to be
INTEGER :: iysize = -999       ! covered by the modified grid
INTEGER :: idxratio = 1        ! resolution ratio between modified grid
INTEGER :: idyratio = 1        ! and initial grid
REAL(KIND=JPRB) :: zhook_handle
!
!
namelist/nam_inifile_cartesian/ixor,iyor,ixsize,iysize,idxratio,idyratio
!
!------------------------------------------------------------------------------
!
!*       1.    Reading of projection parameters
!              --------------------------------
!
IF (lhook) CALL dr_hook('GRID_MODIF_CARTESIAN',0,zhook_handle)
 CALL posnam(klunam,'NAM_INIFILE_CARTESIAN',gfound,kluout)
IF (gfound) READ(unit=klunam,nml=nam_inifile_cartesian)
!
!---------------------------------------------------------------------------
!
!*       2.    All this information stored into pointer PGRID_PAR
!              --------------------------------------------------
!
ALLOCATE(zx1(kl))
ALLOCATE(zy1(kl))
ALLOCATE(zdx1(kl))
ALLOCATE(zdy1(kl))
!
 CALL get_gridtype_cartesian(pgrid_par,zlat0,zlon0,               &
                              iimax1,ijmax1,                       &
                              zx1,zy1,zdx1,zdy1                    )  
!
!---------------------------------------------------------------------------
!
!*       3.    Default : no modification
!              -------------------------
!
IF (ixsize==-999) ixsize=iimax1
IF (iysize==-999) iysize=ijmax1
!
!---------------------------------------------------------------------------
!
!*       4.    Modification of the grid
!              ------------------------
!
!* number of points
!
iimax2=ixsize*idxratio
ijmax2=iysize*idyratio
!
kl2 = iimax2 * ijmax2
!
ALLOCATE(zx2(iimax2*ijmax2))
ALLOCATE(zy2(iimax2*ijmax2))
ALLOCATE(zdx2(iimax2*ijmax2))
ALLOCATE(zdy2(iimax2*ijmax2))
!
 CALL regular_grid_spawn(kluout,                               &
                          kl, iimax1,ijmax1,zx1,zy1,zdx1,zdy1,  &
                          ixor, iyor, idxratio, idyratio,       &
                          ixsize, iysize,                       &
                          kl2, iimax2,ijmax2,zx2,zy2,zdx2,zdy2  )   
DEALLOCATE(zx1)
DEALLOCATE(zy1)
DEALLOCATE(zdx1)
DEALLOCATE(zdy1)
!---------------------------------------------------------------------------
!
!*       5.    All this information stored into pointer PGRID_PAR
!              --------------------------------------------------
!
 CALL put_gridtype_cartesian(zgrid_par,zlat0,zlon0,               &
                              iimax2,ijmax2,                       &
                              zx2,zy2,zdx2,zdy2                    )  
!
!---------------------------------------------------------------------------
DEALLOCATE(zx2)
DEALLOCATE(zy2)
DEALLOCATE(zdx2)
DEALLOCATE(zdy2)
!---------------------------------------------------------------------------
!
!* 1st call : initializes dimension
!
IF (kgrid_par2==0) THEN
  kgrid_par2 = SIZE(zgrid_par)
!
ELSE
!
!* 2nd call : initializes grid array
!
  pgrid_par2(:) = 0.
  pgrid_par2(:) = zgrid_par
END IF
!
DEALLOCATE(zgrid_par)
IF (lhook) CALL dr_hook('GRID_MODIF_CARTESIAN',1,zhook_handle)
!
!---------------------------------------------------------------------------
!
END SUBROUTINE grid_modif_cartesian