get_surf_varn.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE get_surf_var_n (DGF, I, DGI, DGMI, DGS, DGU, DGT, DGW, F, UG, U, USS, &
                                 hprogram, ki, ks,                              &
                                  psea, pwater, pnature, ptown,                &
                                  pt2m, pq2m, pqs, pz0, pz0h, pz0eff,          &
                                  pz0_sea, pz0_water, pz0_nature, pz0_town,    &
                                  pz0h_sea, pz0h_water, pz0h_nature, pz0h_town,&
                                  pqs_sea, pqs_water, pqs_nature, pqs_town,    &
                                  ppsng, ppsnv, pzs, pseries, ptwsnow,         &
                                  psso_stdev, plon, plat,                      &
                                  pbare, plai_tree, ph_tree                    )  
!     #######################################################################
!
!!****  *GET_SURF_VAR_n* - gets some surface fields on atmospheric grid
!!
!!    PURPOSE
!!    -------
!!
!!    This program returns some surface variables neede by the atmosphere
!!
!!**  METHOD
!!    ------
!!
!!    Several functions are called in order to initialize surface variables
!!    needed by the atmospheric model. These functions fill the required arrays by
!!    the diagnosed values computed during the run. Since all arrays are optional,
!!    this program may be called with any of the arguments described above.
!!
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!      P. Le Moigne   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    02/2006
!       S. Riette   06/2010 PSSO_STDEV and PTWSNOW added
!       B. Decharme 09/2012 Argument added in GET_FLUX_n
!       B. Decharme 05/2013 Argument added in GET_FLUX_n for debug in ARP/AL/AR
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
USE modd_diag_flake_n, ONLY : diag_flake_t
USE modd_isba_n, ONLY : isba_t
USE modd_diag_isba_n, ONLY : diag_isba_t
USE modd_diag_misc_isba_n, ONLY : diag_misc_isba_t
USE modd_diag_seaflux_n, ONLY : diag_seaflux_t
USE modd_diag_surf_atm_n, ONLY : diag_surf_atm_t
USE modd_diag_teb_n, ONLY : diag_teb_t
USE modd_diag_watflux_n, ONLY : diag_watflux_t
USE modd_flake_n, ONLY : flake_t
USE modd_surf_atm_grid_n, ONLY : surf_atm_grid_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_surf_atm_sso_n, ONLY : surf_atm_sso_t
!
USE modd_surf_par,     ONLY : xundef
USE modi_get_luout
USE modi_get_flux_n
USE modi_get_frac_n
USE modi_get_z0_n
USE modi_get_qs_n
USE modi_get_var_sea_n
USE modi_get_var_water_n
USE modi_get_var_nature_n
USE modi_get_var_town_n
USE modi_get_zs_n
USE modi_get_series_n
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_abor1_sfx
USE modi_get_sso_stdev_n
USE modi_get_1d_mask
USE modi_get_coord_n
USE modi_get_veg_n
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
!
TYPE(diag_flake_t), INTENT(INOUT) :: dgf
TYPE(isba_t), INTENT(INOUT) :: i
TYPE(diag_isba_t), INTENT(INOUT) :: dgi
TYPE(diag_misc_isba_t), INTENT(INOUT) :: dgmi
TYPE(diag_seaflux_t), INTENT(INOUT) :: dgs
TYPE(diag_surf_atm_t), INTENT(INOUT) :: dgu
TYPE(diag_teb_t), INTENT(INOUT) :: dgt
TYPE(diag_watflux_t), INTENT(INOUT) :: dgw
TYPE(flake_t), INTENT(INOUT) :: f
TYPE(surf_atm_grid_t), INTENT(INOUT) :: ug
TYPE(surf_atm_t), INTENT(INOUT) :: u
TYPE(surf_atm_sso_t), INTENT(INOUT) :: uss
!
 CHARACTER(LEN=6),   INTENT(IN)            :: hprogram    
