control_moist_func.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!   #############
FUNCTION control_moist_func (PMOIST,PSAT) RESULT (PMOISTFUNC)

!   ###############################################################
!!**   CONTROL_MOIST_FUNC
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!     Moisture control factor for decomposition.
!!
!!    EXTERNAL
!!    --------
!!    none
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!      
!!    none
!!
!!    REFERENCE
!!    ---------
!!
!!      Krinner et al., Global Biochemical Cycles, 2005
!!      Modified for Wfc < W < Wsat following Probert et al., Agricultural Systems, 1998
!!      Gibelin et al. 2008, AFM
!!      
!!    AUTHOR
!!    ------
!!
!!      A.-L. Gibelin           * Meteo-France *
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    23/06/09
!!      B. Decharme 05/2012 : Optimization and ISBA-DIF coupling
!!      
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
REAL, DIMENSION(:), INTENT(IN)   :: pmoist ! soil moisture index (-)
REAL, DIMENSION(:), INTENT(IN)   :: psat   ! soil saturated index (-)
!
!*      0.2    declarations of local variables
!
REAL, PARAMETER               :: zmoist_lim = 0.05
REAL, PARAMETER               :: zsat_lim   = 0.5
!
REAL, PARAMETER               :: zcoef1 = 2.40
REAL, PARAMETER               :: zcoef2 = 1.10
REAL, PARAMETER               :: zcoef3 = 0.29
!
REAL, DIMENSION(SIZE(PMOIST)) :: pmoistfunc    ! moisture control factor
!
REAL(KIND=JPRB) :: zhook_handle
!
!*      1.0    Calculates moisture control factor
!
IF (lhook) CALL dr_hook('CONTROL_MOIST_FUNC',0,zhook_handle)
!
WHERE(pmoist(:)<=1.0)
      pmoistfunc(:)=min(1.0,zcoef1*pmoist(:)-zcoef2*pmoist(:)*pmoist(:)-zcoef3)
      pmoistfunc(:)=max(zmoist_lim,pmoistfunc(:))
ELSEWHERE
      pmoistfunc(:)=max(zsat_lim,1.0-0.5*psat(:))
ENDWHERE
!
IF (lhook) CALL dr_hook('CONTROL_MOIST_FUNC',1,zhook_handle)

END FUNCTION control_moist_func