diag_inline_idealn.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
       SUBROUTINE diag_inline_ideal_n (DGL, PTSTEP, PTA, PTS, PQA, PPA, PPS, PRHOA, PZONA,  &
                                         pmera, pht, phw, prain, psnow,                &
                                         pcd, pcdn, pch, pri, phu, pz0,                &
                                         pz0h, pqsat, psfth, psftq, psfzon, psfmer,    &
                                         pdir_sw, psca_sw, plw, pdir_alb, psca_alb,    &
                                         ple, plei, psubl, plwup)  
!     ###############################################################################
!
!!****  *DIAG_INLINE_IDEAL_n * - computes diagnostics during IDEAL time-step
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     P. Le Moigne 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    03/2015
!!------------------------------------------------------------------
!
!
USE modd_diag_ideal_n, ONLY : diag_ideal_t
!
USE modd_csts,         ONLY : xtt, xlvtt
USE modd_surf_par,     ONLY : xundef
!
USE modi_param_cls
USE modi_cls_tq
USE modi_cls_wind
USE modi_diag_surf_budget_ideal
USE modi_diag_surf_budgetc_ideal
USE modi_abor1_sfx
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
TYPE(diag_ideal_t), INTENT(INOUT) :: dgl
!
REAL              , INTENT(IN) :: ptstep ! atmospheric time-step (s)
REAL, DIMENSION(:), INTENT(IN) :: pta    ! atmospheric temperature
REAL, DIMENSION(:), INTENT(IN) :: pts    ! surface temperature
REAL, DIMENSION(:), INTENT(IN) :: pqa    ! atmospheric specific humidity
REAL, DIMENSION(:), INTENT(IN) :: ppa    ! atmospheric level pressure
REAL, DIMENSION(:), INTENT(IN) :: pps    ! surface pressure
REAL, DIMENSION(:), INTENT(IN) :: prhoa  ! air density
REAL, DIMENSION(:), INTENT(IN) :: pzona  ! zonal wind
REAL, DIMENSION(:), INTENT(IN) :: pmera  ! meridian wind
REAL, DIMENSION(:), INTENT(IN) :: pht    ! atmospheric level height
REAL, DIMENSION(:), INTENT(IN) :: phw    ! atmospheric level height for wind
REAL, DIMENSION(:), INTENT(IN) :: prain  ! Rainfall (kg/m2/s)
REAL, DIMENSION(:), INTENT(IN) :: psnow  ! Snowfall (kg/m2/s)
REAL, DIMENSION(:), INTENT(IN) :: pcd    ! drag coefficient for momentum
REAL, DIMENSION(:), INTENT(IN) :: pcdn   ! neutral drag coefficient
REAL, DIMENSION(:), INTENT(IN) :: pch    ! drag coefficient for heat
REAL, DIMENSION(:), INTENT(IN) :: pri    ! Richardson number
REAL, DIMENSION(:), INTENT(IN) :: phu    ! near-surface humidity
REAL, DIMENSION(:), INTENT(IN) :: pz0    ! roughness length for momentum
REAL, DIMENSION(:), INTENT(IN) :: pz0h   ! roughness length for heat
REAL, DIMENSION(:), INTENT(IN) :: pqsat  ! humidity at saturation
REAL, DIMENSION(:), INTENT(IN) :: psfzon ! zonal friction
REAL, DIMENSION(:), INTENT(IN) :: psfmer ! meridian friction
REAL, DIMENSION(:), INTENT(IN) :: psfth  ! heat flux  (W/m2)
REAL, DIMENSION(:), INTENT(IN) :: psftq  ! water flux (kg/m2/s)
REAL, DIMENSION(:,:),INTENT(IN):: pdir_sw   ! direct  solar radiation (on horizontal surf.)
!                                           !                                       (W/m2)
REAL, DIMENSION(:,:),INTENT(IN):: psca_sw   ! diffuse solar radiation (on horizontal surf.)
!                                           !                                       (W/m2)
REAL, DIMENSION(:), INTENT(IN) :: plw       ! longwave radiation (on horizontal surf.) (W/m2)
REAL, DIMENSION(:,:),INTENT(IN):: pdir_alb  ! direct albedo for each spectral band  (-)
REAL, DIMENSION(:,:),INTENT(IN):: psca_alb  ! diffuse albedo for each spectral band (-)
REAL, DIMENSION(:), INTENT(IN) :: ple       ! total latent heat flux (W/m2)
REAL, DIMENSION(:), INTENT(IN) :: plei      ! sublimation heat flux (W/m2)
REAL, DIMENSION(:), INTENT(IN) :: psubl     ! sublimation (kg/m2/s)
REAL, DIMENSION(:), INTENT(IN) :: plwup     ! upward longwave radiation (W/m2)
!
!*      0.2    declarations of local variables
!
REAL, DIMENSION(SIZE(PTA)) :: zh
REAL(KIND=JPRB) :: zhook_handle
!-------------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('DIAG_INLINE_IDEAL_N',0,zhook_handle)
!
dgl%XDIAG_TS(:) = pts(:)
!
  IF (dgl%N2M==1) THEN
    CALL param_cls(pta, pts, pqa, ppa, prhoa, pzona, pmera, pht, phw, &
                     psfth, psftq, psfzon, psfmer,                    &
                     dgl%XT2M, dgl%XQ2M, dgl%XHU2M, dgl%XZON10M, dgl%XMER10M )  
  ELSE IF (dgl%N2M==2) THEN
    zh(:)=2.          
    CALL cls_tq(pta, pqa, ppa, pps, pht,         &
                  pcd, pch, pri,                 &
                  pts, phu, pz0h, zh,            &
                  dgl%XT2M, dgl%XQ2M, dgl%XHU2M  )  
    zh(:)=10.                
    CALL cls_wind(pzona, pmera, phw,        &
                  pcd, pcdn, pri, zh,       &
                  dgl%XZON10M, dgl%XMER10M  )  
  END IF
