carbon_litter.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE carbon_litter (PTSTEP, PTURNOVER, PLITTER, PLIGNIN_STRUC,          &
                          pcontrol_temp, pcontrol_moist,                      &
                          presp_hetero_litter, psoilcarbon_input)  

!   ###############################################################
!!**  CARBON_LITTER 
!!
!!    PURPOSE
!!    -------
!!    Calculates litter evolution.
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!    none
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!      
!!    none
!!
!!    REFERENCE
!!    ---------
!!
!!      Parton et al., Biogeochemestry, 1988
!!      Krinner et al., Global Biochemical Cycles, 2005
!!      Gibelin et al. 2008, AFM
!!      
!!    AUTHOR
!!    ------
!!
!!      A.-L. Gibelin           * Meteo-France *
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    23/06/09
!!      B. Decharme 05/2012 : Optimization
!!
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!    
USE modd_co2v_par,       ONLY : xlc, xtau_litter, xfrac_litter, xfrac_soilcarb
USE modd_csts,           ONLY : xday, xtt
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*       0.1 input
!
! time step in s
REAL, INTENT(IN)                                                 :: ptstep
!time step in s
! Turnover rates (gC/m**2/s)
REAL, DIMENSION(:,:), INTENT(IN)                                 :: pturnover
! temperature control of heterotrophic respiration, above and below
REAL, DIMENSION(:,:), INTENT(IN)                                 :: pcontrol_temp
! moisture control of heterotrophic respiration
REAL, DIMENSION(:,:), INTENT(IN)                                 :: pcontrol_moist
!
!*       0.2 modified fields
!
! metabolic and structural litter, above and below ground (gC/m**2)
REAL, DIMENSION(:,:,:), INTENT(INOUT)                            :: plitter
! ratio Lignin/Carbon in structural litter, above and below ground (gC/m**2)
REAL, DIMENSION(:,:), INTENT(INOUT)                              :: plignin_struc
!
!*       0.3 output
!
! litter heterotrophic respiration (in gC/m**2/day)
REAL, DIMENSION(:), INTENT(OUT)                                  :: presp_hetero_litter
! quantity of carbon going into carbon pools from litter decomposition
!   (gC/m**2/day)
REAL, DIMENSION(:,:), INTENT(OUT)                                :: psoilcarbon_input
!
!*       0.4 local
!
! time step in days
REAL                                                             :: zdt
! fraction of structural or metabolic litter decomposed
REAL                                                             :: zfd
! quantity of structural or metabolic litter decomposed (gC/m**2)
REAL                                                             :: zqd
! old structural litter, above and below (gC/m**2)
REAL, DIMENSION(SIZE(PLITTER,1),SIZE(PLITTER,3))                 :: zold_struc
! increase of metabolic and structural litter, above and below ground (gC/m**2)
REAL, DIMENSION(SIZE(PLITTER,1),SIZE(PLITTER,2),SIZE(PLITTER,3)) :: zlitter_inc
! lignin increase in structural litter, above and below ground (gC/m**2)
REAL, DIMENSION(SIZE(PLITTER,1),SIZE(PLITTER,3))                 :: zlignin_struc_inc
! dimensions
INTEGER                                                          :: inlitter,inlittlevs
! indices
INTEGER                                                          :: ini,ji,jl
!
REAL(KIND=JPRB) :: zhook_handle
!
! correspondence between array indices and biomass compartments
! LEAF = 1
! STRUCT_ACT = 2
! STRUCT_PAS = 3
! STRUCT_BELOW = 4
! WOOD_ABOVE = 5
! WOOD_BELOW = 6
! correspondence between array indices and litter type
! LT_METABOLIC = 1
! LT_STRUCTURAL = 2
! correspondence between array indices and litter levels
! LT_ABOVE = 1
! LT_BELOW = 2
! correspondence between array indices and soil carbon pools
! SL_ACTIVE = 1
! SL_SLOW = 2
! SL_PASSIVE = 3
!-------------------------------------------------------------------------------
!
!*    1 Initialisations
!
!
!*    1.1 dimensions
!
IF (lhook) CALL dr_hook('CARBON_LITTER',0,zhook_handle)
!
ini        = SIZE(plitter,1)
inlitter   = SIZE(plitter,2)
inlittlevs = SIZE(plitter,3)
!
!*    1.2 set output to zero
!
presp_hetero_litter(:) = 0.0
psoilcarbon_input(:,:) = 0.0
!
!*    2 Add biomass to different litterpools
!
zdt = ptstep/xday
!
!*    2.1 first, save old structural litter (needed for lignin fractions).
!            (above/below)
!
zold_struc(:,:) = plitter(:,2,:)
!
! *   2.2 update litter, and lignin content in structural litter
!
zlitter_inc(:,:,:) = 0.0
zlignin_struc_inc(:,:) = 0.0
!
!*    2.2.1 calculate litter increase (per m**2 of ground).
!           Litter increase for structural and metabolic, above/below
!
zlitter_inc(:,1,1) = ( xfrac_litter(1,1) * pturnover(:,1) +          &
                       xfrac_litter(2,1) * pturnover(:,2) +          &
                       xfrac_litter(3,1) * pturnover(:,3) +          &
                       xfrac_litter(5,1) * pturnover(:,5) ) * ptstep 

