coupling_seaflux_orogn.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     ###############################################################################
SUBROUTINE coupling_seaflux_orog_n (SM, DST, SLT, &
                                    hprogram, hcoupling, ptimec,                              &
                 ptstep, kyear, kmonth, kday, ptime, ki, ksv, ksw, ptsun, pzenith, pzenith2, &
                 pazim, pzref, puref, pzs, pu, pv, pqa, pta, prhoa, psv, pco2, hsv,          &
                 prain, psnow, plw, pdir_sw, psca_sw, psw_bands, pps, ppa,                   &
                 psftq, psfth, psfts, psfco2, psfu, psfv,                                    &
                 ptrad, pdir_alb, psca_alb, pemis, ptsurf, pz0, pz0h, pqsurf,                &
                 ppew_a_coef, ppew_b_coef,                                                   &
                 ppet_a_coef, ppeq_a_coef, ppet_b_coef, ppeq_b_coef,                         &
                 htest                                                                       )  
!     ###############################################################################
!
!!****  *COUPLING_SEAFLUX_OROG_n * - Modifies the input forcing if not
!!           initially at sea level
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     V. Masson 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004
!!      B. Decharme   2008   reset the subgrid topographic effect on the forcing
!!      J. Escobar    09/2012 SIZE(PTA) not allowed without-interface , replace by KI
!!      B. Decharme  04/2013 new coupling variables
!!                           improve forcing vertical shift
!!-------------------------------------------------------------
!
!
USE modd_surfex_n, ONLY : seaflux_model_t
!
USE modd_dst_n, ONLY : dst_t
USE modd_slt_n, ONLY : slt_t
!
!
USE modd_surf_par,         ONLY : xundef
USE modd_csts,             ONLY : xcpd, xrd, xp00
!
USE modd_surf_atm, ONLY : lvertshift
!
USE modi_forcing_vert_shift
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_coupling_seawat_sbl_n
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
TYPE(seaflux_model_t), INTENT(INOUT) :: sm
TYPE(dst_t), INTENT(INOUT) :: dst
TYPE(slt_t), INTENT(INOUT) :: slt
!
 CHARACTER(LEN=6),    INTENT(IN)  :: hprogram  ! program calling surf. schemes
 CHARACTER(LEN=1),    INTENT(IN)  :: hcoupling ! type of coupling
                                              ! 'E' : explicit
                                              ! 'I' : implicit
REAL,                INTENT(IN)  :: ptimec    ! current duration since start of the run (s)
INTEGER,             INTENT(IN)  :: kyear     ! current year (UTC)
INTEGER,             INTENT(IN)  :: kmonth    ! current month (UTC)
INTEGER,             INTENT(IN)  :: kday      ! current day (UTC)
REAL,                INTENT(IN)  :: ptime     ! current time since midnight (UTC, s)
INTEGER,             INTENT(IN)  :: ki        ! number of points
INTEGER,             INTENT(IN)  :: ksv       ! number of scalars
INTEGER,             INTENT(IN)  :: ksw       ! number of short-wave spectral bands
REAL, DIMENSION(KI), INTENT(IN)  :: ptsun     ! solar time                    (s from midnight)
REAL,                INTENT(IN)  :: ptstep    ! atmospheric time-step                 (s)
REAL, DIMENSION(KI), INTENT(IN)  :: pzref     ! height of T,q forcing                 (m)
REAL, DIMENSION(KI), INTENT(IN)  :: puref     ! height of wind forcing                (m)
!
REAL, DIMENSION(KI), INTENT(IN)  :: pta       ! air temperature forcing               (K)
REAL, DIMENSION(KI), INTENT(IN)  :: pqa       ! air humidity forcing                  (kg/m3)
REAL, DIMENSION(KI), INTENT(IN)  :: prhoa     ! air density                           (kg/m3)
REAL, DIMENSION(KI,KSV),INTENT(IN) :: psv     ! scalar variables
!                                             ! chemistry:   first char. in HSV: '#'  (molecule/m3)
!                                             !
 CHARACTER(LEN=6), DIMENSION(KSV),INTENT(IN):: hsv  ! name of all scalar variables
