diag_surf_budget_sea.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE  diag_surf_budget_sea(PTT , PSST, PRHOA, PSFTH, PSFTH_ICE,    &
                                 psftq, psftq_ice,                       &
                                 pdir_sw, psca_sw, plw,                  &
                                 pdir_alb,psca_alb,palb_ice,pemis, ptrad,&
                                 psfzon, psfzon_ice, psfmer, psfmer_ice, &
                                 ohandle_sic, psic, ptice,               &
                                 prn, ph, ple, ple_ice, pgflux,             &
                                 pswd, pswu, pswbd, pswbu, plwd, plwu,   &
                                 pfmu, pfmv, pevap, psubl,               &
                                 prn_ice, ph_ice, pgflux_ice,            &
                                 pswu_ice, pswbu_ice, plwu_ice,          &
                                 pfmu_ice, pfmv_ice                      ) 


!     ###############################################################################
!
!!****  *DIAG_SURF_BUDGET_WATER * - Computes diagnostics over water
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     V. Masson 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004
!       B. decharme 04/2013 : Add EVAP and SUBL diag
!       S.Senesi    01/2014 : Handle fluxes on seaice
!!------------------------------------------------------------------
!

!
!
USE modd_csts,           ONLY : xstefan, xlstt, xlvtt
USE modd_water_par,      ONLY : xemiswatice, xalbseaice
! 
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
USE modi_abor1_sfx
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
REAL,               INTENT(IN) :: ptt       ! freezing temperature of water surface
REAL, DIMENSION(:), INTENT(IN) :: psst      ! sea surface temperature (K)
REAL, DIMENSION(:), INTENT(IN) :: prhoa     ! air density
REAL, DIMENSION(:), INTENT(IN) :: psfth     ! heat flux
REAL, DIMENSION(:), INTENT(IN) :: psfth_ice ! heat flux on seaice
!
REAL, DIMENSION(:), INTENT(IN) :: psftq     ! water flux
REAL, DIMENSION(:), INTENT(IN) :: psftq_ice ! water flux on seaice
!
REAL, DIMENSION(:,:),INTENT(IN):: pdir_sw   ! direct  solar radiation (on horizontal surf.)
!                                           !                                       (W/m2)
REAL, DIMENSION(:,:),INTENT(IN):: psca_sw   ! diffuse solar radiation (on horizontal surf.)
!                                           !                                       (W/m2)
REAL, DIMENSION(:), INTENT(IN) :: plw       ! longwave radiation (on horizontal surf.)
!
REAL, DIMENSION(:,:),INTENT(IN):: pdir_alb  ! direct albedo for each spectral band  (-)
REAL, DIMENSION(:,:),INTENT(IN):: psca_alb  ! diffuse albedo for each spectral band (-)
REAL, DIMENSION(:)  ,INTENT(IN):: palb_ice  ! Seaice albedo 
REAL, DIMENSION(:), INTENT(IN) :: pemis     ! emissivity                            (-)
REAL, DIMENSION(:), INTENT(IN) :: ptrad     ! radiative temperature                 (K)
!
REAL, DIMENSION(:), INTENT(IN) :: psfzon    ! zonal friction
REAL, DIMENSION(:), INTENT(IN) :: psfzon_ice! zonal friction
REAL, DIMENSION(:), INTENT(IN) :: psfmer    ! meridional friction
REAL, DIMENSION(:), INTENT(IN) :: psfmer_ice! meridional friction
!
LOGICAL, INTENT(IN)         :: ohandle_sic  ! Do we weight seaice and open sea fluxes
REAL, DIMENSION(:), INTENT(IN) :: psic      ! Sea ice cover                         (-)
REAL, DIMENSION(:), INTENT(IN) :: ptice     ! Sea ice temperature                   (°K)
!
REAL, DIMENSION(:), INTENT(OUT):: prn       ! net radiation                         (W/m2)
REAL, DIMENSION(:), INTENT(OUT):: ph        ! sensible heat flux                    (W/m2)
REAL, DIMENSION(:), INTENT(OUT):: ple       ! total latent heat flux                (W/m2)
REAL, DIMENSION(:), INTENT(OUT):: ple_ice      ! sublimation latent heat flux          (W/m2)
REAL, DIMENSION(:), INTENT(OUT):: pgflux    ! storage flux                          (W/m2)
!
REAL, DIMENSION(:),  INTENT(OUT):: pswd     ! total incoming short wave radiation   (W/m2)
REAL, DIMENSION(:),  INTENT(OUT):: pswu     ! total upward short wave radiation     (W/m2)
REAL, DIMENSION(:,:), INTENT(OUT):: pswbd   ! incoming short wave radiation by spectral band (W/m2)
REAL, DIMENSION(:,:), INTENT(OUT):: pswbu   ! upward  short wave radiation by spectral band (W/m2)
REAL, DIMENSION(:),  INTENT(OUT):: plwd     ! Downward long wave radiation          (W/m2)
REAL, DIMENSION(:),  INTENT(OUT):: plwu     ! Upward long wave radiation            (W/m2)
!
REAL, DIMENSION(:), INTENT(OUT):: pfmu      ! zonal wind stress
REAL, DIMENSION(:), INTENT(OUT):: pfmv      ! meridian wind stress
REAL, DIMENSION(:), INTENT(OUT):: pevap     ! total evaporation                     (kg/m2/s)
REAL, DIMENSION(:), INTENT(OUT):: psubl     ! sublimation                           (kg/m2/s)
! Fluxes on seaice
REAL, DIMENSION(:), INTENT(OUT):: prn_ice   ! net radiation                         (W/m2)
REAL, DIMENSION(:), INTENT(OUT):: ph_ice    ! sensible heat flux                    (W/m2)
REAL, DIMENSION(:), INTENT(OUT):: pgflux_ice! storage flux                          (W/m2)
! Continued
REAL, DIMENSION(:),  INTENT(OUT):: pswu_ice ! total upward short wave radiation (W/m2)
REAL, DIMENSION(:,:),INTENT(OUT):: pswbu_ice! upward  short wave radiation by spectral band (W/m2)
REAL, DIMENSION(:),  INTENT(OUT):: plwu_ice ! upward long wave radiation (W/m2)
REAL, DIMENSION(:),  INTENT(OUT):: pfmu_ice ! zonal wind stress on sea-ice
REAL, DIMENSION(:),  INTENT(OUT):: pfmv_ice ! meridian wind stress on sea-ice

