average1_orography.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE average1_orography (USS, &
                                     kluout,knblines,plat,plon,pvalue,pnodata)
!     #######################################################
!
!!**** *AVERAGE1_OROGRAPHY* computes the sum of orography, squared orography
!!                              and subgrid orography characteristics
!!
!!    PURPOSE
!!    -------
!!
!!    METHOD
!!    ------
!!   
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    V. Masson         Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original    12/09/95
!!
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
!
USE modd_surf_atm_sso_n, ONLY : surf_atm_sso_t
!
USE modd_pgdwork,       ONLY : xsumval, xsumval2, nsize, xssqo, lssqo, nsso
!
USE modi_get_mesh_index
USE modd_point_overlay, ONLY : novmx
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
!
TYPE(surf_atm_sso_t), INTENT(INOUT) :: uss
!
INTEGER,                 INTENT(IN)    :: kluout
INTEGER,                 INTENT(IN)    :: knblines
REAL, DIMENSION(:),      INTENT(IN)    :: plat    ! latitude of the point to add
REAL, DIMENSION(:),      INTENT(IN)    :: plon    ! longitude of the point to add
REAL, DIMENSION(:),      INTENT(IN)    :: pvalue  ! value of the point to add
REAL, OPTIONAL, INTENT(IN) :: pnodata
!
!*    0.2    Declaration of other local variables
!            ------------------------------------
!
INTEGER, DIMENSION(NOVMX,SIZE(PLAT)) :: iindex ! mesh index of all input points
                                         ! 0 indicates the point is out of the domain
INTEGER, DIMENSION(NOVMX,SIZE(PLAT)) :: issox  ! X submesh index in their mesh of all input points
INTEGER, DIMENSION(NOVMX,SIZE(PLAT)) :: issoy  ! Y submesh index in their mesh of all input points
!
INTEGER :: jloop, jover        ! loop index on input arrays
REAL, DIMENSION(SIZE(PLAT)) :: zvalue
REAL :: znodata
REAL(KIND=JPRB) :: zhook_handle
!----------------------------------------------------------------------------
!
!
!*    1.     Get position
!            ------------
!     
IF (lhook) CALL dr_hook('AVERAGE1_OROGRAPHY',0,zhook_handle)
!      
IF (present(pnodata)) THEN
  zvalue(:) = pvalue(:)
  znodata = pnodata
  CALL get_mesh_index(kluout,knblines,plat,plon,iindex,zvalue,znodata,nsso,issox,issoy)
ELSE
  zvalue(:) = 1.
  znodata = 0.
  CALL get_mesh_index(kluout,knblines,plat,plon,iindex,ksso=nsso,kissox=issox,kissoy=issoy)
ENDIF
!
!*    2.     Loop on all input data points
!            -----------------------------
!    
bloop: &
DO jloop = 1 , SIZE(plat)
!
  DO jover = 1, novmx
!
!*    3.     Tests on position
!            -----------------
!     
    IF (iindex(jover,jloop)==0) cycle bloop
!
!*    4.     Summation
!            ---------
!
    nsize(iindex(jover,jloop))=nsize(iindex(jover,jloop))+1
!
!*    5.     Orography
!            ---------
!
    xsumval(iindex(jover,jloop))=xsumval(iindex(jover,jloop))+pvalue(jloop)
!
!*    6.     Square of Orography
!            -------------------
!
    xsumval2(iindex(jover,jloop))=xsumval2(iindex(jover,jloop))+pvalue(jloop)**2
!
!*    7.     Maximum orography in a subgrid square
!            -------------------------------------
!
    lssqo(issox(jover,jloop),issoy(jover,jloop),iindex(jover,jloop)) = .true.
    xssqo(issox(jover,jloop),issoy(jover,jloop),iindex(jover,jloop)) = &
         max(  xssqo(issox(jover,jloop),issoy(jover,jloop),iindex(jover,jloop)) , pvalue(jloop) )   
!
!
!*    8.     Maximum orography in the mesh
!            -----------------------------
!
    uss%XMAX_ZS(iindex(jover,jloop))=max(uss%XMAX_ZS(iindex(jover,jloop)),pvalue(jloop))
!
!
!*    9.     Minimum orography in the mesh
!            -----------------------------
!
    uss%XMIN_ZS(iindex(jover,jloop))=min(uss%XMIN_ZS(iindex(jover,jloop)),pvalue(jloop))
!
!
  END DO
!
ENDDO bloop
IF (lhook) CALL dr_hook('AVERAGE1_OROGRAPHY',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE average1_orography