get_mesh_corner_conf_proj.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #######################################################################################
      SUBROUTINE get_mesh_corner_conf_proj(KGRID_PAR,KL,KC,PGRID_PAR,PCORNER_LAT,PCORNER_LON)
!     #######################################################################################
!
!!**** *GET_MESH_CORNER_CONF_PROJ* get the grid mesh where point (lat,lon) is located
!!
!!    PURPOSE
!!    -------
!!
!!    AUTHOR
!!    ------
!!
!!    B. Decharme         Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original    10/2013
!!
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
USE mode_gridtype_conf_proj
!
USE modi_abor1_sfx
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
INTEGER,                       INTENT(IN)    :: kgrid_par ! size of PGRID_PAR
INTEGER,                       INTENT(IN)    :: kl        ! number of points
INTEGER,                       INTENT(IN)    :: kc        ! number of grid point corner
REAL,    DIMENSION(KGRID_PAR), INTENT(IN)    :: pgrid_par ! grid parameters
REAL,    DIMENSION(KL,KC),     INTENT(OUT)   :: pcorner_lat ! Grid corner Latitude
REAL,    DIMENSION(KL,KC),     INTENT(OUT)   :: pcorner_lon ! Grid corner Longitude
!
!*    0.2    Declaration of other local variables
!            ------------------------------------
!
INTEGER             :: jc       ! loop on corner
!
INTEGER             :: ini      ! Number of point
!
REAL                :: zlat0    ! reference latitude
REAL                :: zlon0    ! reference longitude
REAL                :: zrpk     ! projection parameter 
REAL                :: zbeta    ! angle between grid and reference longitude
REAL                :: zlator   ! latitude  of point of coordinates X=0, Y=0
REAL                :: zlonor   ! longitude of point of coordinates X=0, Y=0
REAL, DIMENSION(KL) :: zx       ! X conformal coordinate
REAL, DIMENSION(KL) :: zy       ! Y conformal coordinate
REAL, DIMENSION(KL) :: zdx      ! size in X conformal coordinate
REAL, DIMENSION(KL) :: zdy      ! size in Y conformal coordinate
!
REAL, DIMENSION(KL,KC) :: zcx ! Grid corner in X
REAL, DIMENSION(KL,KC) :: zcy ! Grid corner in Y
!
REAL(KIND=JPRB) :: zhook_handle
!
!----------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('GET_MESH_CORNER_CONF_PROJ',0,zhook_handle)
!
!*    1.     Gets parameters of the projection
!            ---------------------------------
!
 CALL get_gridtype_conf_proj(pgrid_par,kl=ini)
!  
IF(kl/=ini)THEN
  CALL abor1_sfx('GET_MESH_CORNER_CONF_PROJ: WRONG NUMBER OF POINT')
ENDIF
!
 CALL get_gridtype_conf_proj(pgrid_par,zlat0,zlon0,zrpk,zbeta,zlator, &
                            zlonor,px=zx,py=zy,pdx=zdx,pdy=zdy       )
!
!*    2.     grid cell corner (counterclockwise sense)
!            -----------------------------------------
!
!       4_______3
!       |       |
!       |   .   |
!       |       |
!       |_______|
!       1       2
!
!
zcx(:,1) = zx(:)-zdx(:)/2.
zcy(:,1) = zy(:)-zdy(:)/2.
!
zcx(:,3) = zx(:)+zdx(:)/2.
zcy(:,3) = zy(:)+zdy(:)/2.
!
zcx(:,2) = zcx(:,3)
zcy(:,2) = zcy(:,1)
!
zcx(:,4) = zcx(:,1)
zcy(:,4) = zcy(:,3)
!
DO jc=1,kc
   CALL latlon_conf_proj(zlat0,zlon0,zrpk,zbeta,zlator,zlonor,zcx(:,jc), &
                         zcy(:,jc),pcorner_lat(:,jc),pcorner_lon(:,jc)   )   
ENDDO
!
IF (lhook) CALL dr_hook('GET_MESH_CORNER_CONF_PROJ',1,zhook_handle)
!
!-------------------------------------------------------------------------------
END SUBROUTINE get_mesh_corner_conf_proj