dslt_init_names.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE dslt_init_names (KLUOUT, HRC1, HSV, KPMODE, &
                            keq, ksv_beg, ksv_end, ovarsig, orgfix)
!!    ###########################################
!!
!!*** *DSLT_INIT_NAMES*
!!
!!    PURPOSE
!!    -------
!!      Read and filter all chemical species into the CSV array
!!     initialize NSV_CHSBEG and  NSV_CHSEND index for the begin and the ending chemical index
!!     
!!
!!    REFERENCE
!!    ---------
!!    Modified ch_init_names (february 2005)    
!!
!!    AUTHOR
!!    ------
!!    Alf Grini <alf.grini@cnrm.meteo.fr>
!!
!!    MODIFICATIONS
!!    -------------
!!
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
INTEGER,                         INTENT(IN)  :: kluout   ! output listing channel
 CHARACTER(LEN=4),                INTENT(IN)  :: hrc1
 CHARACTER(LEN=*), DIMENSION(:),  INTENT(IN)  :: hsv      ! name of chemical species
                                                         ! with character # for chemistry
INTEGER,                         INTENT(OUT) :: kpmode
INTEGER,                         INTENT(OUT) :: keq         ! number of dust related variables
INTEGER,                         INTENT(OUT) :: ksv_beg     ! first dust related scalar
INTEGER,                         INTENT(OUT) :: ksv_end     ! last  dust related scalar
LOGICAL,                         INTENT(INOUT) :: ovarsig   ! type of standard deviation
LOGICAL,                         INTENT(INOUT) :: orgfix    ! type of mean radius
!
!*      0.2    declarations of local variables
INTEGER :: jsv  !! loop on scalar variables
 CHARACTER(LEN=4) :: yrc1
REAL(KIND=JPRB) :: zhook_handle
!
!-------------------------------------------------------------------------------

!Initialize output variables
IF (lhook) CALL dr_hook('DSLT_INIT_NAMES',0,zhook_handle)
!
keq  = 0
ksv_beg = 0
ksv_end = 0
!
DO jsv=1, SIZE(hsv)
  !
  yrc1= hsv(jsv)(1:4)
  !
  IF (yrc1 == hrc1) THEN
    !
    IF (hsv(jsv)(5:5) == '6') ovarsig = .true.
    IF (hsv(jsv)(5:5) == '0') orgfix  = .false.
    !
    keq = keq + 1
    IF (keq == 1) ksv_beg = jsv
    !
  ENDIF
  !
ENDDO
!
! Set the output list of scalar to the input list of scalars
!
! Get the index of the last dust relevant tracer
ksv_end = ksv_beg + keq - 1
!
! Get number of dust modes. Each mode represents
! 3 moments, so 9 dust tracers represents 3 modes.
! 3 dust tracers represents 1 mode
kpmode = ksv_end - ksv_beg + 1
IF (ovarsig) THEN
  kpmode = int(kpmode / 3.)
ELSE IF (.NOT.orgfix) THEN
  kpmode = int(kpmode / 2.)
END IF
!
IF (lhook) CALL dr_hook('DSLT_INIT_NAMES',1,zhook_handle)
!
END SUBROUTINE dslt_init_names