REAL, DIMENSION(KI), INTENT(IN)  :: pu        ! zonal wind                            (m/s)
REAL, DIMENSION(KI), INTENT(IN)  :: pv        ! meridian wind                         (m/s)
REAL, DIMENSION(KI,KSW),INTENT(IN) :: pdir_sw ! direct  solar radiation (on horizontal surf.)
!                                             !                                       (W/m2)
REAL, DIMENSION(KI,KSW),INTENT(IN) :: psca_sw ! diffuse solar radiation (on horizontal surf.)
!                                             !                                       (W/m2)
REAL, DIMENSION(KSW),INTENT(IN)  :: psw_bands ! mean wavelength of each shortwave band (m)
REAL, DIMENSION(KI), INTENT(IN)  :: pzenith   ! zenithal angle at t  (radian from the vertical)
REAL, DIMENSION(KI), INTENT(IN)  :: pzenith2  ! zenithal angle at t+1(radian from the vertical)
REAL, DIMENSION(KI), INTENT(IN)  :: pazim     ! azimuthal angle      (radian from North, clockwise)
REAL, DIMENSION(KI), INTENT(IN)  :: plw       ! longwave radiation (on horizontal surf.)
!                                             !                                       (W/m2)
REAL, DIMENSION(KI), INTENT(IN)  :: pps       ! pressure at atmospheric model surface (Pa)
REAL, DIMENSION(KI), INTENT(IN)  :: ppa       ! pressure at forcing level             (Pa)
REAL, DIMENSION(KI), INTENT(IN)  :: pzs       ! atmospheric model orography           (m)
REAL, DIMENSION(KI), INTENT(IN)  :: pco2      ! CO2 concentration in the air          (kg/m3)
REAL, DIMENSION(KI), INTENT(IN)  :: psnow     ! snow precipitation                    (kg/m2/s)
REAL, DIMENSION(KI), INTENT(IN)  :: prain     ! liquid precipitation                  (kg/m2/s)
!
!
REAL, DIMENSION(KI), INTENT(OUT) :: psfth     ! flux of heat                          (W/m2)
REAL, DIMENSION(KI), INTENT(OUT) :: psftq     ! flux of water vapor                   (kg/m2/s)
REAL, DIMENSION(KI), INTENT(OUT) :: psfu      ! zonal momentum flux                   (Pa)
REAL, DIMENSION(KI), INTENT(OUT) :: psfv      ! meridian momentum flux                (Pa)
REAL, DIMENSION(KI), INTENT(OUT) :: psfco2    ! flux of CO2                           (m/s*kg_CO2/kg_air)
REAL, DIMENSION(KI,KSV),INTENT(OUT):: psfts   ! flux of scalar var.                   (kg/m2/s)
!
REAL, DIMENSION(KI), INTENT(OUT) :: ptrad     ! radiative temperature                 (K)
REAL, DIMENSION(KI,KSW),INTENT(OUT):: pdir_alb! direct albedo for each spectral band  (-)
REAL, DIMENSION(KI,KSW),INTENT(OUT):: psca_alb! diffuse albedo for each spectral band (-)
REAL, DIMENSION(KI), INTENT(OUT) :: pemis     ! emissivity                            (-)
!
REAL, DIMENSION(KI), INTENT(OUT) :: ptsurf    ! surface effective temperature         (K)
REAL, DIMENSION(KI), INTENT(OUT) :: pz0       ! roughness length for momentum         (m)
REAL, DIMENSION(KI), INTENT(OUT) :: pz0h      ! roughness length for heat             (m)
REAL, DIMENSION(KI), INTENT(OUT) :: pqsurf    ! specific humidity at surface          (kg/kg)
!
REAL, DIMENSION(KI), INTENT(IN) :: ppew_a_coef! implicit coefficients
REAL, DIMENSION(KI), INTENT(IN) :: ppew_b_coef! needed if HCOUPLING='I'
REAL, DIMENSION(KI), INTENT(IN) :: ppet_a_coef
REAL, DIMENSION(KI), INTENT(IN) :: ppeq_a_coef
REAL, DIMENSION(KI), INTENT(IN) :: ppet_b_coef
REAL, DIMENSION(KI), INTENT(IN) :: ppeq_b_coef
 CHARACTER(LEN=2),    INTENT(IN) :: htest ! must be equal to 'OK'
