bld_occ_calendar.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!#####################################################################################
SUBROUTINE bld_occ_calendar(KYEAR, KMONTH, KDAY, PTSUN, PRESIDENTIAL, PTCOOL_TARGET_IN, PTHEAT_TARGET_IN, &
                            pqin_in, pdt_res, pdt_off, pqin_frac, ptcool_target, ptheat_target, pqin)
!#####################################################################################
!! **** BLD_OCC_CALENDAR *
!!
!!  PURPOSE
!!  -------
!! BLD_OCC_CALENDAR defines the parameters relevant for BEM (TCOOL_TARGET, THEAT_TARGET and QIN)
!! depending on the building use type (hence the DOW and local French TOD) * based on MUSCADE scenarii *
!!
!! AUTHOR
!! ------
!! C. de Munck     *Météo-France*
!! 
!! MODIFICATIONS
!! -------------
!! Original  02/2013
!
USE modd_csts,         ONLY : xtt
!
USE modi_day_of_week
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!! 1. declaration of arguments
!
INTEGER,INTENT(IN)                :: kyear         ! current year  (UTC)
INTEGER,INTENT(IN)                :: kmonth        ! current month (UTC)
INTEGER,INTENT(IN)                :: kday          ! current day   (UTC)
REAL,   DIMENSION(:) , INTENT(IN) :: ptsun         ! current solar time  (s, UTC)
!
REAL, DIMENSION(:) , INTENT(IN)  :: presidential     ! Residential use fraction
REAL, DIMENSION(:) , INTENT(IN)  :: ptcool_target_in ! Cooling setpoint of HVAC system [K] input
REAL, DIMENSION(:) , INTENT(IN)  :: ptheat_target_in ! Heating setpoint of HVAC system [K] input
REAL, DIMENSION(:) , INTENT(IN)  :: pqin_in          ! Internal heat gains [W m-2(floor)] input
REAL,                INTENT(IN)  :: pdt_res          ! Target temperature change when unoccupied (K) (residential buildings)
REAL,                INTENT(IN)  :: pdt_off          ! Target temperature change when unoccupied (K) (offices and commercial buildings)
REAL,                INTENT(IN)  :: pqin_frac        ! Fraction of internal gains when unoccupied (-)
!
REAL, DIMENSION(:) , INTENT(OUT)  :: ptcool_target ! Cooling setpoint of HVAC system [K]
REAL, DIMENSION(:) , INTENT(OUT)  :: ptheat_target ! Heating setpoint of HVAC system [K]
REAL, DIMENSION(:) , INTENT(OUT)  :: pqin          ! Internal heat gains [W m-2(floor)]
!
!! 2. declaration of local variables
!
 CHARACTER(LEN = 6)                :: ctime         ! Local time scheme (winter or summer time)
INTEGER                           :: jdow          ! day of week
INTEGER                           :: jj
!
REAL, DIMENSION(SIZE(PQIN))       :: ztod_beg      ! first Time Of Day that building unoccupied (UTC, s)
REAL, DIMENSION(SIZE(PQIN))       :: ztod_end      ! last Time Of Day that building unoccupied (UTC, s)
REAL, DIMENSION(SIZE(PQIN))       :: zdt           ! Target temperature change when unoccupied (K)

REAL(KIND=JPRB) :: ztodook_handle
!
IF (lhook) CALL dr_hook('BLD_OCC_CALENDAR',0,ztodook_handle)
!
!--------------------------------------------------------------------------------------
!  3. determine the day of the week and the local time scheme in France
!--------------------------------------------------------------------------------------
!
 CALL day_of_week(kyear, kmonth, kday, jdow)
!
 ctime = 'WINTER'
IF (kmonth >= 4 .AND. kmonth <= 10) ctime = 'SUMMER'
!
!--------------------------------------------------------------------------------------
!  4. initialisation of parameters
!--------------------------------------------------------------------------------------
!
! Parameters assigned to the occupied values - read in namelist via BATI.csv :
!
ptheat_target(:) = ptheat_target_in(:)
!  
ptcool_target(:) = ptcool_target_in(:)
! 
pqin(:)          = pqin_in(:)
!
ztod_beg(:) = 0.
ztod_end(:) = 0.
!
!--------------------------------------------------------------------------------------
!  5. computes beginning and end of unoccupied calendar based on building USE TYPE
!--------------------------------------------------------------------------------------
!
DO jj =1,SIZE(ptsun)
!
 IF (presidential(jj) > 0.5) THEN ! RESIDENTIAL
   !
   IF (jdow >= 2 .AND. jdow <=6) THEN ! week days
     ztod_beg(jj) =  9. * 3600.       !  9 UTC - WINTER time
     ztod_end(jj) = 17. * 3600.       ! 17 UTC - WINTER time
   END IF
   zdt(jj) = pdt_res
   !
 ELSE
   !     
   IF (jdow >= 2 .AND. jdow <=7) THEN ! week days
     ztod_beg(jj) = 17. * 3600.       ! 17 UTC
     ztod_end(jj) =  7. * 3600.       !  7 UTC
   ELSE                               ! week-end
     ztod_beg(jj) =  0. * 3600.       !   0 UTC
     ztod_end(jj) = 24. * 3600.       !  24 UTC
   END IF
   zdt(jj) = pdt_off
   !
 END IF
! adjustment of unoccupied TOD based on time scheme
 IF (ctime == 'SUMMER') THEN
  ztod_beg(jj) = ztod_beg(jj) - 3600.   
  ztod_end(jj) = ztod_end(jj) - 3600.   
 END IF
!
ENDDO
!
!--------------------------------------------------------------------------------------
!  6. modulate BEM input values for unoccupied building calendar
!--------------------------------------------------------------------------------------
!
DO jj =1,SIZE(ptsun)
!
     IF (( (ztod_beg(jj) < ztod_end(jj)) .AND. (ptsun(jj) > ztod_beg(jj) .AND. ptsun(jj) < ztod_end(jj))    )      &
        .OR.                                                                                         &
         ( (ztod_beg(jj) > ztod_end(jj)) .AND. ((ptsun(jj) > 0 .AND. ptsun(jj) < ztod_end(jj)) .OR.            &
                                        (ptsun(jj) > ztod_beg(jj) .AND. ptsun(jj) < 24 * 3600.)))) THEN             
         !
            ptheat_target(jj) = ptheat_target_in(jj) - zdt(jj)
            ptcool_target(jj) = ptcool_target_in(jj) + zdt(jj)
            pqin(jj) = pqin_frac * pqin(jj)
      ENDIF
!
ENDDO
!
!--------------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('BLD_OCC_CALENDAR',1,ztodook_handle)
!
END SUBROUTINE bld_occ_calendar