bem_morpho.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!#####################################################################
SUBROUTINE bem_morpho(PBLD, PWALL_O_HOR, PBLD_HEIGHT, PFLOOR_HEIGHT,            &
                      pgr, pn_floor, pwall_o_bld, pglaz_o_bld, pmass_o_bld,     &
                      pfloor_hw_ratio,                                          &
                      pf_floor_mass, pf_floor_wall, pf_floor_win,               &
                      pf_floor_roof, pf_wall_floor, pf_wall_mass,               &
                      pf_wall_win, pf_win_floor, pf_win_mass, pf_win_wall,      &
                      pf_mass_floor, pf_mass_wall, pf_mass_win, pf_waste_can,   &
                      pf_win_win)
!#####################################################################
!
!!**** *BEM_MORPHO 
!!
!!    PURPOSE
!!    -------
!! compute morphometric parameter of the building for BEM
!! 
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      G. Pigeon   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    10/2011
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
REAL, DIMENSION(:),   INTENT(IN)  :: pbld         ! Urban horizontal building density
REAL, DIMENSION(:),   INTENT(IN)  :: pwall_o_hor  ! Wall to horizontal surface ratio
REAL, DIMENSION(:),   INTENT(IN)  :: pbld_height  ! Average building height [m]
REAL, DIMENSION(:),   INTENT(INOUT)::pfloor_height ! Building floor height [m]
REAL, DIMENSION(:),   INTENT(IN)  :: pgr           ! Glazing ratio
REAL, DIMENSION(:),   INTENT(OUT) :: pn_floor ! number of floor levels
REAL, DIMENSION(:),   INTENT(OUT) :: pwall_o_bld  ! wall surface per ground building surface [m2(wall)/m2(bld)]
REAL, DIMENSION(:),   INTENT(OUT) :: pglaz_o_bld  ! glazing surface per ground building surface [m2(glazing)/m2(bld)]
REAL, DIMENSION(:),   INTENT(OUT) :: pmass_o_bld  ! thermal mass surface per ground building surface [m2(mass)/m2(bld)]
REAL, DIMENSION(:),   INTENT(OUT) :: pfloor_hw_ratio !Height to width ratio of the floor levels
REAL, DIMENSION(:),   INTENT(OUT) :: pf_floor_mass  !view factor from floor to mass (how much floor seen by mass)
REAL, DIMENSION(:),   INTENT(OUT) :: pf_floor_wall
REAL, DIMENSION(:),   INTENT(OUT) :: pf_floor_win
REAL, DIMENSION(:),   INTENT(OUT) :: pf_floor_roof
REAL, DIMENSION(:),   INTENT(OUT) :: pf_wall_floor
REAL, DIMENSION(:),   INTENT(OUT) :: pf_wall_mass
REAL, DIMENSION(:),   INTENT(OUT) :: pf_wall_win
REAL, DIMENSION(:),   INTENT(OUT) :: pf_win_floor
REAL, DIMENSION(:),   INTENT(OUT) :: pf_win_mass
REAL, DIMENSION(:),   INTENT(OUT) :: pf_win_wall
REAL, DIMENSION(:),   INTENT(OUT) :: pf_win_win
REAL, DIMENSION(:),   INTENT(OUT) :: pf_mass_floor
REAL, DIMENSION(:),   INTENT(OUT) :: pf_mass_wall
REAL, DIMENSION(:),   INTENT(OUT) :: pf_mass_win
REAL, DIMENSION(:),   INTENT(INOUT)::pf_waste_can !fraction of waste heat released into the canyon
!
!*      0.2    Declarations of local variables 
!
REAL, DIMENSION(SIZE(PBLD)):: zf_aux2       ! Auxiliar view factor
!
!RJ: missing declaration
INTEGER :: jj
!
!------------------------------------------------------------------------------
!
!*    1.   Verify floor height
!          -------------------
!
DO jj=1,SIZE(pbld)
  IF (pfloor_height(jj) < 2.5) THEN
!    WRITE(ILUOUT,*) 'WARNING: PFLOOR_HEIGHT low ',PFLOOR_HEIGHT(JJ),' grid mesh number ',JJ
    pfloor_height(jj) = 2.5
  ENDIF
  IF (pfloor_height(jj) > pbld_height(jj)) THEN
!    WRITE(ILUOUT,*) 'WARNING: PFLOOR_HEIGHT higher than PBLD_HEIGHT ',PFLOOR_HEIGHT(JJ),' grid mesh number ',JJ, &
!                    'set to PBLD_HEIGHT'
    pfloor_height(jj) = pbld_height(jj)
  ENDIF
!
!*    1.   Verify location of HVAC release for very extended buildings
!          -----------------------------------------------------------
!
  IF (pbld(jj) > 0.9999 .AND. pf_waste_can(jj) > 0.) THEN
