ch_dep_water.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
     SUBROUTINE ch_dep_water  (PRESA,PUSTAR,PTA,PTRAD,PSV, HSV, PDEP)
  !###########################################################
  !
  !!                   
  !!                       
  !!
  !!    PURPOSE
  !!    -------
  !!      
  !!    Compute dry deposition velocity for chemical species    
  !!
  !!    AUTHOR
  !!    ------
  !!      P.Tulet      * Laboratoire d'Aerologie*
  !!
  !!    MODIFICATIONS
  !!    -------------
  !!      Original      20/02/97 
  !!    Modification  18/07/03  (Tulet) surface externalization
  !!
  !-------------------------------------------------------------------------------
  !
  !*       0.    DECLARATIONS
  !              ------------
  !
  USE modd_csts
  USE modd_ch_surf
  !
!
  USE yomhook   ,ONLY : lhook,   dr_hook
  USE parkind1  ,ONLY : jprb
!
  IMPLICIT NONE
  !
  !*       0.1   Declarations of dummy arguments :
  !
       REAL, DIMENSION(:),     INTENT(IN)  :: presa        ! aerodynamic resistances
       REAL, DIMENSION(:),     INTENT(IN)  :: pustar       ! frition velocities
       REAL, DIMENSION(:),     INTENT(IN)  :: pta          ! air temperature forcing (K)
       REAL, DIMENSION(:),     INTENT(IN)  :: ptrad        ! radiative temperature   (K)
       REAL, DIMENSION(:,:),   INTENT(IN)  :: psv
       CHARACTER(LEN=6), DIMENSION(:),INTENT(IN) :: hsv
       REAL, DIMENSION(:,:),   INTENT(INOUT):: pdep      ! deposition dry velocity (m/s)
  !
  !
  !
  !*       0.2   Declarations of local variables :
  !
  !
  REAL             , DIMENSION(SIZE(PTRAD,1),SIZE(HSV,1)) :: zscmdt 
  ! Schmidt number
  REAL             , DIMENSION(SIZE(PTRAD,1),SIZE(HSV,1)) :: zdiffmolval
  ! Molecular diffusivity
  REAL             , DIMENSION(SIZE(PTRAD,1),SIZE(HSV,1)) :: zwatrb  
  ! water quasi-laminar  resistance
  REAL             , DIMENSION(SIZE(PTRAD,1),SIZE(HSV,1)) :: zwatrc 
  ! water surface  resistance
  REAL             , DIMENSION(SIZE(PTRAD,1),SIZE(HSV,1)) :: zreswat  
  !  final water resistance
  REAL, DIMENSION(SIZE(PTRAD,1))      :: ztcor
  REAL,DIMENSION(SIZE(PUSTAR,1))      ::zustar
  INTEGER :: jsv
  REAL(KIND=JPRB) :: zhook_handle
  !
  !============================================================================
  !            Primilary
  !            ---------


  !Default values
  !--------------
  IF (lhook) CALL dr_hook('CH_DEP_WATER',0,zhook_handle)
  zwatrc(:,:) = 9999.
  zreswat(:,:)= 9999.0
  zwatrb(:,:) = 9999.
  zustar(:) = max(pustar(:), 1e-9)
  !
  !
  !       2.0  Quasi-laminar resistance (for WATER) (Hicks, 1987)
  !            ------------------------      
  !
  !  
  !         compute molecular diffusivity for each species (Langevin, 1905)
  !         ----------------------------------------------
  DO jsv=1,SIZE(hsv,1)
    zdiffmolval(:,jsv) = 2.22e-05 + 1.46e-07 * (ptrad(:) - 273.0) * &
                                 sqrt(18. / xsrealmassmolval(jsv))  
    zscmdt(:,jsv)=0.15e-4 / zdiffmolval(:,jsv)
  ENDDO
  !
  !
  !         For water
  !         ---------
  DO jsv=1,SIZE(hsv,1)
    zwatrb(:,jsv) =  ((zscmdt(:,jsv)/0.72)**(2./3.)) &
                                     / (xkarman*zustar(:))  
  ENDDO
  !
  !
  !       3.  Surface resistance
  !            ------------------
  ! 
  !       3.1  Surface  resistance on water
  !            ----------------------------
  !
  !         3.1.1  Compute surface  resistance on inland water
  !                --------------------------------------------
  !  
  DO jsv=1,SIZE(hsv,1)
    zwatrc(:,jsv) = 2.54e4 / ( xsrealhenryval(jsv,1) *&
                       exp(xsrealhenryval(jsv,2)* (1./298. - 1./pta(:))) *&
                       ptrad(:) * zustar(:))  
  ENDDO
  ! 
  !          3.1.2 Surface temperature correction 
  !                ------------------------------
  ztcor(:) = 0.
  WHERE( ptrad(:) < 271. )
    ztcor(:) = 1000. * exp(-ptrad(:) + 269.)
    ztcor(:) = min(2.5e3, ztcor(:))
  END WHERE
  DO jsv=1,SIZE(hsv,1)
    zwatrc(:,jsv) = zwatrc(:,jsv)+ztcor(:)   
  ENDDO
  !
  !
  !       5.0  Compute  water resistance (in land water and sea)
  !            -------------------------------------------------
  !
  DO jsv=1,SIZE(hsv,1) 
    zreswat(:,jsv)  = presa(:) + zwatrb(:,jsv) + zwatrc(:,jsv)
  ENDDO
  !
  !        7.0  Compute dry deposition velocity for inland water 
  !             ------------------------------------------------
  !
  pdep(:,:) = 1. / zreswat(:,:)
IF (lhook) CALL dr_hook('CH_DEP_WATER',1,zhook_handle)
  !
END SUBROUTINE ch_dep_water