diag_inline_flaken.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
       SUBROUTINE diag_inline_flake_n (DGF, F, &
                                        ptstep, pta, pqa, ppa, pps, prhoa, pzona,  &
                                         pmera, pht, phw, prain, psnow,                &
                                         pcd, pcdn, pch, pri, phu,                &
                                         pz0h, pqsat, psfth, psftq, psfzon, psfmer,    &
                                         pdir_sw, psca_sw, plw, pdir_alb, psca_alb,    &
                                         ple, plei, psubl, plwup, palb, pswe           )  
!     ###############################################################################
!
!!****  *DIAG_INLINE_FLAKE_n * - computes diagnostics during FLAKE time-step
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     V. Masson 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004
!!      S. Riette    06/2009 CLS_2M becomes CLS_TQ, CLS_TQ and CLS_WIND have one
!!                           more argument (height of diagnostic)
!!      P. Le Moigne 04/2013 : Accumulated diagnostics
!!                             Coupling for ESM
!!------------------------------------------------------------------
!

!
!
!
USE modd_diag_flake_n, ONLY : diag_flake_t
USE modd_flake_n, ONLY : flake_t
!
USE modd_csts,         ONLY : xtt
USE modd_surf_par,     ONLY : xundef
USE modd_sfx_oasis,    ONLY : lcpl_lake
!
USE modi_param_cls
USE modi_cls_tq
USE modi_cls_wind
USE modi_diag_surf_budget_flake
USE modi_diag_surf_budgetc_flake
USE modi_diag_cpl_esm_flake
USE modi_abor1_sfx
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
TYPE(diag_flake_t), INTENT(INOUT) :: dgf
TYPE(flake_t), INTENT(INOUT) :: f
!
REAL              , INTENT(IN) :: ptstep ! atmospheric time-step (s)
REAL, DIMENSION(:), INTENT(IN) :: pta    ! atmospheric temperature
REAL, DIMENSION(:), INTENT(IN) :: pqa    ! atmospheric specific humidity
REAL, DIMENSION(:), INTENT(IN) :: ppa    ! atmospheric level pressure
REAL, DIMENSION(:), INTENT(IN) :: pps    ! surface pressure
REAL, DIMENSION(:), INTENT(IN) :: prhoa  ! air density
REAL, DIMENSION(:), INTENT(IN) :: pzona  ! zonal wind
REAL, DIMENSION(:), INTENT(IN) :: pmera  ! meridian wind
REAL, DIMENSION(:), INTENT(IN) :: pht    ! atmospheric level height
REAL, DIMENSION(:), INTENT(IN) :: phw    ! atmospheric level height for wind
REAL, DIMENSION(:), INTENT(IN) :: prain  ! Rainfall (kg/m2/s)
REAL, DIMENSION(:), INTENT(IN) :: psnow  ! Snowfall (kg/m2/s)
REAL, DIMENSION(:), INTENT(IN) :: pcd    ! drag coefficient for momentum
REAL, DIMENSION(:), INTENT(IN) :: pcdn   ! neutral drag coefficient
REAL, DIMENSION(:), INTENT(IN) :: pch    ! drag coefficient for heat
REAL, DIMENSION(:), INTENT(IN) :: pri    ! Richardson number
REAL, DIMENSION(:), INTENT(IN) :: phu    ! near-surface humidity
REAL, DIMENSION(:), INTENT(IN) :: pz0h   ! roughness length for heat
REAL, DIMENSION(:), INTENT(IN) :: pqsat  ! humidity at saturation
REAL, DIMENSION(:), INTENT(IN) :: psfzon ! zonal friction
REAL, DIMENSION(:), INTENT(IN) :: psfmer ! meridian friction
REAL, DIMENSION(:), INTENT(IN) :: psfth  ! heat flux  (W/m2)
REAL, DIMENSION(:), INTENT(IN) :: psftq  ! water flux (kg/m2/s)
REAL, DIMENSION(:,:),INTENT(IN):: pdir_sw   ! direct  solar radiation (on horizontal surf.)
!                                           !                                       (W/m2)
REAL, DIMENSION(:,:),INTENT(IN):: psca_sw   ! diffuse solar radiation (on horizontal surf.)
!                                           !                                       (W/m2)
REAL, DIMENSION(:), INTENT(IN) :: plw       ! longwave radiation (on horizontal surf.) (W/m2)
REAL, DIMENSION(:,:),INTENT(IN):: pdir_alb  ! direct albedo for each spectral band  (-)
REAL, DIMENSION(:,:),INTENT(IN):: psca_alb  ! diffuse albedo for each spectral band (-)
REAL, DIMENSION(:), INTENT(IN) :: ple       ! total latent heat flux (W/m2)
REAL, DIMENSION(:), INTENT(IN) :: plei      ! sublimation heat flux (W/m2)
REAL, DIMENSION(:), INTENT(IN) :: psubl     ! sublimation (kg/m2/s)
REAL, DIMENSION(:), INTENT(IN) :: plwup     ! upward longwave radiation (W/m2)
!
REAL, DIMENSION(:), INTENT(IN) :: palb      ! Flake total albedo
REAL, DIMENSION(:), INTENT(IN) :: pswe      ! Flake snow water equivalent (kg.m-2)
!
!*      0.2    declarations of local variables
!
REAL, DIMENSION(SIZE(PTA)) :: zh
REAL(KIND=JPRB) :: zhook_handle
!-------------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('DIAG_INLINE_FLAKE_N',0,zhook_handle)
!
dgf%XDIAG_TS(:) = f%XTS(:)
!
IF (.NOT. f%LSBL) THEN
!
  IF (dgf%N2M==1) THEN
    CALL param_cls(pta, f%XTS, pqa, ppa, prhoa, pzona, pmera, pht, phw, &
                     psfth, psftq, psfzon, psfmer,                       &
                     dgf%XT2M, dgf%XQ2M, dgf%XHU2M, dgf%XZON10M, dgf%XMER10M                       )  
  ELSE IF (dgf%N2M==2) THEN
    zh(:)=2.          
    CALL cls_tq(pta, pqa, ppa, pps, pht,         &
                  pcd, pch, pri,                   &
                  f%XTS, phu, pz0h, zh,              &
                  dgf%XT2M, dgf%XQ2M, dgf%XHU2M                )  
    zh(:)=10.                
    CALL cls_wind(pzona, pmera, phw,             &
                    pcd, pcdn, pri, zh,            &
                    dgf%XZON10M, dgf%XMER10M               )  
  END IF
