ch_dep_town.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
     SUBROUTINE ch_dep_town ( PRESA_TOWN,  PUSTAR_TOWN,PTA, PTRAD, PWALL_O_HOR, &
                                psv, hsv,  pdep)  
  !###########################################################
  !
  !!                   
  !!                       
  !!
  !!    PURPOSE
  !!    -------
  !!      
  !!    Compute dry deposition velocity for chemical species    
  !!
  !!    AUTHOR
  !!    ------
  !!      P.Tulet      * Laboratoire d'Aerologie*
  !!
  !!    MODIFICATIONS
  !!    -------------
  !!      Original      20/02/97 
  !!      Modification  21/07/00  (Guenais/Tulet) add deposition on town
  !!      Modification  18/07/03  (Tulet) surface externalization
  !!
  !-------------------------------------------------------------------------------
  !
  !*       0.    DECLARATIONS
  !              ------------
  !
  USE modd_ch_surf
  USE modd_csts
  !
!
  USE yomhook   ,ONLY : lhook,   dr_hook
  USE parkind1  ,ONLY : jprb
!
  IMPLICIT NONE
  !
  !*       0.1   Declarations of dummy arguments :
  !
       REAL, DIMENSION(:),     INTENT(IN)  :: presa_town   ! aerodynamic resistances
       REAL, DIMENSION(:),     INTENT(IN)  :: pustar_town  ! frition velocities
       REAL, DIMENSION(:),     INTENT(IN)  :: pta          ! air temperature forcing (K)
       REAL, DIMENSION(:),     INTENT(IN)  :: ptrad        ! radiative temperature  (K)
       REAL, DIMENSION(:),     INTENT(IN)  :: pwall_o_hor  ! normalized wall surface
       REAL, DIMENSION(:,:),   INTENT(OUT)    :: pdep      ! deposition dry velocity (m/s)
       REAL, DIMENSION(:,:),   INTENT(IN)     :: psv
       CHARACTER(LEN=6), DIMENSION(:),INTENT(IN) :: hsv
       !
  !
  !
  !*       0.2   Declarations of local variables :
  !
  !
  REAL    :: zstownrc_so2
  ! donnees pour Rcsoil au SO2 Wesely (89)
  ! Hemisphere nord latitudes temperees
  REAL    :: zstownrc_o3
  ! donnees pour Rcsoil au O3 Wesely (89)
  ! Hemisphere nord latitudes temperees
  REAL             , DIMENSION(SIZE(PTRAD,1),SIZE(HSV,1)) :: zscmdt 
  ! Sc(:)hmidt number
  REAL             , DIMENSION(SIZE(PTRAD,1),SIZE(HSV,1)) :: zdiffmolval
  ! Molecular diffusivity
  REAL             , DIMENSION(SIZE(PTRAD,1),SIZE(HSV,1)) :: ztownrb 
  ! snow quasi-laminar  resistance
  REAL             , DIMENSION(SIZE(PTRAD,1),SIZE(HSV,1)) :: ztownrc 
  ! towm surface  resistance

  REAL             , DIMENSION(SIZE(PTRAD,1),SIZE(HSV,1)) :: zrestown 
  !  final town  resistance
  REAL, DIMENSION(SIZE(PTRAD,1))      :: ztown_max
  REAL, DIMENSION(SIZE(PTRAD,1))      :: ztcor
  REAL,DIMENSION(SIZE(PUSTAR_TOWN,1))      ::zustar_town
  INTEGER :: jsv
  REAL(KIND=JPRB) :: zhook_handle
  !
  !============================================================================
  !            Primilary
  !            ---------

  !Default values
  !--------------
  IF (lhook) CALL dr_hook('CH_DEP_TOWN',0,zhook_handle)
  ztownrc(:,:) = 9999.
  zrestown(:,:)= 9999.0
  ztownrb(:,:) = 9999.
  !
  ! INDEX OF VEGTYPE
  ! ****************
  zstownrc_so2 = 400.  ! Town
  zstownrc_o3  = 300.   ! Town

  zustar_town(:) = max(pustar_town(:), 1e-9)
  !
  !        1.0  Aerodynamic resistance for the differents COVER TYPE
  !             ----------------------------------------------------
  !   PRESA_TOWN(:)     ! Aerodynamic resistance for TOWN 
  !
  !       2.0  Quasi-laminar resistance (Hicks, 1987)
  !            ------------------------      
  !
       !  
        !         compute molecular diffusivity for each species (Langevin, 1905)
        !         ----------------------------------------------
        DO jsv=1,SIZE(hsv,1)
        zdiffmolval(:,jsv) = 2.22e-05 + 1.46e-07 * (ptrad(:) - 273.0) * &
                                     sqrt(18. / xsrealmassmolval(jsv))  
        zscmdt(:,jsv)=0.15e-4 / zdiffmolval(:,jsv)
        ENDDO
        !
        !
        !         For town
        !         --------
        DO jsv=1,SIZE(hsv,1)
           ztownrb(:,jsv) =  ((zscmdt(:,jsv)/0.72)**(2./3.)) &
                                          / (xkarman*zustar_town(:))  
        ENDDO
  !
  !       3.  Surface resistance
  !            ------------------
  !          3.3.4 Surface temperature correction
  !                ------------------------------
           ztcor(:) = 0.
           WHERE(ptrad(:) < 271.)
              ztcor(:) = 1000 * exp(-ptrad(:) + 269.)
              ztcor(:) = min(2.5e3, ztcor(:))
           END WHERE

           
           DO jsv=1,SIZE(hsv,1)
           ztownrc(:,jsv) = ztcor(:) + (1.e5*zstownrc_so2)/ (xsrealhenryval(jsv,1) * &
                              exp(xsrealhenryval(jsv,2)* (1./298. - 1./pta(:))))   
           ENDDO

  ! 
        !        6.0  Compute town resistance
        !             -----------------------
        !
        DO jsv=1,SIZE(hsv,1) 
           zrestown(:,jsv) = presa_town(:) + &
                  ztownrb(:,jsv) + ztownrc(:,jsv)  
        ENDDO
           !
           ! Town fraction increased to consider the vertical surfaces of buildings
           ztown_max(:) = 1. +  pwall_o_hor(:) 


        !        7.0  Compute final dry deposition velocity on urban area
        !             ---------------------------------------------------
        !
        DO jsv=1,SIZE(hsv,1) 
          pdep(:,jsv) = ztown_max(:) / zrestown(:,jsv)
        ENDDO
IF (lhook) CALL dr_hook('CH_DEP_TOWN',1,zhook_handle)

   
  !
END SUBROUTINE ch_dep_town