garden_properties.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE garden_properties (T, GDM, &
                                    pdir_sw, psca_sw, psw_bands, ksw, &
                                   pts, pemis, palb, pta,            &
                                   palbnir_tveg, palbvis_tveg,       &
                                   palbnir_tsoil, palbvis_tsoil      )  
!     ##########################################################################
!
!!****  *GARDEN_PROPERTIES*  
!!
!!    PURPOSE
!!    -------
!
!     Calculates grid-averaged albedo and emissivity (according to snow scheme)
!         
!!    EXTERNAL
!!    --------
!!
!!    none
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------ 
!!      
!!    AUTHOR
!!    ------
!!
!!      S. Belair           * Meteo-France *
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
!
!
USE modd_teb_n, ONLY : teb_t
USE modd_surfex_n, ONLY : teb_garden_model_t
!
USE modd_surf_par, ONLY : xundef
!
!
USE modi_isba_properties
USE modi_flag_teb_garden_n
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
TYPE(teb_t), INTENT(INOUT) :: t
TYPE(teb_garden_model_t), INTENT(INOUT) :: gdm
!
REAL, DIMENSION(:,:), INTENT(IN)   :: pdir_sw            ! direct incoming solar radiation
REAL, DIMENSION(:,:), INTENT(IN)   :: psca_sw            ! diffus incoming solar radiation
REAL, DIMENSION(:)  , INTENT(IN)   :: psw_bands          ! mean wavelength of each shortwave band (m)
INTEGER,              INTENT(IN)   :: ksw                ! number of short-wave spectral bands
!
REAL, DIMENSION(:)  , INTENT(OUT)  :: pts                ! radiative surface temperature
REAL, DIMENSION(:)  , INTENT(OUT)  :: pemis              ! green areas emissivity
REAL, DIMENSION(:)  , INTENT(OUT)  :: palb               ! green areas albedo
!
REAL, DIMENSION(:)  , INTENT(IN), OPTIONAL :: pta        ! Air temperature (K)
!
REAL, DIMENSION(:)  , INTENT(OUT), OPTIONAL  :: palbnir_tveg       ! nearIR  veg tot albedo
REAL, DIMENSION(:)  , INTENT(OUT), OPTIONAL  :: palbvis_tveg       ! visible veg tot albedo
REAL, DIMENSION(:)  , INTENT(OUT), OPTIONAL  :: palbnir_tsoil      ! nearIR  soil tot albedo
REAL, DIMENSION(:)  , INTENT(OUT), OPTIONAL  :: palbvis_tsoil      ! visible soil tot albedo
!
!-------------------------------------------------------------------------------
!
!*      0.2    Local variables
!              ---------------
!
INTEGER                        :: jlayer
INTEGER                        :: jswb
!
REAL, DIMENSION(SIZE(PALB))    :: ztsnosnow ! surf. temp. on snow free part
REAL, DIMENSION(SIZE(PALB))    :: ztssnow   ! surf. temp. on snow covered part
REAL, DIMENSION(SIZE(PALB))    :: zanosnow  ! snow-free surface albedo
REAL, DIMENSION(SIZE(PALB))    :: zasnow    ! snow albedo
REAL, DIMENSION(SIZE(PALB))    :: zenosnow  ! snow-free surface emissivity
REAL, DIMENSION(SIZE(PALB))    :: zesnow    ! snow emissivity
!
REAL, DIMENSION(SIZE(PALB))    :: zalbnir_tveg       ! nearIR  veg tot albedo
REAL, DIMENSION(SIZE(PALB))    :: zalbvis_tveg       ! visible veg tot albedo
REAL, DIMENSION(SIZE(PALB))    :: zalbnir_tsoil      ! nearIR  soil tot albedo
REAL, DIMENSION(SIZE(PALB))    :: zalbvis_tsoil      ! visible soil tot albedo
!
REAL(KIND=JPRB) :: zhook_handle
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('GARDEN_PROPERTIES',0,zhook_handle)
!
!*      1.     Set physical values for points where there is no garden
!              -------------------------------------------------------
!
! This way, ISBA can run without problem for these points
!
 CALL flag_teb_garden_n(gdm%TGD, gdm%TGDO, gdm%TGDPE, t, gdm%TVG, &
                        1)
!
!
!*      2.     Computes several properties of gardens
!              --------------------------------------
!
 CALL isba_properties(gdm%TVG%CISBA, gdm%TVG%LTR_ML, gdm%TGD%CUR%TSNOW, 1,          &
                     pdir_sw, psca_sw, psw_bands, ksw,                   &
                     gdm%TGDPE%CUR%XALBNIR(:), gdm%TGDPE%CUR%XALBVIS(:), gdm%TGDPE%CUR%XALBUV(:),  &
                     gdm%TGDP%XALBNIR_VEG(:), gdm%TGDP%XALBVIS_VEG(:), gdm%TGDP%XALBUV_VEG(:),    &
                     gdm%TGDP%XALBNIR_SOIL(:), gdm%TGDP%XALBVIS_SOIL(:), gdm%TGDP%XALBUV_SOIL(:),   &
                     gdm%TGDPE%CUR%XVEG(:), gdm%TGDPE%CUR%XLAI(:), gdm%TGDPE%CUR%XZ0(:), &
                     gdm%TGDPE%CUR%XEMIS(:),gdm%TGD%CUR%XTG(:,1),          &
                     zasnow, zanosnow, zesnow, zenosnow, ztssnow, ztsnosnow,      &
                     gdm%TGD%CUR%XSNOWFREE_ALB_VEG, gdm%TGD%CUR%XSNOWFREE_ALB_SOIL,               &
                     zalbnir_tveg, zalbvis_tveg, zalbnir_tsoil, zalbvis_tsoil,    &
                     gdm%TGD%CUR%XPSN(:), gdm%TGD%CUR%XPSNV_A(:), gdm%TGD%CUR%XPSNG(:), &
                     gdm%TGD%CUR%XPSNV(:)          )  
!
gdm%TGD%CUR%XSNOWFREE_ALB = zanosnow
!
!* averaged albedo
palb =  gdm%TGD%CUR%XPSN(:) * zasnow              + (1.-gdm%TGD%CUR%XPSN(:)) * zanosnow
!* averaged emissivity
pemis=  gdm%TGD%CUR%XPSN(:) * zesnow              + (1.-gdm%TGD%CUR%XPSN(:)) * zenosnow
!* averaged surface radiative temperature
!  (recomputed from emitted long wave)
pts  =((gdm%TGD%CUR%XPSN(:) * zesnow * ztssnow**4 + &
        (1.-gdm%TGD%CUR%XPSN(:)) * zenosnow * ztsnosnow**4) / pemis)**0.25
!
IF(present(palbnir_tveg))palbnir_tveg(:)=zalbnir_tveg(:)
IF(present(palbvis_tveg))palbvis_tveg(:)=zalbvis_tveg(:)
IF(present(palbnir_tsoil))palbnir_tsoil(:)=zalbnir_tsoil(:)
IF(present(palbvis_tsoil))palbvis_tsoil(:)=zalbvis_tsoil(:)
!
IF (lhook) CALL dr_hook('GARDEN_PROPERTIES',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE garden_properties