canopy_evol_wind.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE canopy_evol_wind(KI,KLVL,PTSTEP,KIMPL,PWIND,PK,PDKDDVDZ,        &
                                   psflux_u,pforc_u,pdforc_udu,pdz,pdzf,pu,puw,   &
                                   palfa,pbeta                                    ) 
!     #########################################
!
!!****  *CANOPY_EVOL_WIND* - evolution of wind in canopy 
!!                        
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      V. Masson   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    07/2006 
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
USE modi_canopy_evol_field
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
INTEGER,                  INTENT(IN)    :: ki        ! number of horizontal points
INTEGER,                  INTENT(IN)    :: klvl      ! number of levels in canopy
REAL,                     INTENT(IN)    :: ptstep    ! time-step                             (s)
INTEGER,                  INTENT(IN)    :: kimpl     ! implicitation code: 
!                                                    ! 1 : computes only alfa and beta coupling
!                                                    !     coefficients for all variables
!                                                    ! 2 : computes temporal evolution of the
!                                                    !     variables
REAL, DIMENSION(KI),      INTENT(IN)    :: pwind     ! wind at forcing level                 (m/s)
REAL, DIMENSION(KI,KLVL), INTENT(IN)    :: pk        ! mixing exchange coefficient           (m2/s)
REAL, DIMENSION(KI,KLVL), INTENT(IN)    :: pdkddvdz  ! derivative of mixing coefficient as a
!                                                    ! function of vertical gradient of wind
!                                                    ! (at mid levels)                       (m2)
REAL, DIMENSION(KI),      INTENT(IN)    :: psflux_u  ! Surface flux u'w'                     (m2/s2)
REAL, DIMENSION(KI,KLVL), INTENT(IN)    :: pforc_u   ! tendency of wind due to canopy drag   (m/s2)
REAL, DIMENSION(KI,KLVL), INTENT(IN)    :: pdforc_udu! formal derivative of the tendency of
!                                                    ! wind due to canopy drag              (1/s)
REAL, DIMENSION(KI,KLVL), INTENT(IN)    :: pdz       ! deltaZ between canopy half levels,
!                                                    ! located at full levels                (m)
REAL, DIMENSION(KI,KLVL), INTENT(IN)    :: pdzf      ! deltaZ between canopy (full) levels,
!                                                    ! located at half levels                (m)
REAL, DIMENSION(KI,KLVL), INTENT(INOUT) :: pu        ! wind speed at canopy levels           (m/s)
REAL, DIMENSION(KI,KLVL), INTENT(OUT)   :: puw       ! turbulent flux (at half levels)       (m2/s2)
REAL, DIMENSION(KI),      INTENT(OUT)   :: palfa     !  V+(1) = alfa u'w' + beta
REAL, DIMENSION(KI),      INTENT(OUT)   :: pbeta     !  V+(1) = alfa u'w' + beta
!
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
INTEGER                     :: jlayer   ! loop counter on layers
!
REAL, DIMENSION(KI,KLVL)   :: zdudz    ! dU/dz at mid levels
REAL, DIMENSION(KI,KLVL)   :: zf       ! turbulent flux at mid levels
REAL, DIMENSION(KI,KLVL)   :: zdfddvdz ! derivative of turbulent flux as a
!                                       ! function of vertical gradient of wind variable
!                                       ! (at mid levels)
REAL, DIMENSION(KI,KLVL)   :: zext     ! external forcing at full levels
REAL, DIMENSION(KI,KLVL)   :: zdextdv  ! derivative of external forcing as a
!                                       ! function of vertical variable
!                                       ! (at full levels)
REAL, DIMENSION(KI,KLVL)   :: zu       ! work variable : wind at futur instant 
!                                       ! (or past at the end of the routine) 
REAL, DIMENSION(KI)         :: zduadt   ! dUa/dt   at forcing level
LOGICAL                     :: limpl
REAL(KIND=JPRB) :: zhook_handle
!
!-------------------------------------------------------------------------------
!
!
!*    1. initializations
!        ---------------
!
!* external forces
!
IF (lhook) CALL dr_hook('CANOPY_EVOL_WIND',0,zhook_handle)
zext = 0.
zdextdv = 0.
!
!* coupling coefficient with the surface
!
palfa(:)=0.
pbeta(:)=pu(:,1)
!
!-------------------------------------------------------------------------------
!
!*    5. Forcing due to drag (at full levels)
!        -------------------
!
!* drag force by canopy
!
zext = zext + pforc_u(:,:)
!
zdextdv = zdextdv + pdforc_udu(:,:)
!
!-------------------------------------------------------------------------------
!
!*    6. External forcing due to large-scale forces (at full levels)
!        ------------------------------------------
!
!
!* forces due to large-scale forcing
!
! These are computed from wind evolution equation at forcing level :
!
! dUa/dt = Large_Scale_Forcing - d(u'w')/dz|z=forcing_level
!
! because vertical derivative of turbulent flux is not available at forcing
! level, one must make the assumption that the turbulent flux is uniform
! between the forcing level and the level just below.
! This means that one assume that the forcing layer is in the inertail sublayer
! (where turbulent fluxes are constant).
!
zduadt(:) = ( pwind(:) - pu(:,klvl) ) /ptstep
!
!* for smoother evolution at large time steps, does not include explicitely
!  forcing term in lower layers
DO jlayer=1,klvl-1
  zext(:,jlayer) = zext(:,jlayer)
END DO

!* evolution of forcing layer forced by forcing...
zext(:,klvl) = zduadt(:)
!
 CALL  canopy_evol_field(ki, klvl, ptstep, kimpl, pk, pdkddvdz, &
                        psflux_u, pforc_u, pdforc_udu, pdz, pdzf,     &
                        zext, zdextdv, pu, puw, palfa, pbeta          ) 
!
!-------------------------------------------------------------------------------
!
!*   10. Security at all levels : positivity of wind speed
!        ----------------------
!
pu(:,:) = max(pu,0.)
IF (lhook) CALL dr_hook('CANOPY_EVOL_WIND',1,zhook_handle)
!
!----------------------------------------------------------------
!
END SUBROUTINE canopy_evol_wind