get_adj_mes_gauss.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE get_adj_mes_gauss(KGRID_PAR,KL,PGRID_PAR,KLEFT,KRIGHT,KTOP,KBOTTOM)
!     ##############################################################
!
!!**** *GET_ADJACENT_MESHES_GAUSS* get the near grid mesh indices
!!
!!    PURPOSE
!!    -------
!!
!!    METHOD
!!    ------
!!   
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    V. Masson         Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original    03/2004
!!
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
USE mode_gridtype_gauss
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
INTEGER,                         INTENT(IN)    :: kgrid_par ! size of PGRID_PAR
INTEGER,                         INTENT(IN)    :: kl        ! number of points
REAL,    DIMENSION(KGRID_PAR),   INTENT(IN)    :: pgrid_par ! grid parameters
INTEGER, DIMENSION(KL),          INTENT(OUT)   :: kleft     ! left   mesh index
INTEGER, DIMENSION(KL),          INTENT(OUT)   :: kright    ! right  mesh index
INTEGER, DIMENSION(KL),          INTENT(OUT)   :: ktop      ! top    mesh index
INTEGER, DIMENSION(KL),          INTENT(OUT)   :: kbottom   ! bottom mesh index
!
!*    0.2    Declaration of other local variables
!            ------------------------------------
!
INTEGER :: inlati   ! number of pseudo-latitudes
REAL    :: zlapo    ! latitude of the rotated pole (deg)
REAL    :: zlopo    ! logitude of the rotated pole (deg)
REAL    :: zcodil   ! stretching factor
INTEGER, DIMENSION(:),ALLOCATABLE :: inlopa ! number of pseudo-longitudes
!                                           ! on each pseudo-latitude circle
!                                           ! on pseudo-northern hemisphere
!                                           ! (starting from the rotated pole)
REAL, DIMENSION(:),ALLOCATABLE :: zxcen
!
INTEGER :: jlat, jlon, il, jl, ilgrid, jlon2, id, jl0
!
REAL :: zdis, zinter
!
REAL(KIND=JPRB) :: zhook_handle
!
!----------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('GET_ADJ_MES_GAUSS',0,zhook_handle)
 CALL get_gridtype_gauss(pgrid_par,inlati,zlapo,zlopo,zcodil)
!
ALLOCATE(inlopa(0:inlati))
ALLOCATE(zxcen(kl))
!
 CALL get_gridtype_gauss(pgrid_par,inlati,zlapo,zlopo,zcodil,inlopa(1:inlati), &
                         plon_xy=zxcen        )
!
inlopa(0) = 0
!
kleft(:) = 0
kright(:) = 0
ktop(:) = 0
kbottom(:) = 0
!
il=0
DO jlat=1,inlati
   DO jlon=1,inlopa(jlat)
      il=il+1
   ENDDO
ENDDO
!
jl = 0.0
IF (il==kl) THEN
  DO jlat=1,inlati
    !
    jl0 = jl
    !
    DO jlon=1,inlopa(jlat)
      !
      jl = jl + 1
      !
      IF (jlon>1            ) kleft(jl) = jl-1
      IF (jlon<inlopa(jlat) ) kright(jl) = jl+1
      !
      IF (jlon==1           ) kleft(jl) = jl+inlopa(jlat)-1
      IF (jlon==inlopa(jlat)) kright(jl) = jl-inlopa(jlat)+1
      !
      IF (jlat>1            ) THEN
        zdis = abs(zxcen(jl) - zxcen(jl0 - inlopa(jlat-1) + 1))
        id = 1
        DO jlon2 = 1,inlopa(jlat-1)
          zinter = abs(zxcen(jl) - zxcen(jl0 - inlopa(jlat-1) + jlon2))
          IF (zinter<zdis) THEN
            zdis = zinter
            id = jlon2
          ENDIF
        ENDDO
        ktop(jl) = jl0 - inlopa(jlat-1) + id
      ENDIF
      !
      IF (jlat<inlati       ) THEN
        zdis = abs(zxcen(jl) - zxcen(jl0 + inlopa(jlat) + 1))
        id = 1
        DO jlon2 = 1,inlopa(jlat+1)
          zinter = abs(zxcen(jl) - zxcen(jl0 + inlopa(jlat) + jlon2))
          IF (zinter<zdis) THEN
            zdis = zinter
            id = jlon2
          ENDIF
        ENDDO
        kbottom(jl) = jl0 + inlopa(jlat) + id
      ENDIF
      !
    END DO
  END DO
END IF
!
DEALLOCATE(inlopa)
DEALLOCATE(zxcen)
!
IF (lhook) CALL dr_hook('GET_ADJ_MES_GAUSS',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE get_adj_mes_gauss