ch_aer_velgrav1d.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE ch_aer_velgrav1d(PSIG, PRG, PTA, PRHODREF, PRHOP, PMU, PVGK,PDPK, PVGG,PDPG)
!!   #######################################
!!
!!   PURPOSE
!!   -------
!!
!!   REFERENCE
!!   ---------
!!   none
!!
!!   AUTHOR
!!    ------
!!   P. Tulet (meteo france)
!!
!!   MODIFICATIONS
!!    -------------
!!
! Entry variables:
!
! PM(IN)       -Array of moments
!
!*************************************************************
! Exit variables:
!
! PFSED(IN)  -Array of moment variation due to dry deposition
!
!*************************************************************
! Variables used during the deposition velocity calculation
! 
! PDPK       -Polydisperse diffusivity (m2/s)
! PVGK       -Polydisperse settling velocity of the kth moment (m/s)
!************************************************************
!!
!!   IMPLICIT ARGUMENTS
USE modd_chs_aerosol
!!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE

!! Declarations d'arguments
!
REAL, DIMENSION(:,:), INTENT(OUT) :: pvgk,pdpk
REAL, DIMENSION(:),   INTENT(OUT) :: pmu
REAL, DIMENSION(:,:), INTENT(OUT) :: pvgg
REAL, DIMENSION(:,:), INTENT(OUT) :: pdpg
REAL, DIMENSION(:,:), INTENT(IN)    :: prhop
REAL, DIMENSION(:,:), INTENT(IN)    :: psig, prg
REAL, DIMENSION(:),   INTENT(IN)    :: pta, prhodref
!
!!!! Declarations de variables internes
!
REAL, DIMENSION(size(PSIG,1)) :: zlambda

REAL, DIMENSION(size(PSIG,1)) :: zrg,zln2s

REAL, DIMENSION(size(PSIG,1)) :: zkng

REAL, PARAMETER :: gasmw=28.9644d0
REAL :: zk, zrd, zavogadro, zboltz, zmd, zpi, zg

INTEGER :: ii,ij
REAL(KIND=JPRB) :: zhook_handle

IF (lhook) CALL dr_hook('CH_AER_VELGRAV1D',0,zhook_handle)
zpi = 2.*asin(1.)
zavogadro =  6.0221367e+23
zboltz = 1.380658e-23 
zmd   = 28.9644e-3
zrd  = zavogadro * zboltz / zmd
zg  = 9.80665


! Sutherland's equation for viscosity
pmu(:)=1.8325d-5*416.16/(pta(:)+120)*(pta(:)/296.16)*sqrt(pta(:)/296.16)

! Mean free path (Seinfeld and Pandis p455)
zlambda(:)=pmu(:)/prhodref(:)*sqrt(1.89d-4*gasmw/pta(:))*1.e6

do ii=1,jpmode

  zrg(:)=prg(:,ii) * 1e-6 
  zln2s(:)=log(psig(:,ii))**2 
  !
  zkng(:)=zlambda(:) / prg(:,ii) 
  !
  pvgg(:,ii)= 2.*zg*prhop(:,ii)*zrg(:)**2 /(9.*pmu(:))
  pdpg(:,ii)=zboltz*pta(:)/ (6.*zpi* zrg(:)*pmu(:))


 
  do ij=0,2
!
    zk=real(3*ij)
    pdpk(:,3*ii+ij-2)=pdpg(:,ii)*(exp((-2.*zk+1.)/2.*zln2s(:))+1.246*zkng(:)*&
                exp((-4.*zk+4)/2.*zln2s(:)))  

    pvgk(:,3*ii+ij-2)=pvgg(:,ii)*&
      (exp((4.*zk+4.)/2.*zln2s(:)) + 1.246*zkng(:)* exp((2.*zk+1.)/2.*zln2s(:)))  

  enddo
 
enddo
IF (lhook) CALL dr_hook('CH_AER_VELGRAV1D',1,zhook_handle)

END SUBROUTINE ch_aer_velgrav1d