facade_e_budget.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
SUBROUTINE facade_e_budget(HWALL_OPT, HBEM,                                    &
                           pt_wall_a, pt_wall_b, ptstep,                       &
                           phc_wall, ptc_wall, pd_wall,                        &
                           pdn_road, prhoa, pac_wall,                          &
                           pac_bld,                                            &
                           pti_bld, plw_rad, pps, pexns,                       &
                           pabs_sw_wall_a, pabs_sw_wall_b, pt_canyon,          &
                           pts_road, ptsnow_road, pts_garden, pu_win, pgr,     &
                           pabs_sw_win, pf_win_mass, pf_win_wall,              &
                           pf_win_floor, pts_mass, pts_floor, pemis_wall,      &
                           plw_wa_to_wb,                                       &
                           plw_r_to_wa, plw_r_to_wb, plw_g_to_wa, plw_g_to_wb, &
                           plw_s_to_wa, plw_s_to_wb, plw_nr_to_wa,plw_nr_to_wb,&
                           plw_win_to_wa, plw_win_to_wb,                       &
                           plw_s_to_win, plw_wa_to_win, plw_wb_to_win,         &
                           plw_r_to_win, plw_g_to_win, plw_nr_to_win, pt_win1, &
                           pflx_bld_wall_a, pdqs_wall_a,                       &
                           pflx_bld_wall_b, pdqs_wall_b,                       &
                           pt_win2, pemit_lw_fac,                              &
                           pabs_lw_wall_a, pabs_lw_wall_b, pabs_lw_win,        &
                           ph_wall_a, ph_wall_b,                               &
                           pimb_wall, pf_wall_mass, pf_wall_floor,             &
                           pf_wall_win, pradht_in, prad_roof_wall,             &
                           prad_roof_win, prad_wall_floor, prad_wall_mass,     &
                           prad_win_floor, prad_win_mass, pconv_wall_bld,      &
                           pconv_win_bld, pac_win,  pload_in_wall, pload_in_win )
!
!   ##########################################################################
!
!!****  *FACADE_E_BUDGET*  
!!
!!    PURPOSE
!!    -------
!
!     Computes the evolution of wall and window temperature from
!     wall_layer_e_budget et window_e_budget
!         
!     
!!**  METHOD
!     ------
!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    MODD_CST
!!
!!      
!!    REFERENCE
!!    ---------
!!
!!      
!!    AUTHOR
!!    ------
!!
!!      G. Pigeon           * Meteo-France *
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    10/11/2011 
!!      G. Pigeon     /09/2012: new conv. coef for indoor/outdoor 
!!      G. Pigeon     /10/2012: new arg. : solar heat load for indoor
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
USE modd_surf_par, ONLY : xundef
USE modd_csts, ONLY : xcpd
!
USE modi_wall_layer_e_budget
USE modi_window_e_budget
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
 CHARACTER(LEN=4), INTENT(IN)      :: hwall_opt     ! TEB option for walls
                                                   ! 'UNIF' : uniform walls
                                                   ! 'TWO ' : two different opposite walls
 CHARACTER(LEN=3), INTENT(IN)      :: hbem         ! Building Energy model 'DEF' or 'BEM'
REAL, DIMENSION(:,:), INTENT(INOUT) :: pt_wall_a  ! wall A layers temperatures
REAL, DIMENSION(:,:), INTENT(INOUT) :: pt_wall_b  ! wall B layers temperatures
REAL,               INTENT(IN)    :: ptstep       ! time step
REAL, DIMENSION(:,:), INTENT(IN)  :: phc_wall     ! heat capacity for wall layers
REAL, DIMENSION(:,:), INTENT(IN)  :: ptc_wall     ! thermal conductivity for wall layers
REAL, DIMENSION(:,:), INTENT(IN)  :: pd_wall      ! depth of wall layers
REAL, DIMENSION(:), INTENT(IN)    :: pdn_road     ! snow-covered fraction on roads
REAL, DIMENSION(:), INTENT(IN)    :: prhoa        ! rho
REAL, DIMENSION(:), INTENT(IN)    :: pac_wall     ! aerodynamical conductance
!                                                 ! between wall and canyon
REAL, DIMENSION(:), INTENT(IN)    :: pac_bld      ! aerodynamical conductance
                                                  ! inside the building itself
