average1_cover.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE average1_cover(KLUOUT,KNBLINES,PLAT,PLON,PVALUE,PNODATA)
!     #######################################################
!
!!**** *AVERAGE1_COVER* computes the sum of values of a cover fractions
!!                              and the nature of terrain on the grid
!!                              from a data in land-cover file
!!
!!    PURPOSE
!!    -------
!!
!!    METHOD
!!    ------
!!   
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    V. Masson         Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original    12/09/95
!!
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
USE modd_pgdwork, ONLY : xsumcover, nsize
!
USE modi_get_mesh_index
USE modd_point_overlay
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
INTEGER,                 INTENT(IN)    :: kluout
INTEGER,                 INTENT(IN)    :: knblines
REAL, DIMENSION(:),      INTENT(IN)    :: plat    ! latitude of the point to add
REAL, DIMENSION(:),      INTENT(IN)    :: plon    ! longitude of the point to add
REAL, DIMENSION(:),      INTENT(IN)    :: pvalue  ! value of the point to add
REAL, OPTIONAL, INTENT(IN) :: pnodata
!
!*    0.2    Declaration of other local variables
!            ------------------------------------
!
INTEGER, DIMENSION(NOVMX,SIZE(PLAT)) :: iindex ! mesh index of all input points
                                         ! 0 indicates the point is out of the domain                              
!
REAL, DIMENSION(SIZE(PLAT)) :: zvalue
REAL :: znodata
INTEGER :: jloop, jover        ! loop index on input arrays
INTEGER :: icoverclass  ! class of cover type
REAL(KIND=JPRB) :: zhook_handle
!----------------------------------------------------------------------------
!
!
!*    1.     Get position
!            ------------
!     
IF (lhook) CALL dr_hook('AVERAGE1_COVER',0,zhook_handle)
!
IF (present(pnodata)) THEN
  zvalue(:) = pvalue(:)
  znodata = pnodata
  CALL get_mesh_index(kluout,knblines,plat,plon,iindex,zvalue,znodata)
ELSE
  zvalue(:) = 1.
  znodata = 0.
  CALL get_mesh_index(kluout,knblines,plat,plon,iindex)
ENDIF
!
!*    2.     Loop on all input data points
!            -----------------------------
!     
bloop: &
DO jloop = 1 , SIZE(plat)
!
!*    3.     Tests on position
!            -----------------
!    
  DO jover = 1, novmx

    IF (iindex(jover,jloop)==0) cycle bloop
!
!*    4.     Test on value meaning
!            ---------------------
!
    icoverclass = nint(pvalue(jloop))
!
    IF (icoverclass<1 .OR. icoverclass > SIZE(xsumcover,2) )  cycle
!
!*    5.     Summation
!            ---------
!
    nsize(iindex(jover,jloop))=nsize(iindex(jover,jloop))+1
!
!*    6.     Fraction of cover type
!            ----------------------
!
    xsumcover(iindex(jover,jloop),icoverclass)=xsumcover(iindex(jover,jloop),icoverclass)+1.
!
  ENDDO
!
END DO bloop
!
IF (lhook) CALL dr_hook('AVERAGE1_COVER',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE average1_cover