!    WRITE(ILUOUT,*) 'WARNING: PF_WASTE_CAN cannot be higher than 0. while PBLD is 0.9999',PF_WASTE_CAN(JJ), &
!                    ' grid mesh number ',JJ,' set to 0.'
    pf_waste_can(jj) = 0.
  ENDIF
END DO
!
!*       1.    floor number, relative surf. and view factors caculation
!              --------------------------------------------------------
!
pn_floor(:) = float(nint(pbld_height(:) / pfloor_height(:) ))
pwall_o_bld(:) = pwall_o_hor(:) * (1. - pgr(:)) / pbld(:) ! [m2(wall)/m2(bld)]
pglaz_o_bld(:) = pwall_o_hor(:) * pgr(:)        / pbld(:) ! [m2(win)/m2(bld)]

WHERE(pn_floor > 1.5)
   !* more than 1 floor level -> the floor and the roof don't see each other
   !
   !           ROOF
   !  |---------------------|
   !  |                     |
   !  |                     |
   !  |        MASS         |
   !  |---------------------|
   !  |---------------------|
   !  |        MASS         |
   !  |                     |
   !  |                     |
   !  |        FLOOR        |
   !  |---------------------|
   !
   pmass_o_bld(:) = 2 * (pn_floor(:) - 1.)                     ! [m2(mass)/m2(bld)]
   pfloor_hw_ratio(:) = pwall_o_hor(:) / pn_floor(:) / pbld(:) / 2.
   !
   pf_floor_mass(:) = (pfloor_hw_ratio(:)**2 + 1.)**0.5  - pfloor_hw_ratio(:)
   pf_floor_wall(:) = (1. - pf_floor_mass(:)) * (1. - pgr(:))
   pf_floor_win(:) = (1. - pf_floor_mass(:)) * pgr(:)
   pf_floor_roof(:) = 0. ! no rad interaction between floor and roof
   !
   zf_aux2(:) = (1. - pf_floor_mass(:)) / pfloor_hw_ratio(:)
   !
   pf_wall_floor(:) = zf_aux2(:) / ( 2.*pn_floor(:) )
   pf_wall_mass(:) = pf_wall_floor(:) * (2.*pn_floor(:)-2.) 
   pf_wall_win(:) = (1. - zf_aux2(:)) * pgr(:)
   !
   pf_win_floor(:) = pf_wall_floor(:)
   pf_win_mass(:) = pf_wall_mass(:)
   pf_win_wall(:) = (1. - pf_win_floor(:) * 2. - pf_win_mass(:) ) * (1. - pgr(:))
   pf_win_win(:) = (1. - pf_win_floor(:) * 2. - pf_win_mass(:) ) * pgr(:)
   !
   pf_mass_floor(:) = pf_floor_mass(:) / pmass_o_bld(:)
   pf_mass_wall(:) = pwall_o_bld(:) * pf_wall_mass(:) / pmass_o_bld(:)
   pf_mass_win(:) = pglaz_o_bld(:) * pf_win_mass(:)  / pmass_o_bld(:)
ELSE WHERE
   !* 1 floor level -> no mass view factors ; roof and floor see each other
   !
   !           ROOF
   !  |---------------------|
   !  |                     |
   !  |                     |
   !  |        FLOOR        |
   !  |---------------------|
   !
   pmass_o_bld(:) = 0.
   pfloor_hw_ratio(:) = pwall_o_hor(:) / pbld(:) / 2.
   !
   pf_floor_roof(:) = (pfloor_hw_ratio(:)**2 + 1.)**0.5  - pfloor_hw_ratio(:)
   pf_floor_mass(:) = 0.
   pf_floor_wall(:) = (1. - pf_floor_roof(:)) * (1. - pgr(:))
   pf_floor_win(:) = (1. - pf_floor_roof(:)) * pgr(:)
   !
   zf_aux2(:) = (1. - pf_floor_roof(:)) / pfloor_hw_ratio(:)
   !
   pf_wall_floor(:) = zf_aux2(:) / 2.
   pf_wall_mass(:) = 0.
   pf_wall_win(:) = (1. - zf_aux2(:)) * pgr(:)
   !
   pf_win_floor(:) = pf_wall_floor(:)
   pf_win_mass(:) = 0.
   pf_win_wall(:) = (1. - pf_win_floor(:) * 2. - pf_win_mass(:) ) * (1. - pgr(:))
   pf_win_win(:) = (1. - pf_win_floor(:) * 2. - pf_win_mass(:) ) * pgr(:)
   !
   pf_mass_floor(:) = 0.
   pf_mass_wall(:) = 0.
   pf_mass_win(:) = 0.
END WHERE
!
END SUBROUTINE bem_morpho
!-------------------------------------------------------------------------------