!*      0.2    declarations of local variables
!
INTEGER                      :: i
INTEGER                      :: iswb ! number of SW bands
INTEGER                      :: jswb ! loop counter on number of SW bands
REAL(KIND=JPRB) :: zhook_handle
!-------------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('DIAG_SURF_BUDGET_SEA',0,zhook_handle)
!
iswb = SIZE(pdir_sw,2)
! 
!* total incoming and outgoing SW
!
DO jswb=1,iswb
  pswbd(:,jswb) = pdir_sw(:,jswb)                    + psca_sw(:,jswb)
  pswbu(:,jswb) = pdir_sw(:,jswb) * pdir_alb(:,jswb) + psca_sw(:,jswb) * psca_alb(:,jswb) 
ENDDO
!
pswd(:) = 0.
pswu(:) = 0.
DO jswb=1,iswb
   pswd(:)=pswd(:)+pswbd(:,jswb)
   pswu(:)=pswu(:)+pswbu(:,jswb)
ENDDO
!
!*incoming outgoing LW
!
plwd(:)=plw(:)
plwu(:)=pemis(:)*xstefan*ptrad(:)**4 + (1.-pemis(:))*plw(:)
!
!* net radiation
!
prn(:)    =   pswd(:) - pswu(:)     + plwd(:) - plwu(:)
!
IF (.NOT.ohandle_sic) THEN
  !
  !* sensible heat flux
  !
  ph     = psfth
  !
  !* latent heat flux
  !
  WHERE (psst<ptt  )
     ple    = psftq * xlstt
     ple_ice= psftq * xlstt
     pevap  = psftq
     psubl  = psftq
  ELSEWHERE
     ple    = psftq * xlvtt
     ple_ice= 0.0
     pevap  = psftq
     psubl  = 0.0
  END WHERE
  !
  !* wind stress
  !
  pfmu = psfzon
  pfmv = psfmer
!
ELSE
  !
  !---------------------------------------------------------------------------- 
  ! Sea ice or mixed diag
  !---------------------------------------------------------------------------- 
  !
  !
  !* total incoming and outgoing SW
  !
  DO jswb=1,iswb
   pswbu_ice(:,jswb) = (pdir_sw(:,jswb) + psca_sw(:,jswb)) * palb_ice(:) 
  ENDDO
  !
  pswu_ice(:) = 0.
  DO jswb=1,iswb
     pswu_ice(:)=pswu_ice(:)+pswbu_ice(:,jswb)
  ENDDO
  !
  !*incoming outgoing LW
  !
  plwu_ice(:)=xemiswatice*xstefan*ptice(:)**4 + (1.-xemiswatice)*plw(:)
  !
  !* net radiation
  !
  prn_ice(:) =   pswd(:) - pswu_ice(:) + plwd(:) - plwu_ice(:)
  !
  !* sensible heat flux
  !
  ph     = (1 - psic) * psfth         + psic * psfth_ice 
  ph_ice =                                     psfth_ice
  !
  !* latent heat flux
  !
  ple     = (1 - psic) * psftq * xlvtt + psic * psftq_ice * xlstt
  ple_ice =                                     psftq_ice * xlstt
  pevap   = (1 - psic) * psftq         + psic * psftq_ice 
  psubl   =                              psic * psftq_ice 
  !
  !* ice storage flux
  !
   pgflux_ice = prn_ice - ph_ice - ple_ice
  !
  !* wind stress
  !
  pfmu = (1 - psic) * psfzon + psic * psfzon_ice
  pfmu_ice =                          psfzon_ice
  pfmv = (1 - psic) * psfmer + psic * psfmer_ice
  pfmv_ice =                          psfmer_ice
!  
ENDIF
!
!* total storage flux
!
pgflux = prn - ph - ple
!
!
IF (lhook) CALL dr_hook('DIAG_SURF_BUDGET_SEA',1,zhook_handle)
!
!-------------------------------------------------------------------------------------
!
END SUBROUTINE diag_surf_budget_sea