diag_cpl_esm_sea.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
       SUBROUTINE diag_cpl_esm_sea (S, &
                                     ptstep,pzon10m,pmer10m,psfu,psfv,     &
                                      pswd,pswu,pgflux,psftq,prain,psnow, &
                                      plw,ptice,psfth_ice,psftq_ice,      &
                                      pdir_sw,psca_sw,pswu_ice,plwu_ice,  &
                                      osic                                )  
!     ###################################################################
!
!!****  *DIAG_CPL_ESM_SEA * - Computes diagnostics over sea for 
!!                Earth system model coupling or embedded seaice scheme
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     B. Decharme 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    08/2009
!!      S.Senesi    01/2014  Adapt to embedded seaice scheme (SWU and LWU 
!!                           for seaice are provided as inputs)
!!      A.Voldoire  04/2015  Add LCPL_SEAICE test
!!------------------------------------------------------------------
!
!
USE modd_seaflux_n, ONLY : seaflux_t
!
USE modd_csts,      ONLY : xstefan, xlstt
USE modd_water_par, ONLY : xemiswatice
!
USE modd_sfx_oasis, ONLY : lcpl_seaice
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
TYPE(seaflux_t), INTENT(INOUT) :: s
!
REAL,               INTENT(IN) :: ptstep    ! atmospheric time-step
REAL, DIMENSION(:), INTENT(IN) :: pzon10m   ! zonal wind
REAL, DIMENSION(:), INTENT(IN) :: pmer10m   ! meridian wind
REAL, DIMENSION(:), INTENT(IN) :: psfu      ! zonal wind stress
REAL, DIMENSION(:), INTENT(IN) :: psfv      ! meridian wind stress
REAL, DIMENSION(:), INTENT(IN) :: pswd      ! total incoming short wave radiation
REAL, DIMENSION(:), INTENT(IN) :: pswu      ! total upward short wave radiation
REAL, DIMENSION(:), INTENT(IN) :: pgflux    ! storage flux
REAL, DIMENSION(:), INTENT(IN) :: psftq     ! water flux
REAL, DIMENSION(:), INTENT(IN) :: prain     ! Rainfall
REAL, DIMENSION(:), INTENT(IN) :: psnow     ! Snowfall
REAL, DIMENSION(:), INTENT(IN) :: plw       ! longwave radiation (on horizontal surf.)
REAL, DIMENSION(:), INTENT(IN) :: psfth_ice ! heat flux  (W/m2)
REAL, DIMENSION(:), INTENT(IN) :: psftq_ice ! water flux (kg/m2/s)
REAL, DIMENSION(:), INTENT(IN) :: ptice     ! Ice Surface Temperature
REAL, DIMENSION(:,:),INTENT(IN):: pdir_sw   ! direct  solar radiation (on horizontal surf.)
REAL, DIMENSION(:,:),INTENT(IN):: psca_sw   ! diffuse solar radiation (on horizontal surf.)
REAL, DIMENSION(:), INTENT(IN) :: pswu_ice  ! upward short wave radiation on seaice
REAL, DIMENSION(:), INTENT(IN) :: plwu_ice  ! upward long  wave radiation on seaice
LOGICAL,            INTENT(IN) :: osic
!
!*      0.2    declarations of local variables
!
REAL, DIMENSION(SIZE(S%XICE_ALB)) :: zswu, ztice4
!
INTEGER                      :: iswb ! number of SW bands
INTEGER                      :: jswb ! loop counter on number of SW bands
INTEGER                      :: ini  ! number of points
INTEGER                      :: ji   ! loop counter on number of points
!
REAL(KIND=JPRB) :: zhook_handle
!
IF (lhook) CALL dr_hook('DIAG_CPL_ESM_SEA',0,zhook_handle)
!
!-------------------------------------------------------------------------------------
! Total or free-ice sea flux
!-------------------------------------------------------------------------------------
!
!* 10m wind speed (m)
!
s%XCPL_SEA_WIND(:) = s%XCPL_SEA_WIND(:) + ptstep * sqrt(pzon10m(:)**2+pmer10m(:)**2)
! 
!* wind stress (Pa.s)
!
s%XCPL_SEA_FWSU(:) = s%XCPL_SEA_FWSU(:) + ptstep * psfu(:)
s%XCPL_SEA_FWSV(:) = s%XCPL_SEA_FWSV(:) + ptstep * psfv(:)
s%XCPL_SEA_FWSM(:) = s%XCPL_SEA_FWSM(:) + ptstep * sqrt(psfu(:)**2+psfv(:)**2)
!
!* Solar net heat flux (J/m2)
!
s%XCPL_SEA_SNET(:) = s%XCPL_SEA_SNET(:) + ptstep * (pswd(:) - pswu(:))
!
!* Non solar heat flux (J/m2)
!
s%XCPL_SEA_HEAT(:) = s%XCPL_SEA_HEAT(:) + ptstep * (pgflux(:) + pswu(:) - pswd(:)) 
!
!* Evaporation (kg/m2)
!
s%XCPL_SEA_EVAP(:) = s%XCPL_SEA_EVAP(:) + ptstep * psftq(:)
!
!* Precip (kg/m2)
! 
s%XCPL_SEA_RAIN(:) = s%XCPL_SEA_RAIN(:) + ptstep * prain(:)
s%XCPL_SEA_SNOW(:) = s%XCPL_SEA_SNOW(:) + ptstep * psnow(:)
!
!-------------------------------------------------------------------------------------
! Ice flux
!-------------------------------------------------------------------------------------
IF (lcpl_seaice.OR.osic) THEN
!
  ini  = SIZE(pdir_sw,1)
  iswb = SIZE(pdir_sw,2)
!
!* Solar net heat flux (J/m2)
!
  IF (osic) THEN
    zswu(:)=pswu_ice(:)
  ELSE
    zswu(:)=0.0
    DO jswb=1,iswb
      DO ji=1,ini
         zswu(ji) = zswu(ji) + (pdir_sw(ji,jswb)+psca_sw(ji,jswb)) * s%XICE_ALB(ji)
      ENDDO
    ENDDO
  ENDIF
!
  s%XCPL_SEAICE_SNET(:) = s%XCPL_SEAICE_SNET(:) + ptstep * (pswd(:) - zswu(:))
!
!* Non solar heat flux (J/m2)
!
  IF (osic) THEN
    s%XCPL_SEAICE_HEAT(:) = s%XCPL_SEAICE_HEAT(:) + ptstep * &
              ( plw(:) - plwu_ice(:) - psfth_ice(:) - xlstt*psftq_ice(:) )
  ELSE
    ztice4(:)=ptice(:)**4
    s%XCPL_SEAICE_HEAT(:) = s%XCPL_SEAICE_HEAT(:) + ptstep * ( xemiswatice*(plw(:)-xstefan*ztice4(:)) &
                                                         - psfth_ice(:) - xlstt*psftq_ice(:)      ) 
  ENDIF 
!
!* Sublimation (kg/m2)
!
  s%XCPL_SEAICE_EVAP(:) = s%XCPL_SEAICE_EVAP(:) + ptstep * psftq_ice(:)
!
ENDIF
!
IF (lhook) CALL dr_hook('DIAG_CPL_ESM_SEA',1,zhook_handle)
!
!-------------------------------------------------------------------------------------
!
END SUBROUTINE diag_cpl_esm_sea