zlitter_inc(:,1,2) = ( xfrac_litter(4,1) * pturnover(:,4) +          &
                       xfrac_litter(6,1) * pturnover(:,6) ) * ptstep  
!
zlitter_inc(:,2,1) = ( xfrac_litter(1,2) * pturnover(:,1) +          &
                       xfrac_litter(2,2) * pturnover(:,2) +          &
                       xfrac_litter(3,2) * pturnover(:,3) +          &
                       xfrac_litter(5,2) * pturnover(:,5) ) * ptstep 

zlitter_inc(:,2,2) = ( xfrac_litter(4,2) * pturnover(:,4) +          &
                       xfrac_litter(6,2) * pturnover(:,6) ) * ptstep  
!
!*    2.2.2 lignin increase in structural litter
!
zlignin_struc_inc(:,1) = zlignin_struc_inc(:,1) + ( xlc(1)*pturnover(:,1) + xlc(2)*pturnover(:,2) +          &
                                                    xlc(3)*pturnover(:,3) + xlc(5)*pturnover(:,5) ) * ptstep  
zlignin_struc_inc(:,2) = zlignin_struc_inc(:,2) + ( xlc(4)*pturnover(:,4) + xlc(6)*pturnover(:,6) ) * ptstep  
!
!*    2.2.3 add new litter (struct/met, above/below)
!
plitter(:,:,:) = plitter(:,:,:) + zlitter_inc(:,:,:)
!
!*    2.2.4 for security: can't add more lignin than structural litter
!           (above/below)
!
zlignin_struc_inc(:,:) = min( zlignin_struc_inc(:,:), zlitter_inc(:,2,:) )
!
!*    2.2.5 new lignin content: add old lignin and lignin increase, divide by 
!           total structural litter (above/below)
!
WHERE(plitter(:,2,:)>0.0)
      plignin_struc(:,:) = (plignin_struc(:,:)*zold_struc(:,:)+zlignin_struc_inc(:,:))/plitter(:,2,:)
ENDWHERE
!
!*    3 fluxes from litter to carbon pools and respiration
!
DO jl=1,inlittlevs
   DO ji=1,ini
!
!*    3.1 structural litter: goes into active and slow carbon pools + respiration
!
!*    3.1.1 total quantity of structural litter which is decomposed
!
      zfd=ptstep/xtau_litter(2)*pcontrol_temp(ji,jl)*pcontrol_moist(ji,jl)*exp(-3.0*plignin_struc(ji,jl))  
!
      zqd=plitter(ji,2,jl)*zfd
!      
      plitter(ji,2,jl)=plitter(ji,2,jl)-zqd
!
!*    3.1.2 non-lignin fraction of structural litter goes into active carbon pool + respiration
!
      psoilcarbon_input(ji,1)=psoilcarbon_input(ji,1)+xfrac_soilcarb(2,1,jl)*zqd*(1.0-plignin_struc(ji,jl))/zdt  
!
      presp_hetero_litter(ji)=presp_hetero_litter(ji)+(1.0-xfrac_soilcarb(2,1,jl))*zqd*(1.0-plignin_struc(ji,jl))/zdt  
!
!*    3.1.3 lignin fraction of structural litter goes into slow carbon pool + respiration
!
      psoilcarbon_input(ji,2)=psoilcarbon_input(ji,2)+xfrac_soilcarb(2,2,jl)*zqd*plignin_struc(ji,jl)/zdt  
!
      presp_hetero_litter(ji)=presp_hetero_litter(ji)+(1.0-xfrac_soilcarb(2,2,jl))*zqd*plignin_struc(ji,jl)/zdt  
!
!*    3.2 metabolic litter goes into active carbon pool + respiration
!
!*    3.2.1 total quantity of metabolic litter that is decomposed
!
      zfd = ptstep/xtau_litter(1)*pcontrol_temp(ji,jl)*pcontrol_moist(ji,jl)
!
      zqd = plitter(ji,1,jl)*zfd
!
      plitter(ji,1,jl)=plitter(ji,1,jl)-zqd
!
!*    3.2.2 put decomposed litter into carbon pool + respiration
!
      psoilcarbon_input(ji,1)=psoilcarbon_input(ji,1)+xfrac_soilcarb(1,1,jl)*zqd/zdt  
!
      presp_hetero_litter(ji) = presp_hetero_litter(ji)+(1.0-xfrac_soilcarb(1,1,jl))*zqd/zdt
!
   ENDDO
ENDDO
!
IF (lhook) CALL dr_hook('CARBON_LITTER',1,zhook_handle)

!
END SUBROUTINE carbon_litter