ch_init_names.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE ch_init_names (KLUOUT,HSV,KBEQ,KBAER,HSVO,&
                            ksv_chsbeg,ksv_chsend, ksv_aerbeg, ksv_aerend,&
                            ovarsigi, ovarsigj)  
!!    ###########################################
!!
!!*** *CH_INIT_NAMES*
!!
!!    PURPOSE
!!    -------
!!      Read and filter all chemical species into the CSV array
!!     initialize NSV_CHSBEG and  NSV_CHSEND index for the begin and the ending chemical index
!!     
!!
!!    REFERENCE
!!    ---------
!!    
!!    AUTHOR
!!    ------
!!    P. Tulet    *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!    Original 16/10/01
!!    01/12/03    (D.Gazen) change emissions handling for surf. externalization
!!    01/06/05    (P.Tulet) add aerosols list
!!
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
USE modd_chs_aerosol
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!

INTEGER,                         INTENT(IN)  :: kluout ! output listing channel
 CHARACTER(LEN=*), DIMENSION(:),  INTENT(IN)  :: hsv    ! name of chemical species
                                                       ! with character # (gas chemistry )
                                                       ! and  character @ (aerosols)
INTEGER,                         INTENT(OUT) :: kbeq     ! number of chemical variables
INTEGER,                         INTENT(OUT) :: kbaer    ! number of aerosol variables
 CHARACTER(LEN=*), DIMENSION(SIZE(HSV)),  INTENT(OUT) :: hsvo ! name of scalar species without # and @
INTEGER,                         INTENT(OUT) :: ksv_chsbeg  ! first chemical var.
INTEGER,                         INTENT(OUT) :: ksv_chsend  ! last  chemical var.
INTEGER,                         INTENT(OUT) :: ksv_aerbeg  ! first aerosol var.
INTEGER,                         INTENT(OUT) :: ksv_aerend  ! last  aerosol var.
LOGICAL,                         INTENT(OUT) :: ovarsigi, ovarsigj ! type of standard deviation
!
!*      0.2    declarations of local variables
INTEGER :: jsv  !! loop  NBEQ
 CHARACTER        :: yrc1
 CHARACTER(LEN=5) :: yrc2
REAL(KIND=JPRB) :: zhook_handle
!
!-------------------------------------------------------------------------------

IF (lhook) CALL dr_hook('CH_INIT_NAMES',0,zhook_handle)
kbeq = 0
kbaer = 0
ksv_chsbeg = 0
ksv_aerbeg = 0
ksv_chsend = 0
ksv_aerend = 0
ovarsigi = .false.
ovarsigj = .false.
nsoa = 0


DO jsv=1, SIZE(hsv)

  hsvo(jsv) = hsv(jsv)
  yrc1= hsv(jsv)(1:1)
  yrc2 = hsv(jsv)(2:)

  IF (yrc1 == '#') THEN
    hsvo(jsv) = trim(yrc2)
    kbeq = kbeq + 1
    IF (kbeq == 1) ksv_chsbeg=jsv
  ELSE IF (yrc1 == '@') THEN
    hsvo(jsv) = trim(yrc2)
    kbaer = kbaer + 1
    IF (kbaer == 1) ksv_aerbeg=jsv
    IF (hsvo(jsv) == "M6I") ovarsigi = .true.
    IF (hsvo(jsv) == "M6J") ovarsigj = .true.
    IF (hsvo(jsv) == "SOA1I") nsoa = 10
  ENDIF

ENDDO

ksv_chsend = ksv_chsbeg + kbeq -1
ksv_aerend = ksv_aerbeg + kbaer -1

IF (kbaer .GT. 0) THEN
DO jsv=1, size(hsvo)
   IF (trim(hsvo(jsv)) == "M0I") jp_ch_m0i=jsv-ksv_chsend
   IF (trim(hsvo(jsv)) == "M0J") jp_ch_m0j=jsv-ksv_chsend
   IF (trim(hsvo(jsv)) == "M6I") jp_ch_m6i=jsv-ksv_chsend
   IF (trim(hsvo(jsv)) == "M6J") jp_ch_m6j=jsv-ksv_chsend
   IF (trim(hsvo(jsv)) == "H2OI") jp_ch_h2oi=jsv-ksv_chsend
   IF (trim(hsvo(jsv)) == "H2OJ") jp_ch_h2oj=jsv-ksv_chsend
   IF (trim(hsvo(jsv)) == "SO4I") jp_ch_so4i=jsv-ksv_chsend
   IF (trim(hsvo(jsv)) == "SO4J") jp_ch_so4j=jsv-ksv_chsend
   IF (trim(hsvo(jsv)) == "NO3I") jp_ch_no3i=jsv-ksv_chsend
   IF (trim(hsvo(jsv)) == "NO3J") jp_ch_no3j=jsv-ksv_chsend
   IF (trim(hsvo(jsv)) == "NH3I") jp_ch_nh3i=jsv-ksv_chsend
   IF (trim(hsvo(jsv)) == "NH3J") jp_ch_nh3j=jsv-ksv_chsend
   IF (trim(hsvo(jsv)) == "OCI") jp_ch_oci=jsv-ksv_chsend
   IF (trim(hsvo(jsv)) == "OCJ") jp_ch_ocj=jsv-ksv_chsend
   IF (trim(hsvo(jsv)) == "BCI") jp_ch_bci=jsv-ksv_chsend
   IF (trim(hsvo(jsv)) == "BCJ") jp_ch_bcj=jsv-ksv_chsend
   IF (trim(hsvo(jsv)) == "DSTI") jp_ch_dsti=jsv-ksv_chsend
   IF (trim(hsvo(jsv)) == "DSTJ") jp_ch_dstj=jsv-ksv_chsend
END DO

END IF
IF (lhook) CALL dr_hook('CH_INIT_NAMES',1,zhook_handle)

!
END SUBROUTINE ch_init_names