REAL, DIMENSION(:), INTENT(IN)    :: pti_bld      ! inside building temperature
REAL, DIMENSION(:), INTENT(IN)    :: plw_rad      ! atmospheric infrared radiation
REAL, DIMENSION(:), INTENT(IN)    :: pps          ! pressure at the surface
REAL, DIMENSION(:), INTENT(IN)    :: pexns        ! surface Exner function
REAL, DIMENSION(:), INTENT(IN)    :: pabs_sw_wall_a! absorbed solar radiation
REAL, DIMENSION(:), INTENT(IN)    :: pabs_sw_wall_b! absorbed solar radiation
REAL, DIMENSION(:), INTENT(IN)    :: pt_canyon    ! air canyon temperature
REAL, DIMENSION(:), INTENT(IN)    :: pts_road     ! road surface temperature
REAL, DIMENSION(:), INTENT(IN)    :: ptsnow_road  ! road snow temperature
REAL, DIMENSION(:), INTENT(IN)    :: pts_garden   ! green area surface temperature
REAL, DIMENSION(:), INTENT(IN)    :: pu_win       ! window U-factor [W m-2 K-1]
REAL, DIMENSION(:), INTENT(IN)    :: pgr          ! glazing ratio
REAL, DIMENSION(:), INTENT(IN)    :: pabs_sw_win  ! window absorbed shortwave radiation [W m-2] 
REAL, DIMENSION(:),   INTENT(IN)  :: pf_win_mass  ! window mass view factor
REAL, DIMENSION(:),   INTENT(IN)  :: pf_win_wall  ! window wall view factor
REAL, DIMENSION(:),   INTENT(IN)  :: pf_win_floor ! window floor view factor
REAL, DIMENSION(:), INTENT(IN)    :: pts_mass     ! surface mass temperature  [K]
REAL, DIMENSION(:), INTENT(IN)    :: pts_floor    ! floor layers temperatures [K]
REAL, DIMENSION(:), INTENT(IN)    :: pemis_wall   ! wall emissivity
!
REAL, DIMENSION(:), INTENT(IN)    :: plw_wa_to_wb ! LW interactions wall  -> wall (both versions)
REAL, DIMENSION(:), INTENT(IN)    :: plw_r_to_wa  ! LW interactions road -> wall ; DEF formulation 
REAL, DIMENSION(:), INTENT(IN)    :: plw_r_to_wb  ! LW interactions road -> wall ; DEF formulation 
REAL, DIMENSION(:), INTENT(IN)    :: plw_g_to_wa  ! LW interactions garden -> wall ; DEF formulation
REAL, DIMENSION(:), INTENT(IN)    :: plw_g_to_wb  ! LW interactions garden -> wall ; DEF formulation
REAL, DIMENSION(:), INTENT(IN)    :: plw_s_to_wa  ! LW interactions sky   -> wall 
REAL, DIMENSION(:), INTENT(IN)    :: plw_s_to_wb  ! LW interactions sky   -> wall 
REAL, DIMENSION(:), INTENT(IN)    :: plw_nr_to_wa ! LW interactions road(snow) -> wall 
REAL, DIMENSION(:), INTENT(IN)    :: plw_nr_to_wb ! LW interactions road(snow) -> wall 
REAL, DIMENSION(:), INTENT(IN)    :: plw_wa_to_win! Radiative heat trasfer coeff wall-window 
                                                  ! [W K-1 m-2]
REAL, DIMENSION(:), INTENT(IN)    :: plw_wb_to_win! Radiative heat trasfer coeff wall-window 
                                                  ! [W K-1 m-2]
REAL, DIMENSION(:), INTENT(IN)    :: plw_s_to_win ! Radiative heat trasfer coeff window-sky 
                                                  ! [W K-1 m-2]
REAL, DIMENSION(:), INTENT(IN)    :: plw_win_to_wa! Radiative heat trasfer coeff window-wall
                                                  ! [W K-1 m-2] 
REAL, DIMENSION(:), INTENT(IN)    :: plw_win_to_wb! Radiative heat trasfer coeff window-wall
                                                  ! [W K-1 m-2] 
REAL, DIMENSION(:), INTENT(IN)    :: plw_r_to_win ! Radiative heat trasfer coeff window-road 
                                                  ! [W K-1 m-2]