INTEGER,            INTENT(IN)            :: ki         ! number of points
INTEGER,            INTENT(IN)            :: ks         ! number of points
!
REAL, DIMENSION(:), INTENT(OUT), OPTIONAL :: psea       ! sea fraction
REAL, DIMENSION(:), INTENT(OUT), OPTIONAL :: pwater     ! water fraction
REAL, DIMENSION(:), INTENT(OUT), OPTIONAL :: pnature    ! nature fraction
REAL, DIMENSION(:), INTENT(OUT), OPTIONAL :: ptown      ! town fraction
!
REAL, DIMENSION(:), INTENT(OUT), OPTIONAL :: pt2m       ! Air temperature at 2 meters         (K)
REAL, DIMENSION(:), INTENT(OUT), OPTIONAL :: pq2m       ! Air humidity at 2 meters            (kg/kg)
!
REAL, DIMENSION(:), INTENT(OUT), OPTIONAL :: pqs
REAL, DIMENSION(:), INTENT(OUT), OPTIONAL :: pz0        ! surface roughness length            (m)
REAL, DIMENSION(:), INTENT(OUT), OPTIONAL :: pz0h       ! surface roughness length for heat   (m)
REAL, DIMENSION(:), INTENT(OUT), OPTIONAL :: pz0eff     ! effective roughness length for heat (m)
!
REAL, DIMENSION(:), INTENT(OUT), OPTIONAL :: pz0_sea    ! surface roughness length over sea   (m)
REAL, DIMENSION(:), INTENT(OUT), OPTIONAL :: pz0_water  ! surface roughness length over water (m)
REAL, DIMENSION(:), INTENT(OUT), OPTIONAL :: pz0_nature ! surface roughness length over nature(m)
REAL, DIMENSION(:), INTENT(OUT), OPTIONAL :: pz0_town   ! surface roughness length over town  (m)
!
REAL, DIMENSION(:), INTENT(OUT), OPTIONAL :: pz0h_sea    ! surface roughness length for heat over sea   (m)
REAL, DIMENSION(:), INTENT(OUT), OPTIONAL :: pz0h_water  ! surface roughness length for heat over water (m)
REAL, DIMENSION(:), INTENT(OUT), OPTIONAL :: pz0h_nature ! surface roughness length for heat over nature(m)
REAL, DIMENSION(:), INTENT(OUT), OPTIONAL :: pz0h_town   ! surface roughness length for heat over town  (m)
!
REAL, DIMENSION(:), INTENT(OUT), OPTIONAL :: pqs_sea    ! surface humidity over sea           (kg/kg)
REAL, DIMENSION(:), INTENT(OUT), OPTIONAL :: pqs_water  ! surface humidity over water         (kg/kg)
REAL, DIMENSION(:), INTENT(OUT), OPTIONAL :: pqs_nature ! surface humidity over nature        (kg/kg)
REAL, DIMENSION(:), INTENT(OUT), OPTIONAL :: pqs_town   ! surface humidity over town          (kg/kg)
!
REAL, DIMENSION(:), INTENT(OUT), OPTIONAL :: ppsng      ! snow fraction over ground           (-)        
REAL, DIMENSION(:), INTENT(OUT), OPTIONAL :: ppsnv      ! snow fraction over vegetation       (-)
!
REAL, DIMENSION(:), INTENT(OUT), OPTIONAL :: pzs        ! surface orography                   (m)    
!
REAL, DIMENSION(:,:), INTENT(OUT), OPTIONAL :: pseries  ! any surface field for which 
!                                                       ! mesoNH series are required
REAL, DIMENSION(:), INTENT(OUT), OPTIONAL :: ptwsnow    ! Snow total reservoir
REAL, DIMENSION(:), INTENT(OUT), OPTIONAL :: psso_stdev ! S.S.O. standard deviation           (m)
!
REAL, DIMENSION(:), INTENT(OUT), OPTIONAL :: plon       ! longitude
REAL, DIMENSION(:), INTENT(OUT), OPTIONAL :: plat       ! latitude
!
REAL, DIMENSION(:), INTENT(OUT), OPTIONAL :: pbare      ! bare soil fraction on grid mesh     (-)
REAL, DIMENSION(:), INTENT(OUT), OPTIONAL :: plai_tree       ! Leaf Area Index    on grid mesh     (-)
REAL, DIMENSION(:), INTENT(OUT), OPTIONAL :: ph_tree        ! Height of trees    on grid mesh     (-)
!
!-------------------------------------------------------------------------------
!
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
REAL, DIMENSION(KI)    :: zfield1, zfield2, zfield3, zfield4, zfield5, zfield6
REAL, DIMENSION(KI)    :: zfield7, zfield8
REAL, DIMENSION(KI,KS) :: zseries
INTEGER, DIMENSION(KI) :: imask
!
INTEGER :: ki_sea    ! dimension of sea tile
INTEGER :: ki_water  ! dimension of water tile
INTEGER :: ki_nature ! dimension of nature tile
INTEGER :: ki_town   ! dimension of town tile
!
INTEGER                            :: ji           ! loop index over tiles
INTEGER                            :: iluout       ! unit number
REAL(KIND=JPRB) :: zhook_handle
!
!-------------------------------------------------------------------------------
!
!*   0. Logical unit for writing out
!
IF (lhook) CALL dr_hook('GET_SURF_VAR_N',0,zhook_handle)
 CALL get_luout(hprogram,iluout)