!
  IF (dgl%N2M>=1) THEN
    !
    dgl%XT2M_MIN(:) = min(dgl%XT2M_MIN(:),dgl%XT2M(:))
    dgl%XT2M_MAX(:) = max(dgl%XT2M_MAX(:),dgl%XT2M(:))
    !
    dgl%XHU2M_MIN(:) = min(dgl%XHU2M_MIN(:),dgl%XHU2M(:))
    dgl%XHU2M_MAX(:) = max(dgl%XHU2M_MAX(:),dgl%XHU2M(:))
    !
    dgl%XWIND10M(:) = sqrt(dgl%XZON10M(:)**2+dgl%XMER10M(:)**2)
    dgl%XWIND10M_MAX(:) = max(dgl%XWIND10M_MAX(:),dgl%XWIND10M(:))
    !
    !* Richardson number
    dgl%XRI = pri
    !
  ENDIF
!
IF (dgl%LSURF_BUDGET) THEN
  !
  dgl%XLE  (:) = ple(:)
  dgl%XLEI (:) = plei(:)
  dgl%XEVAP(:) = psftq(:)
  dgl%XSUBL(:) = psubl(:)
  !
  CALL  diag_surf_budget_ideal( prhoa, psfth,                     &
                                  pdir_sw, psca_sw, plw,                &
                                  pdir_alb, psca_alb, plwup,            &
                                  psfzon, psfmer, dgl%XLE, dgl%XRN,     &
                                  dgl%XH, dgl%XGFLUX, dgl%XSWD,         &
                                  dgl%XSWU, dgl%XSWBD, dgl%XSWBU,       &
                                  dgl%XLWD, dgl%XLWU, dgl%XFMU, dgl%XFMV )  
  !
END IF
!
IF( dgl%LSURF_BUDGETC)THEN
  CALL diag_surf_budgetc_ideal(dgl, ptstep,  dgl%XRN,  dgl%XH,  dgl%XLE,  &
                               dgl%XLEI,  dgl%XGFLUX, dgl%XSWD,  dgl%XSWU, &
                               dgl%XLWD,  dgl%XLWU,  dgl%XFMU,  dgl%XFMV,  &
                               dgl%XEVAP, dgl%XSUBL                    )  
ENDIF
!
IF (dgl%LCOEF) THEN
  !
  !* Transfer coefficients
  !
  dgl%XCD = pcd
  dgl%XCH = pch
  dgl%XCE = pch
  !
  !* Roughness lengths
  !
  dgl%XZ0  = pz0
  dgl%XZ0H = pz0h
  !
END IF
!
IF (dgl%LSURF_VARS) THEN
  !
  !* Humidity at saturation
  !
  dgl%XQS = pqsat
  !
END IF
!
IF (lhook) CALL dr_hook('DIAG_INLINE_IDEAL_N',1,zhook_handle)
!-------------------------------------------------------------------------------------
!
END SUBROUTINE diag_inline_ideal_n