REAL, DIMENSION(:), INTENT(IN)    :: plw_g_to_win ! Radiative heat trasfer coeff window-garden
REAL, DIMENSION(:), INTENT(IN)    :: plw_nr_to_win! Radiative heat trasfer coeff window-snow
!
REAL, DIMENSION(:), INTENT(INOUT) :: pt_win1      ! outdoor window temperature [K]
REAL, DIMENSION(:), INTENT(OUT)   :: pflx_bld_wall_a! flux from bld to wall
REAL, DIMENSION(:), INTENT(INOUT) :: pdqs_wall_a    ! heat storage inside the wall 
REAL, DIMENSION(:), INTENT(OUT)   :: pflx_bld_wall_b! flux from bld to wall
REAL, DIMENSION(:), INTENT(INOUT) :: pdqs_wall_b    ! heat storage inside the wall 
REAL, DIMENSION(:), INTENT(INOUT) :: pt_win2      ! indoor window temperature [K]
REAL, DIMENSION(:), INTENT(OUT)   :: pemit_lw_fac ! LW flux emitted by the facade (W/m2 of facade)
REAL, DIMENSION(:), INTENT(OUT)   :: pabs_lw_wall_a ! absorbed infrared rad.
REAL, DIMENSION(:), INTENT(OUT)   :: pabs_lw_wall_b ! absorbed infrared rad.
REAL, DIMENSION(:), INTENT(OUT)   :: pabs_lw_win  ! window absorbed shortwave radiation [W m-2] 
REAL, DIMENSION(:), INTENT(OUT)   :: ph_wall_a    ! Sensible heat flux from wall to air [W/m2(wall)]
                                                  ! wall = facade - glazing
REAL, DIMENSION(:), INTENT(OUT)   :: ph_wall_b    ! Sensible heat flux from wall to air [W/m2(wall)]
                                                  ! wall = facade - glazing
REAL, DIMENSION(:), INTENT(OUT)   :: pimb_wall    ! wall residual energy imbalance 
                                                  ! for verification [W m-2]
REAL, DIMENSION(:),   INTENT(IN)  :: pf_wall_floor ! View factor wall-floor
REAL, DIMENSION(:),   INTENT(IN)  :: pf_wall_mass  ! View factor wall-mass
REAL, DIMENSION(:),   INTENT(IN)  :: pf_wall_win   ! View factor wall-win
REAL, DIMENSION(:),   INTENT(IN)  :: pradht_in     ! Indoor radiant heat transfer coefficient
                                                    ! [W K-1 m-2]