!
!*      0.2    declarations of local variables
!
REAL, DIMENSION(KI)  ::  zpeq_b_coef   ! 1st explicit coefficient
REAL, DIMENSION(KI)  ::  zpet_b_coef   ! 2nd explicit coefficient
!
REAL, DIMENSION(KI)  :: zta    ! Temperature at forcing height above surface orography
REAL, DIMENSION(KI)  :: zpa    ! Pressure    at forcing height above surface orography
REAL, DIMENSION(KI)  :: zps    ! Pressure    at surface orography
REAL, DIMENSION(KI)  :: zqa    ! Humidity    at forcing height above surface orography
REAL, DIMENSION(KI)  :: zrhoa  ! Density     at forcing height above surface orography
REAL, DIMENSION(KI)  :: zlw    ! LW rad      at forcing height above surface orography
REAL, DIMENSION(KI)  :: zrain  ! Rainfall    at forcing height above surface orography
REAL, DIMENSION(KI)  :: zsnow  ! Snowfall    at forcing height above surface orography
!
REAL(KIND=JPRB) :: zhook_handle
!-------------------------------------------------------------------------------------
! Preliminaries:
!-------------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('COUPLING_SEAFLUX_OROG_N',0,zhook_handle)
!
zpeq_b_coef(:) = ppeq_b_coef(:)
zpet_b_coef(:) = ppet_b_coef(:)
!
IF(lvertshift)THEN
!
  zta(:) = xundef
  zqa(:) = xundef
  zps(:) = xundef
  zpa(:) = xundef
  zrhoa(:) = xundef
  zlw(:) = xundef
  zrain(:) = xundef
  zsnow(:) = xundef
!     
   CALL forcing_vert_shift(pzs,sm%S%XZS,pta,pqa,ppa,prhoa,plw,prain,psnow,&
                           zta,zqa,zpa,zrhoa,zlw,zrain,zsnow         )
!
   zps(:) = zpa(:) + (pps(:) - ppa(:))
!
  IF (hcoupling=='I') THEN
    zpeq_b_coef = ppeq_b_coef + zqa - pqa
    zpet_b_coef = ppet_b_coef + zta/(zpa/xp00)**(xrd/xcpd) - pta/(ppa/xp00)**(xrd/xcpd)
  ENDIF
!
ELSE
!
  zta(:) = pta(:)
  zqa(:) = pqa(:)
  zps(:) = pps(:)
  zpa(:) = ppa(:)
  zrhoa(:) = prhoa(:)
  zlw(:) = plw(:)
  zrain(:) = prain(:)
  zsnow(:) = psnow(:)
!
ENDIF
!
 CALL coupling_seaflux_sbl_n(sm, dst, slt, &
                             hprogram, hcoupling, ptimec, ptstep,                   &
                             kyear, kmonth, kday, ptime, ki, ksv, ksw,              &
                             ptsun, pzenith, pzenith2, pazim, pzref, puref, pu, pv, &
                             zqa, zta, zrhoa, psv, pco2, hsv, zrain, zsnow, zlw,    &
                             pdir_sw, psca_sw, psw_bands, zps, zpa, psftq, psfth,   &
                             psfts, psfco2, psfu, psfv, ptrad, pdir_alb, psca_alb,  &
                             pemis, ptsurf, pz0, pz0h, pqsurf, ppew_a_coef,         &
                             ppew_b_coef, ppet_a_coef, ppeq_a_coef, zpet_b_coef,    &
                             zpeq_b_coef, htest                                     )
!
IF (lhook) CALL dr_hook('COUPLING_SEAFLUX_OROG_N',1,zhook_handle)
!-------------------------------------------------------------------------------------
!
END SUBROUTINE coupling_seaflux_orog_n