carbon_soil.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE carbon_soil (PTSTEP, PSAND,                                      &
                          psoilcarbon_input, pcontrol_temp, pcontrol_moist, &
                          psoilcarb, presp_hetero_soil)  

!   ###############################################################
!!**  CARBON_SOIL 
!!
!!    PURPOSE
!!    -------
!!    Calculates soil carbon pools evolution.
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!    none
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!      
!!    none
!!
!!    REFERENCE
!!    ---------
!!
!!      Parton et al., Biogeochemestry, 1988
!!      Krinner et al., Global Biochemical Cycles, 2005
!!      Gibelin et al. 2008, AFM
!!      
!!    AUTHOR
!!    ------
!!
!!      A.-L. Gibelin           * Meteo-France *
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    23/06/09
!!      B. Decharme 05/2012 : Optimization
!!
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
USE modd_co2v_par,       ONLY : xtau_soilcarb
USE modd_csts,           ONLY : xday
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE


!*       0.1 input

! time step in s
REAL, INTENT(IN)                                                  :: ptstep
! sand fraction (between 0 and 1)
REAL, DIMENSION(:), INTENT(IN)                                    :: psand
! quantity of carbon going into carbon pools from litter decomposition
!   (gC/m**2/day)
REAL, DIMENSION(:,:), INTENT(IN)                                  :: psoilcarbon_input
! temperature control of heterotrophic respiration
REAL, DIMENSION(:,:), INTENT(IN)                                  :: pcontrol_temp
! moisture control of heterotrophic respiration
REAL, DIMENSION(:,:), INTENT(IN)                                  :: pcontrol_moist

!*       0.2 modified fields

! carbon pool: active, slow, or passive (gC/m**2)
REAL, DIMENSION(:,:), INTENT(INOUT)                               :: psoilcarb

!*       0.3 output

! soil heterotrophic respiration (in gC/day/m**2)
REAL, DIMENSION(:), INTENT(OUT)                                   :: presp_hetero_soil

!*       0.4 local

! time step in days
REAL                                                              :: zdt
! flux fractions within carbon pools
REAL, DIMENSION(SIZE(PSOILCARB,1),SIZE(PSOILCARB,2),SIZE(PSOILCARB,2)) :: zfrac_carb
! fraction of carbon flux which goes into heterotrophic respiration
REAL, DIMENSION(SIZE(PSOILCARB,1),SIZE(PSOILCARB,2))                   :: zfrac_resp
! total flux out of carbon pools (gC/m**2)
REAL, DIMENSION(SIZE(PSOILCARB,1),SIZE(PSOILCARB,2))                   :: zfluxtot
! fluxes between carbon pools (gC/m**2)
REAL, DIMENSION(SIZE(PSOILCARB,1),SIZE(PSOILCARB,2),SIZE(PSOILCARB,2)) :: zflux
!
REAL, DIMENSION(SIZE(PSOILCARB,1))                                     :: zwork ! Work array
!
! dimensions
INTEGER                                                           :: ini, insoilcarb
! indices
INTEGER                                                           :: ji, jl
REAL(KIND=JPRB) :: zhook_handle
!
! correspondence between array indices and litter levels
! LT_ABOVE = 1
! LT_BELOW = 2
! correspondence between array indices and soil carbon pools
! SL_ACTIVE = 1
! SL_SLOW = 2
! SL_PASSIVE = 3
!-------------------------------------------------------------------------------

!
!*       1 Initialisations
!
!
!*       1.1 dimensions
!
IF (lhook) CALL dr_hook('CARBON_SOIL',0,zhook_handle)
!
ini        = SIZE(psoilcarb,1)
insoilcarb = SIZE(psoilcarb,2)
!
!*       1.2 get soil "constants"
!
!*       1.2.1 flux fractions between carbon pools: depend on soil texture, recalculated each time
!
!*       1.2.1.1 from active pool: depends on soil texture
!
zfrac_carb(:,1,1) = 0.0
zfrac_carb(:,1,3) = 0.004
zfrac_carb(:,1,2) = 1. - ( .85 - .68 * (1.-psand(:)) ) - zfrac_carb(:,1,3)
!
!*       1.2.1.2 from slow pool
!
zfrac_carb(:,2,2) = .0
zfrac_carb(:,2,1) = .42
zfrac_carb(:,2,3) = .03
!
!*       1.2.1.3 from passive pool
!
zfrac_carb(:,3,3) = .0
zfrac_carb(:,3,1) = .45
zfrac_carb(:,3,2) = .0
!
!*       1.3 set output to zero
!
presp_hetero_soil(:) = 0.0
!
!
!*       2 input into carbon pools
!
zdt = ptstep/xday
!
psoilcarb(:,:) = psoilcarb(:,:) + psoilcarbon_input(:,:) * zdt
!
!
!*       3 fluxes within carbon reservoirs + respiration
!
!*       3.1 determine fraction of flux that is respiration
!     diagonal elements of frac_carb are zero
!
zfrac_resp(:,:) = 1. - zfrac_carb(:,:,1) - zfrac_carb(:,:,2) - zfrac_carb(:,:,3)   
!
!*       3.2 calculate fluxes
!
!*       3.2.1 flux out of pools
!
!soil property dependance (1.0-0.75*(1.0-PSAND(:)))
zwork(:)=0.25+0.75*psand(:)
!
! determine total flux out of pool
zfluxtot(:,1) = ptstep/xtau_soilcarb(1)*psoilcarb(:,1)*pcontrol_moist(:,2)*pcontrol_temp(:,2)*zwork(:) 
zfluxtot(:,2) = ptstep/xtau_soilcarb(2)*psoilcarb(:,2)*pcontrol_moist(:,2)*pcontrol_temp(:,2) 
zfluxtot(:,3) = ptstep/xtau_soilcarb(3)*psoilcarb(:,3)*pcontrol_moist(:,2)*pcontrol_temp(:,2) 
!
!decrease this carbon pool
psoilcarb(:,:) = psoilcarb(:,:) - zfluxtot(:,:)
!
!fluxes towards the other pools (k -> kk)
DO jl=1,insoilcarb
   DO ji=1,ini
      zflux(ji,1,jl) = zfrac_carb(ji,1,jl) * zfluxtot(ji,1)
      zflux(ji,2,jl) = zfrac_carb(ji,2,jl) * zfluxtot(ji,2)
      zflux(ji,3,jl) = zfrac_carb(ji,3,jl) * zfluxtot(ji,3)
   ENDDO
ENDDO
!
!*       3.2.2 respiration
!
presp_hetero_soil(:) = ( zfrac_resp(:,1) * zfluxtot(:,1) +         &
                         zfrac_resp(:,2) * zfluxtot(:,2) +         &
                         zfrac_resp(:,3) * zfluxtot(:,3)  ) / zdt  
!
!*       3.2.3 add fluxes to active, slow, and passive pools
!
psoilcarb(:,1) = psoilcarb(:,1) + zflux(:,1,1) + zflux(:,2,1) + zflux(:,3,1)  
psoilcarb(:,2) = psoilcarb(:,2) + zflux(:,1,2) + zflux(:,2,2) + zflux(:,3,2)  
psoilcarb(:,3) = psoilcarb(:,3) + zflux(:,1,3) + zflux(:,2,3) + zflux(:,3,3)  
!
IF (lhook) CALL dr_hook('CARBON_SOIL',1,zhook_handle)
!
END SUBROUTINE carbon_soil