REAL, DIMENSION(:), INTENT(IN)    :: prad_roof_wall ! rad. fluxes from roof to wall [W m-2(roof)]
REAL, DIMENSION(:), INTENT(IN)    :: prad_roof_win  ! rad. fluxes from roof to win [W m-2(roof)]
REAL, DIMENSION(:), INTENT(OUT)   :: prad_wall_floor! rad. fluxes from wall to floor [W m-2(wall)]
REAL, DIMENSION(:), INTENT(OUT)   :: prad_wall_mass ! rad. fluxes from wall to mass [W m-2(wall)]
REAL, DIMENSION(:), INTENT(OUT)   :: prad_win_floor ! rad. fluxes from window to floor [W m-2(win)]
REAL, DIMENSION(:), INTENT(OUT)   :: prad_win_mass  ! rad. fluxes from window to mass [W m-2(win)]
REAL, DIMENSION(:), INTENT(OUT)   :: pconv_wall_bld ! conv. fluxes from wall to bld [W m-2(wall)]
REAL, DIMENSION(:), INTENT(OUT)   :: pconv_win_bld  ! conv. fluxes from window to bld [W m-2(wind.)]
REAL, DIMENSION(:), INTENT(IN)    :: pac_win        ! window aerodynamic conductance
!
REAL, DIMENSION(:), INTENT(IN)    :: pload_in_wall  ! solar + inter. heat gains W/m2 [wall]
REAL, DIMENSION(:), INTENT(IN)    :: pload_in_win   ! solar + inter. heat gains W/m2 [win]
!*      0.2    declarations of local variables
!
REAL, DIMENSION(SIZE(PTI_BLD)) :: zrad_wall_win   ! rad. fluxes between averaged wall and win [W m-2(wall)]
REAL, DIMENSION(SIZE(PTI_BLD)) :: zrad_wall_a_win ! rad. fluxes between one wall and win [W m-2(wall)]
REAL, DIMENSION(SIZE(PTI_BLD)) :: zemis_win     ! window emissivity
REAL, DIMENSION(SIZE(PTI_BLD)) :: zemit_lw_win  ! Longwave radiation emitted by the window [W m-2(window)]
REAL, DIMENSION(SIZE(PTI_BLD)) :: zemit_lw_wall_a ! Longwave radiation emitted by the wall [W m-2(wall)]
REAL, DIMENSION(SIZE(PTI_BLD)) :: zemit_lw_wall_b ! Longwave radiation emitted by the wall [W m-2(wall)]
REAL, DIMENSION(SIZE(PTI_BLD)) :: zts_wall_a    ! surface temperature of wall A at previous time-step
REAL, DIMENSION(SIZE(PTI_BLD)) :: zts_wall_b    ! surface temperature of wall B at previous time-step
REAL, DIMENSION(SIZE(PTI_BLD)) :: zti_wall_a    ! internal temperature of wall A at previous time-step
REAL, DIMENSION(SIZE(PTI_BLD)) :: zti_wall_b    ! internal temperature of wall B at previous time-step
REAL, DIMENSION(SIZE(PTI_BLD)) :: zts_wall      ! surface temperature of averaged wall at new time-step
REAL, DIMENSION(SIZE(PTI_BLD)) :: zimb_wall     ! wall residual energy imbalance for verification [W m-2]
REAL, DIMENSION(SIZE(PTI_BLD)) :: zrad_wall_floor! rad. fluxes from wall to floor [W m-2(wall)]
REAL, DIMENSION(SIZE(PTI_BLD)) :: zrad_wall_mass ! rad. fluxes from wall to mass [W m-2(wall)]
REAL, DIMENSION(SIZE(PTI_BLD)) :: zconv_wall_bld ! conv. fluxes from wall to bld [W m-2(wall)]
REAL, DIMENSION(SIZE(PTI_BLD)) :: zlw_w_to_win   ! Radiative heat trasfer coeff wall-window [W K-1 m-2]
INTEGER                        :: iwall
REAL(KIND=JPRB) :: zhook_handle
!-------------------------------------------------------------------------------
IF (lhook) CALL dr_hook('FACADE_E_BUDGET',0,zhook_handle)
!-------------------------------------------------------------------------------
prad_wall_floor= xundef
prad_wall_mass = xundef
prad_win_floor = xundef
prad_win_mass  = xundef
pconv_wall_bld = xundef
pconv_win_bld  = xundef
!
!* surface temperature of the opposite wall
!  ----------------------------------------
!
zts_wall_a(:) = pt_wall_a(:,1)
zts_wall_b(:) = pt_wall_b(:,1)
iwall = SIZE(pt_wall_a,2)
zti_wall_a(:) = pt_wall_a(:,iwall)
zti_wall_b(:) = pt_wall_b(:,iwall)
!
! *Convection heat transfer coefficients [W m-2 K-1] from EP Engineering Reference
! --------------------------------------------------------------------------------
!
!
! *opaque balance of the facade for wall A
!  ---------------------------------------
!
 CALL wall_layer_e_budget(hbem, pt_wall_a, zts_wall_b, zti_wall_b, ptstep,                     &
                         phc_wall, ptc_wall, pd_wall, pdn_road, prhoa, pac_wall,  &
                         pac_bld, pti_bld, plw_rad, pps, pexns, pabs_sw_wall_a, pt_canyon,    &
                         pts_road, ptsnow_road, pts_garden, pts_mass, pts_floor, pemis_wall,  &
                         plw_wa_to_wb, plw_r_to_wa, plw_g_to_wa, plw_nr_to_wa,                &
                         plw_win_to_wa, plw_s_to_wa,                                          &
                         pt_win1, pflx_bld_wall_a, pdqs_wall_a, pt_win2, pabs_lw_wall_a,      &
                         zemit_lw_wall_a, ph_wall_a, zimb_wall, pf_wall_mass,                 &
                         pf_wall_floor, pf_wall_win, pradht_in, prad_roof_wall,               &
                         zrad_wall_a_win, zrad_wall_floor, zrad_wall_mass, zconv_wall_bld,    &
                         pload_in_wall)