!
!*   1. Fraction of each tile
!
IF (present(psea) .OR. present(pwater) .OR. present(pnature) .OR. present(ptown)) THEN
   !
   CALL get_frac_n(u, &
                   hprogram, ki, zfield1, zfield2, zfield3, zfield4)
   !
   IF (present(psea)   ) psea    = zfield1
   IF (present(pwater) ) pwater  = zfield2
   IF (present(pnature)) pnature = zfield3
   IF (present(ptown)  ) ptown   = zfield4
   !
END IF
!
!-------------------------------------------------------------------------------
!
!*   2. Parameters at 2 meters
!
IF ( present(pt2m) .OR. present(pq2m) ) THEN
   !
   CALL get_flux_n(dgu, &
                   hprogram, ki, zfield1, zfield1, zfield1, zfield1, zfield1, zfield2, &
                                 zfield3, zfield4, zfield4, zfield4, zfield4, zfield4, &
                                 zfield4, zfield4, zfield4                             )
   !
   IF (present(pt2m)   ) pt2m    = zfield2
   IF (present(pq2m)   ) pq2m    = zfield3
   !
END IF
!
!-------------------------------------------------------------------------------
!
!*   3. Roughness lengths
!
IF ( present(pz0) .OR. present(pz0h) ) THEN
   !
   CALL get_z0_n(dgu, &
                 hprogram, ki, zfield1, zfield2)
   !
   IF (present(pz0)    ) pz0    = zfield1
   IF (present(pz0h)   ) pz0h   = zfield2
   !
END IF
!
!-------------------------------------------------------------------------------
!
!*   3. Specific humidity
!
IF ( present(pqs) ) THEN
   !
   CALL get_qs_n(dgu, &
                 hprogram, ki, pqs)
   !
END IF
!
!-------------------------------------------------------------------------------
!
!*   4. Surface humidity for each tile (qs is not aggregated)
!
IF ( present(pqs_sea) .OR. present(pz0_sea) .OR. present(pz0h_sea) ) THEN
   !
   ! Get parameters over sea tile
   !
   IF ( .NOT.present(psea) ) THEN
      !
      CALL abor1_sfx('GET_SURF_VARN: ARGUMENT PSEA MISSING')
      !
   ENDIF
   !
   ki_sea  = count(psea(:) > 0.0)
   !
   imask(:)=0
   CALL get_1d_mask(ki_sea, ki, psea, imask(1:ki_sea))
   !
   CALL get_var_sea_n(dgs, &
                      hprogram, ki_sea, zfield1(1:ki_sea), zfield2(1:ki_sea), zfield3(1:ki_sea))
   !
   IF(present(pqs_sea))THEN
      pqs_sea(:) = xundef
      DO ji = 1, ki_sea
         pqs_sea(imask(ji))  = zfield1(ji)
      END DO
   ENDIF
   !   
   IF(present(pz0_sea))THEN
      pz0_sea(:) = xundef
      DO ji = 1, ki_sea
         pz0_sea(imask(ji))  = zfield2(ji)
      END DO
   ENDIF
   !
   IF(present(pz0h_sea))THEN
      pz0h_sea(:) = xundef
      DO ji = 1, ki_sea
         pz0h_sea(imask(ji)) = zfield3(ji)
      END DO
   ENDIF
   !
