average1_ldb.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE average1_ldb(KLUOUT,KNBLINES,PLAT,PLON,PVALUE,HTYPE,PNODATA)
!     #######################################################
!
!!**** *AVERAGE1_LDB* 
!!
!!    PURPOSE
!!    -------
!!
!!    METHOD
!!    ------
!!   
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    S. Faroux         Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original    17/02/11
!!
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
USE modd_pgdwork, ONLY : xtng, nsize
USE modd_data_lake, ONLY : xboundgraddepth_ldb, xboundgradstatus_ldb
!
USE modd_point_overlay
!
USE modi_get_mesh_index
USE modi_abor1_sfx
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
INTEGER,                 INTENT(IN)    :: kluout
INTEGER,                 INTENT(IN)    :: knblines
REAL, DIMENSION(:),      INTENT(IN)    :: plat    ! latitude of the point to add
REAL, DIMENSION(:),      INTENT(IN)    :: plon    ! longitude of the point to add
REAL, DIMENSION(:),      INTENT(IN)    :: pvalue  ! value of the point to add
 CHARACTER(LEN=1),       INTENT(IN)    :: htype
REAL, OPTIONAL, INTENT(IN) :: pnodata
!
!*    0.2    Declaration of other local variables
!            ------------------------------------
!
REAL, DIMENSION(:), ALLOCATABLE :: zbound
!
INTEGER, DIMENSION(NOVMX,SIZE(PLAT)) :: iindex ! mesh index of all input points
                                         ! 0 indicates the point is out of the domain                              
!
REAL, DIMENSION(SIZE(PLAT)) :: zvalue
REAL :: znodata
!
REAL    :: zcut
INTEGER :: jloop, jgrad, jover        ! loop index on input arrays
REAL(KIND=JPRB) :: zhook_handle
!----------------------------------------------------------------------------
!
!*    1.     Get position
!            ------------
!     
IF (lhook) CALL dr_hook('AVERAGE1_LDB',0,zhook_handle)
!
SELECT CASE (htype)
!
  CASE('D')
    ALLOCATE(zbound(SIZE(xboundgraddepth_ldb)))
    zbound(:) = xboundgraddepth_ldb(:)
!
  CASE('S')
    ALLOCATE(zbound(SIZE(xboundgradstatus_ldb)))
    zbound(:) = xboundgradstatus_ldb(:)
!
  CASE default
    CALL abor1_sfx("AVERAGE1_LDB: HTYPE NOT SUPPORTED")
!
END SELECT
!
!
IF (present(pnodata)) THEN
  zvalue(:) = pvalue(:)
  znodata = pnodata
  CALL get_mesh_index(kluout,knblines,plat,plon,iindex,zvalue,znodata)
ELSE
  zvalue(:) = 1.
  znodata = 0.
  CALL get_mesh_index(kluout,knblines,plat,plon,iindex)
ENDIF
!
!*    2.     Loop on all input data points
!            -----------------------------
!    
bloop: &
DO jloop = 1 , SIZE(plat)
!
  DO jover = 1, novmx
!
!*    3.     Tests on position
!            -----------------
!     
    IF (iindex(jover,jloop)==0) cycle bloop
!
!*    4.     Test on value meaning
!            ---------------------
!
    zcut = pvalue(jloop)
!
    DO jgrad = 1, SIZE(zbound)-1
      IF (zcut.GT.zbound(jgrad) .AND. zcut.LE.zbound(jgrad+1)) THEN
        xtng(iindex(1,jloop),jgrad) = xtng(iindex(1,jloop),jgrad) + 1
        EXIT
      ENDIF
    ENDDO
!
!*    5.     Summation
!            ---------
!
    nsize(iindex(1,jloop))=nsize(iindex(1,jloop))+1
!
  END DO
!
ENDDO bloop
!
DEALLOCATE(zbound)
!
IF (lhook) CALL dr_hook('AVERAGE1_LDB',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE average1_ldb