!
  IF (dgf%N2M>=1) THEN
    !
    dgf%XT2M_MIN(:) = min(dgf%XT2M_MIN(:),dgf%XT2M(:))
    dgf%XT2M_MAX(:) = max(dgf%XT2M_MAX(:),dgf%XT2M(:))
    !
    dgf%XHU2M_MIN(:) = min(dgf%XHU2M_MIN(:),dgf%XHU2M(:))
    dgf%XHU2M_MAX(:) = max(dgf%XHU2M_MAX(:),dgf%XHU2M(:))
    !
    dgf%XWIND10M(:) = sqrt(dgf%XZON10M(:)**2+dgf%XMER10M(:)**2)
    dgf%XWIND10M_MAX(:) = max(dgf%XWIND10M_MAX(:),dgf%XWIND10M(:))
    !
    !* Richardson number
    dgf%XRI = pri
    !
  ENDIF
!
ELSE
  !
  IF (dgf%N2M>=1) THEN
    dgf%XT2M    = xundef
    dgf%XQ2M    = xundef
    dgf%XHU2M   = xundef
    dgf%XZON10M = xundef
    dgf%XMER10M = xundef
    dgf%XRI     = pri
  ENDIF
ENDIF
!
IF (dgf%LSURF_BUDGET.OR.dgf%LSURF_BUDGETC) THEN
  !
  dgf%XLE  (:) = ple(:)
  dgf%XLEI (:) = plei(:)
  dgf%XEVAP(:) = psftq(:)
  dgf%XSUBL(:) = psubl(:)
  dgf%XALBT(:) = palb(:)
  dgf%XSWE (:) = pswe(:)
  !
  CALL  diag_surf_budget_flake( prhoa, psfth,                          &
                                  pdir_sw, psca_sw, plw,                &
                                  pdir_alb, psca_alb, plwup,            &
                                  psfzon, psfmer, dgf%XLE, dgf%XRN, dgf%XH, dgf%XGFLUX, &
                                  dgf%XSWD, dgf%XSWU, dgf%XSWBD, dgf%XSWBU, dgf%XLWD, dgf%XLWU, &
                                  dgf%XFMU, dgf%XFMV )  
  !
END IF
!
IF(dgf%LSURF_BUDGETC)THEN
  CALL diag_surf_budgetc_flake(dgf, &
                               ptstep, dgf%XRN, dgf%XH, dgf%XLE, dgf%XLEI, dgf%XGFLUX,  &
                                 dgf%XSWD, dgf%XSWU, dgf%XLWD, dgf%XLWU, dgf%XFMU, dgf%XFMV,&
                                 dgf%XEVAP, dgf%XSUBL                       )  
ENDIF
!
IF (dgf%LCOEF) THEN
  !
  !* Transfer coefficients
  !
  dgf%XCD = pcd
  dgf%XCH = pch
  dgf%XCE = pch
  !
  !* Roughness lengths
  !
  dgf%XZ0  = f%XZ0
  dgf%XZ0H = pz0h
  !
END IF
!
IF (dgf%LSURF_VARS) THEN
  !
  !* Humidity at saturation
  !
  dgf%XQS = pqsat
  !
END IF
!
! Diag for Earth System Model coupling
!
IF (lcpl_lake) THEN
!
  CALL diag_cpl_esm_flake(f, &
                          ptstep,prain,psnow,psftq)
! 
ENDIF
!
IF (lhook) CALL dr_hook('DIAG_INLINE_FLAKE_N',1,zhook_handle)
!-------------------------------------------------------------------------------------
!
END SUBROUTINE diag_inline_flake_n