ENDIF
   !
   !-------------------------------------------------------------------------------
   !
IF ( present(pqs_water) .OR. present(pz0_water) .OR. present(pz0h_water) ) THEN
   !
   ! Get parameters over water tile
   !
   IF ( .NOT.present(pwater) ) THEN
      CALL abor1_sfx('GET_SURF_VARN: ARGUMENT PWATER MISSING')
   ENDIF
   !
   ki_water  = count(pwater(:) > 0.0)
   !
   imask(:)=0
   CALL get_1d_mask(ki_water, ki, pwater, imask(1:ki_water))
   !
   CALL get_var_water_n(dgf, dgw, &
                        hprogram, ki_water, u%CWATER, zfield1(1:ki_water), &
                               zfield2(1:ki_water), zfield3(1:ki_water))
   !
   IF(present(pqs_water))THEN
      pqs_water(:) = xundef
      DO ji = 1, ki_water
         pqs_water(imask(ji))  = zfield1(ji)
      END DO
   ENDIF
   !   
   IF(present(pz0_water))THEN
      pz0_water(:) = xundef
      DO ji = 1, ki_water
         pz0_water(imask(ji))  = zfield2(ji)
      END DO
   ENDIF
   !
   IF(present(pz0h_water))THEN
      pz0h_water(:) = xundef
      DO ji = 1, ki_water
         pz0h_water(imask(ji)) = zfield3(ji)
      END DO
   ENDIF
   !
ENDIF
   !
   !-------------------------------------------------------------------------------
   !
IF ( present(pqs_nature) .OR. present(ppsng) .OR. present(ppsnv) .OR.  present(pz0eff).OR. &
     present(ptwsnow) .OR. present(pbare) .OR. present(plai_tree) .OR. present(ph_tree) ) THEN
   !
   ! Get parameters over nature tile
   !
   !
   IF ( .NOT.present(pnature) ) THEN
      !
      CALL abor1_sfx('GET_SURF_VARN: ARGUMENT PNATURE MISSING')
      !
   ENDIF
   !   
   ki_nature = count(pnature(:) > 0.0)
   !
   imask(:)=0
   CALL get_1d_mask(ki_nature, ki, pnature, imask(1:ki_nature))
   !
   IF (ki_nature>0) THEN
     CALL get_var_nature_n(i, dgi, dgmi, &
                           hprogram, ki_nature, zfield1(1:ki_nature), zfield2(1:ki_nature), &
                                                zfield3(1:ki_nature), zfield4(1:ki_nature), &
                          zfield5(1:ki_nature), zfield6(1:ki_nature), zfield7(1:ki_nature), &
                          zfield8(1:ki_nature))
   ENDIF
   !
   IF(present(pqs_nature))THEN
     pqs_nature(:) = xundef
     DO ji = 1, ki_nature
       pqs_nature(imask(ji))  = zfield1(ji)
     END DO
   ENDIF
   !   
   IF(present(pz0_nature))THEN
     pz0_nature(:) = xundef
     DO ji = 1, ki_nature
       pz0_nature(imask(ji))  = zfield5(ji)
     END DO
   ENDIF
   !
   IF(present(pz0h_nature))THEN
     pz0h_nature(:) = xundef
     DO ji = 1, ki_nature
       pz0h_nature(imask(ji)) = zfield6(ji)
     END DO
   ENDIF
   !  
   IF (present(ppsng)) THEN
     ppsng(:) = xundef
     DO ji = 1, ki_nature
       ppsng(imask(ji)) = zfield2(ji)
     END DO
   ENDIF
   !
   IF (present(ppsnv)) THEN
     ppsnv(:) = xundef
     DO ji = 1, ki_nature
       ppsnv(imask(ji)) = zfield3(ji)
     END DO
   ENDIF
   !
   IF ( present(pz0eff) ) THEN
     pz0eff(:) = xundef
     DO ji = 1, ki_nature
       pz0eff(imask(ji)) = zfield4(ji)
     END DO
   ENDIF
   !
   IF(present(ptwsnow)) THEN
     ptwsnow(:) = xundef
     DO ji = 1, ki_nature
       ptwsnow(imask(ji)) = zfield7(ji)
     ENDDO
   ENDIF
   !
   !* bare soil fraction
   !
   IF(present(pbare)) THEN
     pbare(:) = xundef
     DO ji = 1, ki_nature
       pbare(imask(ji)) = zfield8(ji)
     ENDDO
     pbare(:) = pbare(:) * u%XNATURE(:) ! averages bare soil fraction on whole grid mesh
   ENDIF
   !
   !*   LAI and height of trees
   !
   IF (present(plai_tree) .OR. present(ph_tree) ) THEN
     !
     CALL get_veg_n(hprogram, ki_nature, u, i, zfield1(1:ki_nature), zfield2(1:ki_nature))
     !
     IF (present(plai_tree)) THEN
       plai_tree(:) = xundef
       DO ji = 1, ki_nature
         plai_tree(imask(ji)) = zfield1(ji)
       ENDDO
       plai_tree(:) = plai_tree(:) * u%XNATURE(:) ! averages tree LAI on whole grid mesh
     END IF
     !
     IF (present(ph_tree)) THEN
       ph_tree(:) = 0.
       DO ji = 1, ki_nature
         ph_tree(imask(ji)) = zfield2(ji)
       ENDDO
     END IF
     !
   END IF   
   !   