!
pimb_wall       = 0.5 * zimb_wall
prad_wall_floor = 0.5 * zrad_wall_floor
prad_wall_mass  = 0.5 * zrad_wall_mass 
pconv_wall_bld  = 0.5 * zconv_wall_bld 
zrad_wall_win   = 0.5 * zrad_wall_a_win
!
! *opaque balance of the facade for wall B
!  ---------------------------------------
!
IF (hwall_opt/='UNIF') THEN
 CALL wall_layer_e_budget(hbem, pt_wall_b, zts_wall_a, zti_wall_a, ptstep,                     &
                         phc_wall, ptc_wall, pd_wall, pdn_road, prhoa, pac_wall,              &
                         pac_bld, pti_bld, plw_rad, pps, pexns, pabs_sw_wall_b, pt_canyon,    &
                         pts_road, ptsnow_road, pts_garden, pts_mass, pts_floor, pemis_wall,  &
                         plw_wa_to_wb, plw_r_to_wb, plw_g_to_wb, plw_nr_to_wb,                &
                         plw_win_to_wb, plw_s_to_wb,                                          &
                         pt_win1, pflx_bld_wall_b, pdqs_wall_b, pt_win2, pabs_lw_wall_b,      &
                         zemit_lw_wall_b, ph_wall_b, zimb_wall, pf_wall_mass,                 &
                         pf_wall_floor, pf_wall_win, pradht_in, prad_roof_wall,               &
                         zrad_wall_a_win, zrad_wall_floor, zrad_wall_mass, zconv_wall_bld,    & 
                         pload_in_wall                                                        )
ELSE
  pt_wall_b        = pt_wall_a
  ph_wall_b        = ph_wall_a
  pabs_lw_wall_b   = pabs_lw_wall_a
  pdqs_wall_b      = pdqs_wall_a
  pflx_bld_wall_b  = pflx_bld_wall_a
  zemit_lw_wall_b  = zemit_lw_wall_a
END IF
!
pimb_wall       = pimb_wall       + 0.5 * zimb_wall
prad_wall_floor = prad_wall_floor + 0.5 * zrad_wall_floor
prad_wall_mass  = prad_wall_mass  + 0.5 * zrad_wall_mass 
pconv_wall_bld  = pconv_wall_bld  + 0.5 * zconv_wall_bld 
zrad_wall_win   = zrad_wall_win   + 0.5 * zrad_wall_a_win
!
!-------------------------------------------------------------------------------
!
! *Energy Balance for windows (averaged on both walls)
!  ---------------------------------------------------
!
IF (hbem == 'DEF') THEN
  zemit_lw_win(:) = 0.
  pabs_lw_win(:) = xundef
END IF
!
IF (hbem == 'BEM') THEN
        zemis_win(:) = 0.84 ! From Engineering Reference documentation p219 
                            ! (see http://apps1.eere.energy.gov/buildings/energyplus/
   zlw_w_to_win(:) = plw_wa_to_win(:) + plw_wb_to_win(:)
   zts_wall(:) = xundef
   WHERE (zlw_w_to_win(:)>0.) &
   zts_wall(:) = ( plw_wa_to_win(:)*pt_wall_a(:,1)+plw_wb_to_win(:)*pt_wall_b(:,1) ) / zlw_w_to_win(:)
   CALL window_e_budget(pu_win, zemis_win, pf_win_floor, pf_win_wall, pf_win_mass,                &
                        zlw_w_to_win, plw_r_to_win, plw_g_to_win, plw_nr_to_win, plw_s_to_win,    &
                        prad_roof_win, zrad_wall_win, pabs_sw_win, plw_rad, pac_win,              &
                        pradht_in, pti_bld, pts_mass, pts_floor, prhoa, pdn_road,                 &
                        pt_canyon, zts_wall, pts_road, ptsnow_road, pts_garden,                   &
                        pt_win1, pt_win2, prad_win_floor, prad_win_mass, pconv_win_bld,           &
                        zemit_lw_win, pabs_lw_win, pload_in_win                                   )
ENDIF

!*        wall, and win emitted LW radiation on snow-free surfaces
!         ----------------------------------------------------------------
!
!
pemit_lw_fac(:) = 0.5*(zemit_lw_wall_a(:)+zemit_lw_wall_b(:)) * (1-pgr(:)) +  zemit_lw_win(:) * pgr(:)
!
!-------------------------------------------------------------------------------
IF (lhook) CALL dr_hook('FACADE_E_BUDGET',1,zhook_handle)
END SUBROUTINE facade_e_budget