assim_set_sst.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     ###############################################################################
SUBROUTINE assim_set_sst (DTCO, DGU, S, U, &
                          ki,pitm,psst,psic,htest)

!     ###############################################################################
!
!!****  *ASSIM_SET_SST * - Reads SST from file
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     T. Aspelien
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    04/2012
!!--------------------------------------------------------------------
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_diag_surf_atm_n, ONLY : diag_surf_atm_t
USE modd_seaflux_n, ONLY : seaflux_t
USE modd_surf_atm_n, ONLY : surf_atm_t
!
USE modd_surfex_mpi, ONLY : nrank, npio, nproc
!
USE modd_assim,         ONLY : lecsst, lread_sst_from_file, cfile_format_sst, nprintlev
USE modd_surf_par,      ONLY : xundef
!
#ifdef SFX_FA
USE modd_io_surf_fa,    ONLY : cfilein_fa, cdnomc
#endif
!
USE modi_abor1_sfx
USE modi_init_io_surf_n
USE modi_read_surf
USE modi_read_and_send_mpi
USE modi_gather_and_write_mpi
USE modi_end_io_surf_n
USE modi_io_buff_clean
USE modi_unpack_same_rank
!
USE yomhook,            ONLY : lhook,dr_hook
USE parkind1,           ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
!
TYPE(data_cover_t), INTENT(INOUT) :: dtco
TYPE(diag_surf_atm_t), INTENT(INOUT) :: dgu
TYPE(seaflux_t), INTENT(INOUT) :: s
TYPE(surf_atm_t), INTENT(INOUT) :: u
!
INTEGER,            INTENT(IN)  :: ki
REAL,DIMENSION(KI), INTENT(IN)  :: pitm
REAL,DIMENSION(KI), INTENT(OUT) :: psst
REAL,DIMENSION(KI), INTENT(OUT) :: psic  ! Not used at the moment
 CHARACTER(LEN=2),   INTENT(IN)  :: htest ! must be equal to 'OK'
!
!*      0.2    declarations of local variables
!
!-------------------------------------------------------------------------------------
!
REAL,ALLOCATABLE, DIMENSION(:,:) :: zwork,zwork2
REAL,ALLOCATABLE, DIMENSION(:)   :: zsea
 CHARACTER(LEN=200)   :: ymfile     ! Name of the SST file
 CHARACTER(LEN=6)     :: yprogram2 = 'FA    '
REAL, DIMENSION(SIZE(PSST)) :: zsst
REAL                 :: zfmax, zfmin, zfmean
INTEGER              :: iresp,istat
INTEGER              :: ji,jj,icpt
REAL(KIND=JPRB)      :: zhook_handle

IF (lhook) CALL dr_hook('ASSIM_SET_SST',0,zhook_handle)

IF (htest/='OK') THEN
  CALL abor1_sfx('ASSIM_SET_SST: FATAL ERROR DURING ARGUMENT TRANSFER')
END IF
!
IF (u%CSEA=="NONE" .OR. u%NDIM_SEA == 0) THEN
  IF (lhook) CALL dr_hook('ASSIM_SET_SST_N',1,zhook_handle)
  RETURN
