average1_mesh.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE average1_mesh(KLUOUT,KNBLINES,PLAT,PLON,PVALUE,PNODATA)
!     #######################################################
!
!!**** *AVERAGE1_MESH* computes the sum of orography, squared orography
!!                              and subgrid orography characteristics
!!
!!    PURPOSE
!!    -------
!!
!!    METHOD
!!    ------
!!   
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    V. Masson         Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original    12/09/95
!!
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
USE modd_pgdwork,       ONLY : xsumval, nsize, catype, &
                               nvalnbr, nvalcount, xvallist, jpvalmax
USE modd_data_cover_par,ONLY : xcdref
!
USE modi_get_mesh_index
USE modd_point_overlay
USE modi_abor1_sfx
!
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
INTEGER,                 INTENT(IN)    :: kluout
INTEGER,                 INTENT(IN)    :: knblines
REAL, DIMENSION(:),      INTENT(IN)    :: plat    ! latitude of the point to add
REAL, DIMENSION(:),      INTENT(IN)    :: plon    ! longitude of the point to add
REAL, DIMENSION(:),      INTENT(IN)    :: pvalue  ! value of the point to add
REAL, OPTIONAL, INTENT(IN) :: pnodata
!
!*    0.2    Declaration of other local variables
!            ------------------------------------
!
INTEGER, DIMENSION(NOVMX,SIZE(PLAT)) :: iindex ! mesh index of all input points
                                         ! 0 indicates the point is out of the domain
INTEGER :: jval         ! loop counter on encoutered values
INTEGER :: jloop, jover        ! loop index on input arrays
REAL    :: zeps=1.e-10  ! a small value
LOGICAL :: gfound       ! T : Value already found in this grid point
!
REAL, DIMENSION(SIZE(PLAT)) :: zvalue
REAL :: znodata
!
REAL(KIND=JPRB) :: zhook_handle
!----------------------------------------------------------------------------
!
!*    1.     Get position
!            ------------
! 
IF (lhook) CALL dr_hook('AVERAGE1_MESH',0,zhook_handle)
!
IF (present(pnodata)) THEN
  zvalue(:) = pvalue(:)
  znodata = pnodata
  CALL get_mesh_index(kluout,knblines,plat,plon,iindex,zvalue,znodata)
ELSE
  zvalue(:) = 1.
  znodata = 0.
  CALL get_mesh_index(kluout,knblines,plat,plon,iindex)
ENDIF
!
!*    2.     Loop on all input data points
!            -----------------------------
!     
bloop: &
DO jloop = 1 , SIZE(plat)
!
  DO jover = 1, novmx
!
!*    3.     Tests on position
!            -----------------
! 
    IF (iindex(jover,jloop)==0) cycle bloop
!
!*    4.     Summation
!            ---------
!
    nsize(iindex(jover,jloop))=nsize(iindex(jover,jloop))+1
!
!*    5.     Choice of type of summation
!            ---------------------------
!
    SELECT CASE (catype)
      CASE ('ARI')
        xsumval(iindex(jover,jloop))=xsumval(iindex(jover,jloop))+   pvalue(jloop)
      CASE ('INV')
        xsumval(iindex(jover,jloop))=xsumval(iindex(jover,jloop))+1./pvalue(jloop)
      CASE ('CDN')
        xsumval(iindex(jover,jloop))=xsumval(iindex(jover,jloop))+1./(log(xcdref/pvalue(jloop)))**2
      CASE ('MAJ')
        gfound=.false.
        DO jval=1,nvalnbr(iindex(jover,jloop))
          IF (abs( xvallist(iindex(jover,jloop),jval) - pvalue(jloop)) < zeps) THEN
            nvalcount(iindex(jover,jloop),jval) = nvalcount(iindex(jover,jloop),jval) + 1
            gfound=.true.
            EXIT
          END IF
        END DO
        IF (.NOT. gfound) THEN
          IF (nvalnbr(iindex(jover,jloop))==jpvalmax) &
            CALL abor1_sfx('TOO MANY DIFFERENT VALUES TO AGGREGATE WITH THE MAJORITY RULE')
          nvalnbr(iindex(jover,jloop)) = nvalnbr(iindex(jover,jloop)) +1
          jval = nvalnbr(iindex(jover,jloop))
          nvalcount(iindex(jover,jloop),jval) = 1
          xvallist(iindex(jover,jloop),jval) = pvalue(jloop)
        END IF
    END SELECT
!
  ENDDO
END DO bloop
IF (lhook) CALL dr_hook('AVERAGE1_MESH',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE average1_mesh