ENDIF
   !
   !-------------------------------------------------------------------------------
   !
IF ( present(pqs_town) .OR. present(pz0_town) .OR. present(pz0h_town) ) THEN
   !
   ! Get parameters over town tile
   !
   IF ( .NOT.present(ptown) ) THEN
      !
      CALL abor1_sfx('GET_SURF_VARN: ARGUMENT PTOWN MISSING')
      !
   ENDIF
   !
   ki_town   = count(ptown(:) > 0.0)
   !
   imask(:)=0
   CALL get_1d_mask(ki_town, ki, ptown, imask(1:ki_town))
   !
   CALL get_var_town_n(dgt, &
                       hprogram, ki_town, zfield1(1:ki_town), zfield2(1:ki_town), zfield3(1:ki_town))
   !
   IF(present(pqs_town))THEN
      pqs_town(:) = xundef
      DO ji = 1, ki_town
         pqs_town(imask(ji))  = zfield1(ji)
      END DO
   ENDIF
   !   
   IF(present(pz0_town))THEN
      pz0_town(:) = xundef
      DO ji = 1, ki_town
         pz0_town(imask(ji))  = zfield2(ji)
      END DO
   ENDIF
   !
   IF(present(pz0h_town))THEN
      pz0h_town(:) = xundef
      DO ji = 1, ki_town
         pz0h_town(imask(ji)) = zfield3(ji)
      END DO
   ENDIF
   !
END IF
!
!*   5. Orography
!
IF (present(pzs)) THEN
   !
   CALL get_zs_n(u, &
                 hprogram, ki, zfield1)
   !
   pzs = zfield1 
   !
END IF
!
!*   6. Series
!
IF (present(pseries)) THEN
   !
   IF ( .NOT.present(pwater) ) THEN
      CALL abor1_sfx('GET_SURF_VARN: ARGUMENT PWATER REQUIRED FOR WATER SERIES')
   ENDIF        
   !
   IF ( count(pwater(:) > 0.0) > 0.0 ) THEN
     !   
     CALL get_series_n(f, &
                       hprogram, ki, ks, zseries)
     !
     pseries = zseries
     !
   ELSE
     pseries = xundef
   ENDIF
   !
END IF
!
!*   7. Subgrid orography standard deviation
!
IF (present(psso_stdev)) THEN
   !
   CALL get_sso_stdev_n(uss, &
                        'ASCII ', ki, zfield1)
   !
   psso_stdev = zfield1
   !
END IF
!
!*   8. Longitude et Latitude
!
IF (present(plon).OR.present(plat)) THEN
   !
   CALL get_coord_n(ug, &
                    hprogram, ki, zfield1, zfield2)
   !
   IF (present(plon)   ) plon    = zfield1
   IF (present(plat)   ) plat    = zfield2
   !
END IF
!
IF (lhook) CALL dr_hook('GET_SURF_VAR_N',1,zhook_handle)
!==============================================================================
!
END SUBROUTINE get_surf_var_n