ENDIF
!
psic(:) = 0.
!
IF ( lread_sst_from_file ) THEN
  !
  IF ( trim(cfile_format_sst) == "ASCII" ) THEN
    !
    ALLOCATE(zsea(u%NDIM_FULL))
    ALLOCATE(zwork(u%NDIM_FULL,2))
    ALLOCATE(zwork2(u%NSIZE_FULL,2))
    !
    IF (nproc>1) CALL gather_and_write_mpi(u%XSEA,zsea)
    !
    IF (nrank==npio) THEN
      ymfile = 'SST_SIC'
      IF (nprintlev > 0 .AND. nrank==npio ) &
              WRITE(*,*) "READING SST/SIC from file "//trim(ymfile)//".DAT for ",&
                                u%NDIM_SEA," sea points",u%NDIM_FULL
      istat = 0
      OPEN(unit=55,file=trim(ymfile)//".DAT",form='FORMATTED',status='OLD',iostat=istat)
      IF ( istat /= 0 ) CALL abor1_sfx("Can not open "//trim(ymfile))

      zwork(:,:) = xundef
      ! Read SST/SIC values
      DO ji = 1,u%NDIM_FULL
        IF ( zsea(ji) > 0. ) THEN
          READ (55,*,iostat=istat)  (zwork(ji,jj),jj=1,2)
          IF ( istat /= 0 ) CALL abor1_sfx("Error reading file "//trim(ymfile))
        ENDIF
      ENDDO
      CLOSE(55)
    ENDIF

    ! Distribute ZWORK to all processors
    IF (nproc>1) THEN
      CALL read_and_send_mpi(zwork(:,1),zwork2(:,1))
      CALL read_and_send_mpi(zwork(:,2),zwork2(:,2))
    ELSE
      zwork2=zwork
    ENDIF

    ! Set SST/SIC variables
    DO ji = 1,u%NSIZE_FULL
      psst(ji)=zwork2(ji,1)
      psic(ji)=zwork2(ji,2)
    ENDDO

    DEALLOCATE(zwork)
    DEALLOCATE(zwork2)
    DEALLOCATE(zsea)

  ELSEIF ( trim(cfile_format_sst) == "FA" ) THEN
    !
    !  Read SST from boundaries when SST analysis NOT is performed in CANARI
    !
    !  Define FA file name for SST analysis interpolated from boundary file 
    !
#ifdef SFX_FA
    cfilein_fa = 'SST_SIC'        ! input SST and SIC analysis  
    cdnomc     = 'CADRE SST'      ! new frame name 
    IF (nrank==npio .AND. nprintlev>0) WRITE(*,*) 'READING SST FROM ',trim(cfilein_fa)
#endif
    !
    !  Open FA file
    !
    CALL init_io_surf_n(dtco, dgu, u, &
                        yprogram2,'EXTZON','SURF  ','READ ')
    !
    !  Read SST_SIC 
    !
    IF ( lecsst ) THEN
      ! SST field interpolated from ECMWF SST ANALYSIS to model domain
      CALL read_surf(&
                     yprogram2,'SURFSEA.TEMPERA',psst,iresp)
    ELSE
      ! Surface temperature from boundary in SST_SIC
      CALL read_surf(&
                     yprogram2,'SURFTEMPERATURE',psst,iresp)
    ENDIF
    !
    !  Close SST_SIC file
    !
    CALL end_io_surf_n(yprogram2)
    CALL io_buff_clean
    IF (nrank==npio) WRITE(*,*) 'READ SST_SIC OK'

    zfmin = minval(psst)
    zfmax = maxval(psst)
    IF ( ki > 0 ) THEN
      zfmean = sum(psst)/float(ki)
    ELSE
      zfmean=xundef
    ENDIF

    IF ( lecsst ) THEN

      IF (nrank==npio .AND. nprintlev>0) THEN
        WRITE(*,*) '  ECMWF_SST_SIC'
        WRITE(*,'("  SURFSEA.TEMPERA - min, mean, max: ",3E13.4)') zfmin, zfmean, zfmax
      ENDIF

      ! Replace -9999. with UNDEF
      WHERE ( psst(:)< 0. )
        psst(:) = xundef
      ENDWHERE

    ELSE

      IF (nrank==npio .AND. nprintlev>0) THEN
        WRITE(*,*) '  Boundary file'
        WRITE(*,'("  SURFTEMPERATURE - min, mean, max: ",3E13.4)') zfmin, zfmean, zfmax
      ENDIF
      ! To avoid surface temperatures influenced by land, NATURE points are replaced with UNDEF
      WHERE ( pitm(:)>0.5 )
        psst(:) = xundef
      ENDWHERE

    ENDIF

    zfmin = minval(psst)
    zfmax = maxval(psst)
    IF ( ki > 0 ) THEN
      zfmean = sum(psst)/float(ki)
    ELSE
      zfmean=xundef
    ENDIF

    IF (nrank==npio .AND. nprintlev>0) THEN
      WRITE(*,*) '  Replaced land by UNDEF '
      WRITE(*,'("  SST            - min, mean, max: ",3E13.4)') zfmin, zfmean, zfmax
    ENDIF

  ELSE
     CALL abor1_sfx("CFILE_FORMAT_SST="//trim(cfile_format_sst)//" not implemented!")
  ENDIF

ELSE
  !
  IF ( u%NSIZE_SEA>0 .AND. u%CSEA/="NONE") THEN
    CALL unpack_same_rank(u%NR_SEA,s%XSST,zsst)
    psst(:) = zsst(:)
  ELSE
    psst(:) = xundef
  ENDIF
  !
ENDIF
!
IF (lhook) CALL dr_hook('ASSIM_SET_SST',1,zhook_handle)
!
!-------------------------------------------------------------------------------------
!
END SUBROUTINE assim_set_sst